互不侵犯（BZOJ1087） 题解

【题目描述】

    在N×N的棋盘里面放K个国王，使他们互不攻击，共有多少种摆放方案。国王能攻击到它上下左右，以及左上左下右上右下八个方向上附近的各一个格子，共8个格子。

【样例输入】

    3 2

【样例输出】

    16

【解题思路】

    本题为SCOI2005的题，正解应该是状态压缩动态规划，把所有方案变为二进制存储，1为该位置摆放了国王，0为没有，因为一行最多九个格子，也就是说最多为511，空间上完全可以接受。然后我们可以先预处理一下所有可行的国王摆放的位置，以减少动规的次数，设f[i,j,k]为现在是第i行，用第j种方案，一共摆放了k个国王的总方案数，那么我们动规的条件就是f[i,j,k]=∑f[i-1,s,t]{s为与j不冲突的方案，t<=k}

    于是对于每个可行方案，我们需要记录一些东西：这个可行方案摆了多少国王，这个可行方案的攻击范围。那么满足条件的s即为s and j=0。

【代码实现】

type rec=record
     j,l,p:longint;
end;
var f:array[1..9,0..512,0..80] of int64;
    n,m,i,j,w,k,q,total,l:longint;
    ans:int64;
    fl:boolean;
    fa:array[1..500] of rec;
procedure dfs(w,dep,t:longint);
var i:longint;
    s:string;
    ch:string;
begin
 if dep>n then
  begin
   inc(total);
   fa[total].j:=t;
   i:=t;
   s:='';
   while i<>0 do
    begin
     if i and 1=1 then
      inc(fa[total].l);
     str(i and 1,ch);
     s:=ch+s;
     i:=i shr 1;
    end;
   while length(s)<n do
    s:='0'+s;
   for i:=n downto 1 do
    if i=1 then
     begin
      if (s[i]='1')or(s[i+1]='1') then
       fa[total].p:=fa[total].p+(1 shl (n-i));
     end
    else
     if i=n then
      begin
       if (s[i]='1')or(s[i-1]='1') then
        fa[total].p:=fa[total].p+1;
      end
     else
      if (s[i]='1')or(s[i-1]='1')or(s[i+1]='1') then
       fa[total].p:=fa[total].p+(1 shl (n-i));
   exit;
  end;
 if w=1 then
  dfs(0,dep+1,t)
 else
  for i:=0 to 1 do
   begin
    t:=t+i shl (dep-1);
    dfs(i,dep+1,t);
   end;
end;
begin
 readln(n,m);
 if m>sqr((n+1)shr 1) then
  begin
   writeln(0);
   halt;
  end;
 dfs(0,1,0);
 for i:=1 to total do
  f[1,fa[i].j,fa[i].l]:=1;
 for i:=2 to n do
  for j:=1 to total do
   for l:=0 to ((n+1)shr 1)*(i-1) do
    if f[i-1,fa[j].j,l]=0 then
     continue
    else
     for k:=1 to total do
      if fa[j].p and fa[k].j=0 then
       inc(f[i,fa[k].j,l+fa[k].l],f[i-1,fa[j].j,l]);
 for i:=1 to total do
  ans:=ans+f[n,fa[i].j,m];
 writeln(ans);
end.