1021: [SHOI2008]Debt 循环的债务

Description

Alice、Bob和Cynthia总是为他们之间混乱的债务而烦恼，终于有一天，他们决定坐下来一起解决这个问题。不过，鉴别钞票的真伪是一件很麻烦的事情，于是他们决定要在清还债务的时候尽可能少的交换现金。比如说，Alice欠Bob 10元，而Cynthia和他俩互不相欠。现在假设Alice只有一张50元，Bob有3张10元和10张1元，Cynthia有3张20元。一种比较直接的做法是：Alice将50元交给Bob，而Bob将他身上的钱找给Alice，这样一共就会有14张钞票被交换。但这不是最好的做法，最好的做法是：Alice把50块给Cynthia，Cynthia再把两张20给Alice，另一张20给Bob，而Bob把一张10块给C，此时只有5张钞票被交换过。没过多久他们就发现这是一个很棘手的问题，于是他们找到了精通数学的你为他们解决这个难题。
Input

输入的第一行包括三个整数：x1、x2、x3（-1,000≤x1，x2，x3≤1,000），其中 x1代表Alice欠Bob的钱（如果x1是负数，说明Bob欠了Alice的钱） x2代表Bob欠Cynthia的钱（如果x2是负数，说明Cynthia欠了Bob的钱） x3代表Cynthia欠Alice的钱（如果x3是负数，说明Alice欠了Cynthia的钱）接下来有三行，每行包括6个自然数： a100，a50，a20，a10，a5，a1 b100，b50，b20，b10，b5，b1 c100，c50，c20，c10，c5，c1 a100表示Alice拥有的100元钞票张数，b50表示Bob拥有的50元钞票张数，以此类推。另外，我们保证有a10+a5+a1≤30，b10+b5+b1≤30，c10+c5+c1≤30，而且三人总共拥有的钞票面值总额不会超过1,000。
Output

如果债务可以还清，则输出需要交换钞票的最少张数；如果不能还清，则输出“impossible”（注意单词全部小写，输出到文件时不要加引号）。
Sample Input
输入一
10 0 0
0 1 0 0 0 0
0 0 0 3 0 10
0 0 3 0 0 0

输入二
-10 -10 -10
0 0 0 0 0 0
0 0 0 0 0 0
0 0 0 0 0 0
Sample Output
输出一
5

输出二
0
HINT

对于100%的数据，x1、x2、x3 ≤ |1,000|。

囧，为了让pascal调试的时候不怎么卡，把循环队列调小了，一开始打的是没剪枝的，直接冲突了，查了半天没查出来

就是一个动态规划，dp[i,j,k]表示用到第i种钞票，A有j元钱，B有k元钱的最小交换次数

我们从小钞票开始，因为小钞票可以合成大钞票，大钞票不能当成小钞票

然后就可以加一个剪枝，如果现在的钱与最终的钱的差值不可能用i以后的钞票得到（用最小公倍数判断），那么这个状态就没有用了，所以就不要加入队列

const
    gold:array[1..6]of longint=(1,5,10,20,50,100);
    h:array[1..6]of longint=(5,10,10,10,100,100);
    maxq=100000;
var
    f:array[0..6,0..1000,0..1000]of longint;
    g:array[0..3]of longint;
    s:array[1..3,0..6]of longint;
    q:array[0..maxq,1..3]of longint;
    head,tail,sum:longint;
 
procedure init;
var
    x,y,z,i,j:longint;
begin
    read(x,y,z);
    g[1]:=z-x;
    g[2]:=x-y;
    g[3]:=y-z;
    fillchar(f,sizeof(f),1);
    for i:=1 to 3 do
      for j:=6 downto 1 do
        begin
          read(s[i,j]);
          inc(g[i],s[i,j]*gold[j]);
          inc(sum,s[i,j]*gold[j]);
        end;
    head:=1;
    tail:=2;
    q[1,1]:=0;
    q[1,2]:=g[1]-(z-x);
    q[1,3]:=g[2]-(x-y);
    f[0,g[1]-(z-x),g[2]-(x-y)]:=0;
end;
 
function min(x,y:longint):longint;
begin
    if x<y then exit(x);
    exit(y);
end;
 
procedure work;
var
    i,j,k:longint;
    a:array[0..3]of longint;
begin
    while head<>tail do
      begin
        if q[head,1]=6 then break;
        a[1]:=q[head,2];
        a[2]:=q[head,3];
        a[3]:=sum-a[1]-a[2];
        for i:=1 to 3 do
          begin
            for j:=0 to s[i mod 3+1,q[head,1]+1] do
              for k:=0 to s[(i mod 3+1)mod 3+1,q[head,1]+1] do
                begin
                  inc(a[i],gold[q[head,1]+1]*(j+k));
                  dec(a[i mod 3+1],j*gold[q[head,1]+1]);
                  dec(a[(i mod 3+1)mod 3+1],k*gold[q[head,1]+1]);
                  if f[q[head,1]+1,a[1],a[2]]>100000 then
                  if (abs(a[1]-g[1])mod h[q[head,1]+1]=0) and (abs(a[2]-g[2])mod h[q[head,1]+1]=0) then
                  begin
                    q[tail,1]:=q[head,1]+1;
                    q[tail,2]:=a[1];
                    q[tail,3]:=a[2];
                    tail:=tail mod maxq+1;
                  end;
                  f[q[head,1]+1,a[1],a[2]]:=min(f[q[head,1]+1,a[1],a[2]],f[q[head,1],q[head,2],q[head,3]]+j+k);
                  dec(a[i],gold[q[head,1]+1]*(j+k));
                  inc(a[i mod 3+1],j*gold[q[head,1]+1]);
                  inc(a[(i mod 3+1)mod 3+1],k*gold[q[head,1]+1]);
                end;
            for j:=0 to s[i,q[head,1]+1] do
              for k:=0 to j do
                begin
                  dec(a[i],gold[q[head,1]+1]*j);
                  inc(a[i mod 3+1],(j-k)*gold[q[head,1]+1]);
                  inc(a[(i mod 3+1)mod 3+1],k*gold[q[head,1]+1]);
                  if f[q[head,1]+1,a[1],a[2]]>100000 then
                  if (abs(a[1]-g[1])mod h[q[head,1]+1]=0) and (abs(a[2]-g[2])mod h[q[head,1]+1]=0) then
                  begin
                    q[tail,1]:=q[head,1]+1;
                    q[tail,2]:=a[1];
                    q[tail,3]:=a[2];
                    tail:=tail mod maxq+1;
                  end;
                  f[q[head,1]+1,a[1],a[2]]:=min(f[q[head,1]+1,a[1],a[2]],f[q[head,1],q[head,2],q[head,3]]+j);
                  inc(a[i],gold[q[head,1]+1]*j);
                  dec(a[i mod 3+1],(j-k)*gold[q[head,1]+1]);
                  dec(a[(i mod 3+1)mod 3+1],k*gold[q[head,1]+1]);
                end;
          end;
        head:=head mod maxq+1;
      end;
    if f[6,g[1],g[2]]<10000 then write(f[6,g[1],g[2]])
    else write('impossible');
end;
 
begin
    init;
    work;
end.