Comparing records on a same table

Sometimes you need to know what’s the difference between records. I made a simple function to do just that. It’s an example of how to use reflection and field IDs on records.

It takes two records and returns a container with the field IDs and the values from both records. For simplicity I used a flattened container instead of more complicated data structures. Feel free to replace it with nested containers or some kind of collection.

I added this to the class Global for easy access.

As you can see it only compares records of the same type and skips system fields (e.g. RecId). Special care is taken to handle array fields correctly.

Using it is quite straightforward.

 X++ code as below.

October 7th 2010 by Jimmy xie

static void Jimmy_CompareRecordsOnSameTable(Args _args)
{
    CustTable   custTable1 = CustTable::find("QVSHK");
    CustTable   custTable2 = CustTable::find("WIB-CHN");
    container   con;
    int         m,n;
container compareRecords(Common _record1, Common _record2)
{
    SysDictTable    dictTable = new SysDictTable(_record1.TableId);
    SysDictField    dictField;
    FieldId         fieldId, extFieldId;
    container       ret;
    int             i, j;
;
    if (_record1.TableId != _record2.TableId)
        return conNull();

    for (i = 1; i <= dictTable.fieldCnt(); ++i)
    {
        fieldId     = dictTable.fieldCnt2Id(i);
        //dictField   = new SysDictField(_record1.tableId, fieldId);// also wrote this code
        dictField   = dictTable.fieldObject(fieldId);
        if (!dictField.isSystem())
        {
            for (j = 1; j <= dictField.arraySize(); ++j)
            {
                extFieldId = fieldId2Ext(fieldId, j);

                if (_record1.(extFieldId) != _record2.(extFieldId))
                {
                    ret += [extFieldId, _record1.(extFieldId), _record2.(extFieldId)];
                }
            }
        }
    }

    return ret;
}
;
    con = compareRecords(custTable1, custTable2);

    for (m = 1; m <= conLen(con); m += 3)
    {
        n++;
        info(strFmt("%4 - %1: '%2' <-> '%3'"
                   ,fieldId2Name(tableNum(CustTable), conPeek(con, m))
                   ,conPeek(con, m+1)
                   ,conPeek(con, m+2)
                   ,n
                   )
             );
    }
}
//ps :  default dictField.arraySize() is 1