【BZOJ1179】[Apio2009]Atm (tarjan+SPFA)

    显而易见的tarjan+spfa...不解释了

const maxn=500419;
type
 edgetype=record
  toward,next:longint;
 end;
 
var
 edge1,edge2:array[0..maxn] of edgetype;
 first1,first2,scc,stack,dfn,low,val,sum,q,d:Array[0..maxn] of longint;
 pd:array[0..maxn] of boolean;
 num,tot,n,m,cnt,top:longint;
 
function min(x,y:longint):longint; begin if x<y then exit(x) else exit(y); end;
 
procedure addedge(i,j:longint);
begin
 inc(tot);
 edge1[tot].toward:=j;
 edge1[tot].next:=first1[i];
 first1[i]:=tot;
end;
 
procedure add(i,j:longint);
begin
 inc(tot);
 edge2[tot].toward:=j;
 edge2[tot].next:=first2[i];
 first2[i]:=tot;
end;
 
procedure tarjan(v:longint);
var i,tmp,u:longint;
begin
 inc(cnt); dfn[v]:=cnt; low[v]:=cnt;
 inc(top); stack[top]:=v;
 pd[v]:=true; i:=first1[v];
 while i<>0 do
  begin
   tmp:=edge1[i].toward;
   if dfn[tmp]=0 then
    begin
     tarjan(tmp);
     low[v]:=min(low[v],low[tmp]);
    end
   else if pd[tmp] then low[v]:=min(low[v],dfn[tmp]);
   i:=edge1[i].next;
  end;
 if low[v]=dfn[v] then
  begin
   inc(num);
   repeat
    u:=stack[top]; dec(top);
    pd[u]:=false; scc[u]:=num;
    inc(sum[num],val[u]);
   until u=v;
  end;
end;
 
procedure spfa(s:longint);
var head,tail,i,j,tmp:longint;
begin
 fillchar(d,sizeof(d),0);
 fillchar(pd,sizeof(pd),false);
 head:=0;
 tail:=1;
 pd[scc[s]]:=true;
 q[1]:=scc[s];
 d[scc[s]]:=sum[scc[s]];
 while head<>tail do
  begin
   inc(head);
   if head>maxn then head:=1;
   j:=q[head];
   i:=first2[j];
   while i<>0 do
    begin
     tmp:=edge2[i].toward;
     if d[j]+sum[tmp]>d[tmp] then
      begin
       d[tmp]:=d[j]+sum[tmp];
       if not pd[tmp] then
        begin
         inc(tail); if tail>maxn then tail:=1;
         q[tail]:=tmp;
         pd[tmp]:=true;
        end;
      end;
     i:=edge2[i].next;
    end;
   pd[j]:=false;
  end;
end;
 
procedure init;
var i,j,a,b:longint;
begin
 read(n,m);
 for i:= 1 to m do
  begin
   readln(a,b);
   addedge(a,b);
  end;
 for i:= 1 to n do read(val[i]);
 for i:= 1 to n do if dfn[i]=0 then tarjan(i);
end;
 
procedure solve;
var p,x,ans,s,i,j:longint;
begin
 read(s,p);
 tot:=0;
 for j:= 1 to n do
  begin
   i:=first1[j];
   while i<>0 do
    begin
     x:=edge1[i].toward;
     if scc[x]<>scc[j] then add(scc[j],scc[x]);
     i:=edge1[i].next;
    end;
  end;
 spfa(s);
 ans:=0;
 for i:= 1 to p do
  begin
   read(x);
   if d[scc[x]]>ans then ans:=d[scc[x]];
  end;
 writeln(ans);
end;
 
Begin
 init;
 solve;
End.