bzoj1036 [ZJOI2008]树的统计Count（树链剖分）

Description

　　一棵树上有n个节点，编号分别为1到n，每个节点都有一个权值w。我们将以下面的形式来要求你对这棵树完成一些操作： I. CHANGE u t : 把结点u的权值改为t II. QMAX u v: 询问从点u到点v的路径上的节点的最大权值 III. QSUM u v: 询问从点u到点v的路径上的节点的权值和 注意：从点u到点v的路径上的节点包括u和v本身

Input

　　输入的第一行为一个整数n，表示节点的个数。接下来n – 1行，每行2个整数a和b，表示节点a和节点b之间有一条边相连。接下来n行，每行一个整数，第i行的整数wi表示节点i的权值。接下来1行，为一个整数q，表示操作的总数。接下来q行，每行一个操作，以“CHANGE u t”或者“QMAX u v”或者“QSUM u v”的形式给出。 
     对于100％的数据，保证1<=n<=30000，0<=q<=200000；中途操作中保证每个节点的权值w在-30000到30000之间。

Output

　　对于每个“QMAX”或者“QSUM”的操作，每行输出一个整数表示要求输出的结果。

Sample Input

4
1 2
2 3
4 1
4 2 1 3
12
QMAX 3 4
QMAX 3 3
QMAX 3 2
QMAX 2 3
QSUM 3 4
QSUM 2 1
CHANGE 1 5
QMAX 3 4
CHANGE 3 6
QMAX 3 4
QMAX 2 4
QSUM 3 4

Sample Output

4
1
2
2
10
6
5
6
5
16

 

 

没什么可说的，就是复习一下树链剖分模板。

以前做过，那是还是用指针存树的，也是dfs的。

以前的：http://www.cnblogs.com/Currier/p/6388145.html

现在写的是数组模拟邻接表，以及非递归的预处理。

这个非递归预处理可以使子树和链都在一起，也可以只保证链在一起，这题没有子树操作，只要后者即可，但也写了下使子树在一起的代码。

先是只保证链在一起的代码：

program rrr(input,output);
const
  inf=123456789;
type
  treetype=record
     l,r,max,sum:longint;
  end;
  etype=record
     t,next:longint;
  end;
var
  a:array[0..120012]of treetype;
  b,c,father,siz,son,ss,idx,head,q,dep:array[0..30030]of longint;
  e:array[0..60060]of etype;
  n,m,i,j,x,y,cnt,h,t,ans:longint;
  s:string;
function max(a,b:longint):longint;
begin
   if a>b then exit(a) else exit(b);
end;
procedure add(x,y:longint);
begin
   inc(cnt);e[cnt].t:=y;e[cnt].next:=c[x];c[x]:=cnt;
end;
procedure work;
begin
   j:=pos(' ',s);val(copy(s,1,j-1),x);delete(s,1,j);val(s,y);
end;
procedure prepare;
begin
   h:=0;t:=1;q[1]:=1;father[1]:=0;dep[1]:=1;
   while h<t do
      begin
         inc(h);
         i:=c[q[h]];
         while i<>0 do
            begin
               if e[i].t<>father[q[h]] then
                  begin
                     father[e[i].t]:=q[h];dep[e[i].t]:=dep[q[h]]+1;
                     inc(t);q[t]:=e[i].t;
                  end;
               i:=e[i].next;
            end;
      end;
   fillchar(son,sizeof(son),0);fillchar(ss,sizeof(ss),0);
   for i:=1 to n do siz[i]:=1;
   for i:=n downto 2 do
      begin
         inc(siz[father[q[i]]],siz[q[i]]);
         if siz[q[i]]>ss[father[q[i]]] then
            begin ss[father[q[i]]]:=siz[q[i]];son[father[q[i]]]:=q[i]; end;
      end;
   cnt:=0;fillchar(idx,sizeof(idx),0);
   for i:=1 to n do
      if idx[q[i]]=0 then
         begin
            j:=q[i];
            while j<>0 do begin inc(cnt);idx[j]:=cnt;head[j]:=q[i];j:=son[j]; end;
         end;
end;
procedure build(k,l,r:longint);
var
  mid,i:longint;
begin
   a[k].l:=l;a[k].r:=r;
   if l=r then begin a[k].max:=b[l];a[k].sum:=b[l];exit; end;
   mid:=(l+r)>>1;i:=k+k;
   build(i,l,mid);
   build(i+1,mid+1,r);
   a[k].max:=max(a[i].max,a[i+1].max);
   a[k].sum:=a[i].sum+a[i+1].sum;
