TObject与消息分发

在TObject类中，有一个Dispatch()方法和一个DefaultHandler()方法，它们都是消息分发机制相关的。

 

Dispatch()负责将特定的消息分发给适应的消息处理函数，DefaultHandler()方法是默认的消息处理方法。

 

首先Dispatch()会在对象本身类型的类中寻找消息处理函数，如果找到则调用它，如果没有找到则调用默认的处理方法。如果两者都不存在，则继续在其父类中寻找，直到寻找到TObject中。DefaultHandler()方法是虚函数（函数体中没有处理代码），所以一般情况下都要重载这个默认的消息处理方法。

 

注：自定义的消息结构时，VCL规定首四字节必须是消息的编号，其他随意。

 

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;


type
  TMyMsg = record
    Msg : Cardinal;
    MsgText : String;
  end;
  TMsgAccepter = class
    private
      procedure AcceptMsg2000(var msg : TMyMsg); message 2000;
      procedure AcceptMsg2001(var msg : TMyMsg); message 2001;
    public
      procedure DefaultHandler(var Message); override;
  end;

var
  Form1: TForm1;
  MsgAccept : TMsgAccepter;
implementation

{$R *.dfm}

{ TMsgAccepter }

procedure TMsgAccepter.AcceptMsg2000(var msg: TMyMsg);
begin
  ShowMessage(Format('收到消息：%d，%s', [msg.Msg, msg.MsgText]));
end;

procedure TMsgAccepter.AcceptMsg2001(var msg: TMyMsg);
begin
  ShowMessage(Format('收到消息：%d，%s', [msg.Msg, msg.MsgText]));
end;

procedure TMsgAccepter.defaultHandler(var Message);
begin
  inherited;
  ShowMessage(Format('没有匹配的消息处理方法：%d，%s', [TMyMsg(Message).Msg, TMyMsg(Message).MsgText]));
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  msg : TMyMsg;
begin
  msg.Msg := 2000;
  msg.MsgText := '第2000条消息';
  MsgAccept.Dispatch(msg);
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  msg : TMyMsg;
begin
  msg.Msg := 2001;
  msg.MsgText := '第2001条消息';
  MsgAccept.Dispatch(msg);
end;

procedure TForm1.Button3Click(Sender: TObject);
var
  msg : TMyMsg;
begin
  msg.Msg := 2002;
  msg.MsgText := '第2002条消息';
  MsgAccept.Dispatch(msg);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  MsgAccept :=  TMsgAccepter.Create;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  MsgAccept.Free;
  MsgAccept := nil;
end;

end.