3140:[HNOI2013]消毒

题目描述 Description
最近在生物实验室工作的小 T 遇到了大麻烦。
由于实验室最近升级的缘故，他的分格实验皿是一个长方体,其尺寸为 a*b*c，a、b、c均为正整数。为了实验的方便，它被划分为 a*b*c 个单位立方体区域，每个单位立方体尺寸为 1*1*1。用(i,j,k)标识一个单位立方体，1≤i≤a，1≤j≤b，1≤k≤c。这个实验皿已经很久没有人用了，现在，小 T 被导师要求将其中一些单位立方体区域进行消毒操作（每个区域可以被重复消毒）。而由于严格的实验要求，他被要求使用一种特定的 F 试剂来进行消毒。
这种 F 试剂特别奇怪，每次对尺寸为 x*y*z 的长方体区域（它由 x*y*z 个单位立方体组成）进行消毒时，只需要使用 min{x,y,z}单位的 F 试剂。F 试剂的价格不菲，这可难倒了小T。现在请你告诉他，最少要用多少单位的 F 试剂。(注：min{x,y,z}表示 x、y、z 中的最小者。)

输入描述 Input Description
输入文件第一行是一个正整数D，表示数据组数。
接下来是D组数据，每组数据开头是三个数a,b,c表示实验皿的尺寸。接下来会出现a个b行c列的用空格隔开的01矩阵，0表示对应的单位立方体不要求消毒，1表示对应的单位立方体需要消毒；例如，如果第1个01矩阵的第2行第3列为1，则表示单位立方体(1,2,3)需要被消毒。
输入保证满足a*b*c≤5000,T≤3。
输出描述 Output Description
仅包含 D 行，每行一个整数，表示对应实验皿最少要用多少单位的 F 试剂。
样例输入 Sample Input
1
4 4 4
1 0 1 1
0 0 1 1
0 0 0 0
0 0 0 0
0 0 1 1
1 0 1 1
0 0 0 0
0 0 0 0
0 0 0 0
0 0 0 0
1 0 0 0
0 0 0 0
0 0 0 0
0 0 0 0
0 0 0 0
1 0 0 0
样例输出 Sample Output
3
数据范围及提示 Data Size & Hint
对于区域(1,1,3)-(2,2,4)和(1,1,1)-(4,4,1)消毒，分别花费2个单位和1个单位的F试剂。

终于过了，fillchar没有一点优势啊
还是用各种for来把赋初值快一些

二维的怎么做大家都知道，就是二分图匹配，但是这是三维
怎么办呢？
！！！！强行转化成二维，枚举第三维的情况，那这需要2^k所以我们找最小的k
因为a*b*c<=5000，所以min{a,b,c}最大是17左右
然后开始枚举，但是还是很吃力所以对于把一个数组重新赋值的事最好避免

var
    f:array[0..5000,1..3]of longint;
    first,next,last,cover,bool:array[0..5000]of longint;
    flag,sum:array[0..20]of boolean;
    a,b,c,tot,num,min,aug,ans,match,t,time,time2,maxa,maxb,maxc:longint;

procedure swap(var x,y:longint);
var
    t:longint;
begin
    t:=x;
    x:=y;
    y:=t;
end;

procedure init;
var
    i,j,k,s,ai,bi,ci:longint;
begin
    read(ai,bi,ci);
    a:=1;
    b:=2;
    c:=3;
    num:=0;
    maxa:=0;
    maxb:=0;
    maxc:=0;
    for i:=1 to ai do
      for j:=1 to bi do
        for k:=1 to ci do
          begin
            read(s);
            if s=1 then
            begin
              inc(num);
              f[num,1]:=i;
              f[num,2]:=j;
              f[num,3]:=k;
              if i>maxa then maxa:=i;
              if j>maxb then maxb:=j;
              if k>maxc then maxc:=k;
            end;
          end;
    min:=ai;
    if bi<min then min:=bi;
    if ci<min then min:=ci;
    if (bi<=ai)and(bi<=ci) then
      begin
        swap(a,b);
        swap(maxa,maxb);
      end
    else
      if (ci<=ai)and(ci<=bi) then
      begin
        swap(a,c);
        swap(maxa,maxc);
      end;
    fillchar(sum,sizeof(sum),false);
    for i:=1 to num do
      sum[f[i,a]]:=true;
end;

function path(x:integer):boolean;
var
    i:integer;
begin
    i:=first[x];
    while i<>0 do
      begin
        if bool[last[i]]<>time2 then
          begin
            bool[last[i]]:=time2;
            if (cover[last[i]]=0)or(path(cover[last[i]])) then
            begin
              cover[last[i]]:=x;
              exit(true);
            end;
          end;
        i:=next[i];
      end;
    exit(false);
end;

procedure insert(x,y:integer);
begin
    inc(tot);
    last[tot]:=y;
    next[tot]:=first[x];
    first[x]:=tot;
end;

procedure work;
var
    i:integer;
begin
    if aug>ans then exit;
    tot:=0;
    match:=0;
    for i:=1 to maxb do
      first[i]:=0;
    for i:=1 to maxc do
      cover[i]:=0;
    for i:=1 to num do
      if flag[f[i,a]] then insert(f[i,b],f[i,c]);
    for i:=1 to maxb do
      begin
        inc(time2);
        if path(i) then inc(match);
      end;
    if ans>aug+match then ans:=aug+match;
end;

procedure try(x:integer);
begin
    if x>min then work
    else
      begin
        flag[x]:=true;
        try(x+1);
        if sum[x] then
        begin
          flag[x]:=false;
          inc(aug);
          try(x+1);
          dec(aug);
        end;
      end;
end;

begin
    read(t);
    for time:=1 to t do
      begin
        init;
        ans:=200;
        try(1);
        writeln(ans);
      end;
end.