end;
procedure change(k,x,y:longint);
var
  mid,i:longint;
begin
   if a[k].l=a[k].r then begin a[k].sum:=y;a[k].max:=y;exit end;
   mid:=(a[k].l+a[k].r)>>1;i:=k+k;
   if x<=mid then change(i,x,y) else change(i+1,x,y);
   a[k].max:=max(a[i].max,a[i+1].max);
   a[k].sum:=a[i].sum+a[i+1].sum;
end;
function askmax(k,x,y:longint):longint;
var
  mid,ans:longint;
begin
   if (x<=a[k].l) and (a[k].r<=y) then exit(a[k].max);
   mid:=(a[k].l+a[k].r)>>1;
   ans:=-inf;
   if x<=mid then ans:=askmax(k+k,x,y);
   if mid<y then ans:=max(ans,askmax(k+k+1,x,y));
   exit(ans);
end;
function asksum(k,x,y:longint):longint;
var
  mid,ans:longint;
begin
   if (x<=a[k].l) and (a[k].r<=y) then exit(a[k].sum);
   mid:=(a[k].l+a[k].r)>>1;
   ans:=0;
   if x<=mid then ans:=asksum(k+k,x,y);
   if mid<y then ans:=ans+asksum(k+k+1,x,y);
   exit(ans);
end;
procedure qmax;
begin
   ans:=-inf;
   while head[x]<>head[y] do
      if dep[head[x]]>dep[head[y]] then
         begin
            ans:=max(ans,askmax(1,idx[head[x]],idx[x]));
            x:=father[head[x]];
         end
      else begin
         ans:=max(ans,askmax(1,idx[head[y]],idx[y]));
         y:=father[head[y]];
      end;
   if dep[x]>dep[y] then ans:=max(ans,askmax(1,idx[y],idx[x]))
   else ans:=max(ans,askmax(1,idx[x],idx[y]));
end;
procedure qsum;
begin
   ans:=0;
   while head[x]<>head[y] do
      if dep[head[x]]>dep[head[y]] then
         begin
            ans:=ans+asksum(1,idx[head[x]],idx[x]);
            x:=father[head[x]];
         end
      else begin
         ans:=ans+asksum(1,idx[head[y]],idx[y]);
         y:=father[head[y]];
      end;
   if dep[x]>dep[y] then ans:=ans+asksum(1,idx[y],idx[x])
   else ans:=ans+asksum(1,idx[x],idx[y]);
end;
begin
   assign(input,'r.in');assign(output,'r.out');reset(input);rewrite(output);
   readln(n);
   fillchar(c,sizeof(c),0);cnt:=0;
   for i:=1 to n-1 do begin readln(x,y);add(x,y);add(y,x); end;
   prepare;
   for i:=1 to n do read(b[idx[i]]);
   build(1,1,n);
   readln(m);
   for i:=1 to m do
      begin
         readln(s);
         if s[1]='C' then begin delete(s,1,7);work;change(1,idx[x],y); end
         else if s[2]='M' then begin delete(s,1,5);work;qmax;writeln(ans); end
         else begin delete(s,1,5);work;qsum;writeln(ans); end;
      end;
   close(input);close(output);
end.

然后是是子树也在一起的代码：

program rrr(input,output);
const
  inf=123456789;
type
  treetype=record
     l,r,max,sum:longint;
  end;
  etype=record
     t,next:longint;
  end;
var
  a:array[0..120012]of treetype;
  b,c,father,siz,son,ss,idx,head,q,dep,ot:array[0..30030]of longint;
  e:array[0..60060]of etype;
  n,m,i,j,x,y,cnt,h,t,ans:longint;
  s:string;
function max(a,b:longint):longint;
begin
   if a>b then exit(a) else exit(b);
end;
procedure add(x,y:longint);
begin
   inc(cnt);e[cnt].t:=y;e[cnt].next:=c[x];c[x]:=cnt;
end;
procedure work;
begin
   j:=pos(' ',s);val(copy(s,1,j-1),x);delete(s,1,j);val(s,y);
