2337:[HNOI2011]XOR和路径

昨天才做了一道高斯消元，一下要精度判断，一下又不要精度判断
主要是思路很重要
很容易想到每一个二进制位算一个概率，然后求和，设f[i]为走到从i走到n这一个二进制位为1的概率
f[i]:=∑{f[j]/d[i](i到j的路径这一位是0),(1-f[j])/d[i],(i到j的路径这一位是1)}(f[n]直接设为0)

var
    f:array[0..110,0..110]of extended;
    d:array[0..110]of longint;
    v,u,w:array[0..10010]of longint;
    ans:extended;
    n,m:longint;
 
procedure swap(var x,y:extended);
var
    t:extended;
begin
    t:=x;
    x:=y;
    y:=t;
end;
 
procedure init;
var
    i:longint;
begin
    read(n,m);
    for i:=1 to m do
      begin
        read(v[i],u[i],w[i]);
        inc(d[v[i]]);
        inc(d[u[i]]);
        if u[i]=v[i] then dec(d[u[i]]);
      end;
end;
 
procedure work;
var
    t,i,j,k:longint;
    s:extended;
begin
    for t:=0 to 30 do
      begin
        for i:=1 to n do
          for j:=1 to n+1 do
            f[i,j]:=0;
        for i:=1 to n do
          f[i,i]:=1;
        for i:=1 to m do
          if w[i]and(1<<t)=0 then
            begin
              f[v[i],u[i]]:=f[v[i],u[i]]-1/d[v[i]];
              f[u[i],v[i]]:=f[u[i],v[i]]-1/d[u[i]];
              if u[i]=v[i] then f[v[i],v[i]]:=f[u[i],u[i]]+1/d[v[i]];
            end
          else
            begin
              f[v[i],u[i]]:=f[v[i],u[i]]+1/d[v[i]];
              f[u[i],v[i]]:=f[u[i],v[i]]+1/d[u[i]];
              f[v[i],n+1]:=f[v[i],n+1]+1/d[v[i]];
              f[u[i],n+1]:=f[u[i],n+1]+1/d[u[i]];
              if v[i]=u[i] then
              begin
                f[u[i],v[i]]:=f[u[i],v[i]]-1/d[u[i]];
                f[v[i],n+1]:=f[v[i],n+1]-1/d[v[i]];
              end;
            end;
        for i:=1 to n-2 do
          begin
            for j:=i to n-1 do
              if f[j,i]<>0 then break;
            for k:=i to n+1 do
              swap(f[i,k],f[j,k]);
            for j:=i+1 to n-1 do
              if abs(f[j,i])>0 then
              begin
                s:=f[j,i]/f[i,i];
                f[j,i]:=0;
                for k:=i+1 to n+1 do
                  f[j,k]:=f[j,k]-s*f[i,k];
              end;
          end;
          for i:=n-1 downto 1 do
            begin
              for j:=i+1 to n-1 do
                f[i,n+1]:=f[i,n+1]-f[j,0]*f[i,j];
              f[i,0]:=f[i,n+1]/f[i,i];
            end;
          ans:=ans+f[1,0]*(1<<t);
      end;
    write(ans:0:3);
end;