算法模板——sap网络最大流 1（非递归+邻接矩阵）

实现功能：首行输入N，M，S，T，代表这张图N个点，M条边，源点为S，汇点为T；接下来T行输入个边的出发点、终点和权值；输出最大流

原理：sap网络流算法（详见百度百科，个人觉得这个模板已经不错了，虽然本人暂时还未考虑引入邻接表进行优化）（推荐模板题：Codevs1993）

var
   i,j,k,l,m,n,ans,aug,s,t,tmp,jl,mi:longint;
   flag:boolean;
   vh,dis,di,his,pre:array[0..10000] of longint;
   map:array[0..2050,0..2050] of longint;
function min(x,y:longint):longint;inline;
         begin
              if x<y then min:=x else min:=y;
         end;
begin
     readln(n,m,s,t);
     fillchar(map,sizeof(map),0);
     for i:=1 to m do
         begin
              readln(j,k,l);
              map[j,k]:=map[j,k]+l;
         end;
     i:=s;ans:=0;aug:=maxlongint;
     fillchar(dis,sizeof(dis),0);
     for i:=1 to n do di[i]:=1;
     i:=s;
     while dis[s]<n do
           begin
                flag:=false;
                his[i]:=aug;
                for j:=di[i] to n do
                    begin
                         if (map[i,j]>0) and (dis[i]=(dis[j]+1)) then
                            begin
                                 aug:=min(aug,map[i,j]);
                                 pre[j]:=i;di[i]:=j;
                                 i:=j;flag:=true;
                                 if i=t then
                                    begin
                                         ans:=ans+aug;
                                         while i<>s do
                                               begin
                                                    tmp:=i;
                                                    i:=pre[i];
                                                    map[i,tmp]:=map[i,tmp]-aug;
                                                    map[tmp,i]:=map[tmp,i]+aug;
                                               end;
                                         aug:=maxlongint;
                                    end;
                                 break;
                            end;
                    end;
                if flag then continue;
                jl:=-1;mi:=n-1;
                for j:=1 to n do
                    begin
                         if (map[i,j]>0) and (dis[j]<mi) then
                            begin
                                 mi:=dis[j];
                                 jl:=j;
                            end;
                    end;
                di[i]:=jl;
                dec(vh[dis[i]]);
                if vh[dis[i]]=0 then break;
                dis[i]:=mi+1;
                inc(vh[dis[i]]);
                if i<>s then
                   begin
                        i:=pre[i];
                        aug:=his[i];
                   end;
           end;
     writeln(ans);
end.