end;
procedure prepare;
begin
   h:=0;t:=1;q[1]:=1;father[1]:=0;dep[1]:=1;
   while h<t do
      begin
         inc(h);
         i:=c[q[h]];
         while i<>0 do
            begin
               if e[i].t<>father[q[h]] then
                  begin
                     father[e[i].t]:=q[h];dep[e[i].t]:=dep[q[h]]+1;
                     inc(t);q[t]:=e[i].t;
                  end;
               i:=e[i].next;
            end;
      end;
   fillchar(son,sizeof(son),0);fillchar(ss,sizeof(ss),0);
   for i:=1 to n do siz[i]:=1;
   for i:=n downto 2 do
      begin
         inc(siz[father[q[i]]],siz[q[i]]);
         if siz[q[i]]>ss[father[q[i]]] then
            begin ss[father[q[i]]]:=siz[q[i]];son[father[q[i]]]:=q[i]; end;
      end;
   fillchar(idx,sizeof(idx),0);ot[0]:=0;
   for i:=1 to n do
      if idx[q[i]]=0 then
         begin
            cnt:=ot[father[q[i]]];j:=q[i];
            while j<>0 do
               begin
                  head[j]:=q[i];
                  inc(cnt);idx[j]:=cnt;
                  ot[j]:=cnt;inc(ot[father[j]],siz[j]);
                  j:=son[j];
               end;
         end;
end;
procedure build(k,l,r:longint);
var
  mid,i:longint;
begin
   a[k].l:=l;a[k].r:=r;
   if l=r then begin a[k].max:=b[l];a[k].sum:=b[l];exit; end;
   mid:=(l+r)>>1;i:=k+k;
   build(i,l,mid);
   build(i+1,mid+1,r);
   a[k].max:=max(a[i].max,a[i+1].max);
   a[k].sum:=a[i].sum+a[i+1].sum;
end;
procedure change(k,x,y:longint);
var
  mid,i:longint;
begin
   if a[k].l=a[k].r then begin a[k].sum:=y;a[k].max:=y;exit end;
   mid:=(a[k].l+a[k].r)>>1;i:=k+k;
   if x<=mid then change(i,x,y) else change(i+1,x,y);
   a[k].max:=max(a[i].max,a[i+1].max);
   a[k].sum:=a[i].sum+a[i+1].sum;
end;
function askmax(k,x,y:longint):longint;
var
  mid,ans:longint;
begin
   if (x<=a[k].l) and (a[k].r<=y) then exit(a[k].max);
   mid:=(a[k].l+a[k].r)>>1;
   ans:=-inf;
   if x<=mid then ans:=askmax(k+k,x,y);
   if mid<y then ans:=max(ans,askmax(k+k+1,x,y));
   exit(ans);
end;
function asksum(k,x,y:longint):longint;
var
  mid,ans:longint;
begin
   if (x<=a[k].l) and (a[k].r<=y) then exit(a[k].sum);
   mid:=(a[k].l+a[k].r)>>1;
   ans:=0;
   if x<=mid then ans:=asksum(k+k,x,y);
   if mid<y then ans:=ans+asksum(k+k+1,x,y);
   exit(ans);
end;
procedure qmax;
begin
   ans:=-inf;
   while head[x]<>head[y] do
      if dep[head[x]]>dep[head[y]] then
         begin
            ans:=max(ans,askmax(1,idx[head[x]],idx[x]));
            x:=father[head[x]];
         end
      else begin
         ans:=max(ans,askmax(1,idx[head[y]],idx[y]));
         y:=father[head[y]];
      end;
   if dep[x]>dep[y] then ans:=max(ans,askmax(1,idx[y],idx[x]))
   else ans:=max(ans,askmax(1,idx[x],idx[y]));
end;
procedure qsum;
begin
   ans:=0;
   while head[x]<>head[y] do
      if dep[head[x]]>dep[head[y]] then
         begin
            ans:=ans+asksum(1,idx[head[x]],idx[x]);
            x:=father[head[x]];
         end
      else begin
         ans:=ans+asksum(1,idx[head[y]],idx[y]);
         y:=father[head[y]];
      end;
   if dep[x]>dep[y] then ans:=ans+asksum(1,idx[y],idx[x])
   else ans:=ans+asksum(1,idx[x],idx[y]);
end;
begin
   assign(input,'r.in');assign(output,'r.out');reset(input);rewrite(output);
   readln(n);
   fillchar(c,sizeof(c),0);cnt:=0;
   for i:=1 to n-1 do begin readln(x,y);add(x,y);add(y,x); end;
   prepare;
   for i:=1 to n do read(b[idx[i]]);
   build(1,1,n);
   readln(m);
   for i:=1 to m do
      begin
         readln(s);
         if s[1]='C' then begin delete(s,1,7);work;change(1,idx[x],y); end
         else if s[2]='M' then begin delete(s,1,5);work;qmax;writeln(ans); end
         else begin delete(s,1,5);work;qsum;writeln(ans); end;
      end;
   close(input);close(output);
end.

其实大部分都是一模一样的，只是预处理不一样。