算法模板——二分图匹配

实现功能为二分图匹配

原理：匈牙利算法，核心思想——匹配上了就配，没直接匹配上也要通过前面的腾出位置让这个匹配上（详见：趣写算法系列之——匈牙利算法）

本程序以Codevs2776为例

详见Codevs2776

type
    point=^node;
    node=record
               g:longint;
               next:point;
    end;
var
   i,j,k,l,m,n:longint;
   c,f:array[0..1000] of longint;
   a:array[0..1000] of point;
procedure add(x,y:longint);inline;
          var p:point;
          begin
               new(p);
               p^.g:=y;
               p^.next:=a[x];
               a[x]:=p;
          end;
function check(x:longint):boolean;inline;
         var p:point;
         begin
              p:=a[x];
              while p<>nil do
                    begin
                         if f[p^.g]<>i then
                            begin
                                 f[p^.g]:=i;
                                 if c[p^.g]=0 then
                                    begin
                                         c[p^.g]:=x;
                                         exit(true);
                                    end
                                 else if check(c[p^.g]) then
                                      begin
                                           c[p^.g]:=x;
                                           exit(true);
                                      end;
                            end;
                         p:=p^.next;
                    end;
              exit(false);
         end;

{$IFDEF WINDOWS}{$R wiki2776.rc}{$ENDIF}

begin
     readln(n,m);
     for i:=1 to n do
         begin
              a[i]:=nil;
              while not(eoln) do
                    begin
                         read(j);
                         if j=0 then break;
                         add(i,j);
                    end;
              readln;
         end;
     fillchar(c,sizeof(c),0);
     fillchar(f,sizeof(f),0);l:=0;
     for i:=1 to n do
         if check(i) then inc(l);
     writeln(l);
     readln;
end.