1034: [ZJOI2008]泡泡堂BNB

Description

第XXXX届NOI期间，为了加强各省选手之间的交流，组委会决定组织一场省际电子竞技大赛，每一个省的代表队由n名选手组成，比赛的项目是老少咸宜的网络游戏泡泡堂。每一场比赛前，对阵双方的教练向组委会提交一份参赛选手的名单，决定了选手上场的顺序，一经确定，不得修改。比赛中，双方的一号选手，二号选手……，n号选手捉对厮杀，共进行n场比赛。每胜一场比赛得2分，平一场得1分，输一场不得分。最终将双方的单场得分相加得出总分，总分高的队伍晋级(总分相同抽签决定)。作为浙江队的领队，你已经在事先将各省所有选手的泡泡堂水平了解的一清二楚，并将其用一个实力值来衡量。为简化问题，我们假定选手在游戏中完全不受任何外界因素干扰，即实力强的选手一定可以战胜实力弱的选手，而两个实力相同的选手一定会战平。由于完全不知道对手会使用何种策略来确定出场顺序，所以所有的队伍都采取了这样一种策略，就是完全随机决定出场顺序。当然你不想这样不明不白的进行比赛。你想事先了解一下在最好与最坏的情况下，浙江队最终分别能得到多少分。
Input

输入的第一行为一个整数n，表示每支代表队的人数。接下来n行，每行一个整数，描述了n位浙江队的选手的实力值。接下来n行，每行一个整数，描述了你的对手的n位选手的实力值。 20％的数据中，1<=n<=10； 40％的数据中，1<=n<=100； 60％的数据中，1<=n<=1000； 100％的数据中，1<=n<=100000，且所有选手的实力值在0到10000000之间。
Output

包括两个用空格隔开的整数，分别表示浙江队在最好与最坏的情况下分别能得多少分。不要在行末输出多余的空白字符。
Sample Input
2
1
3
2
4
Sample Output
2 0
样例说明
我们分别称4位选手为A,B,C,D。则可能出现以下4种对战方式，最好情况下可得2分，最坏情况下得0分。
一 二 三 四
浙江 ??? 结果 浙江 ??? 结果 浙江 ??? 结果 浙江 ??? 结果
一号选手 A C 负 A D 负 B C 胜 B D 负
二号选手 B D 负 B C 胜 A D 负 A C 负
总得分 0 2 2 0

水一题......

跟田忌赛马差不多，贪心得到最优解，但是不能直接贪心得到最差解，而是贪心得到对方的最优解然后减一下得到我方的最差解

每一次都做下面这个过程，直到全部比完

1.如果我方最弱可以战胜对方最弱，则挑战之，然后退出，否则转2

2.若果我方最强可以战胜对方最强，则挑战之，然后退出，否则转3

3.用我方最弱挑战对方最强（此时只可能平局或失败），退出

const
    maxn=100010;
type
    aa=array[0..maxn]of longint;
var
    a,b:aa;
    n:longint;

procedure init;
var
    i:longint;
begin
    read(n);
    for i:=1 to n do
      read(a[i]);
    for i:=1 to n do
      read(b[i]);
end;

procedure sort(l,r:longint;var a:aa);
var
    i,j,y,t:longint;
begin
    i:=l;
    j:=r;
    y:=a[(l+r)>>1];
    repeat
      while a[i]<y do
        inc(i);
      while a[j]>y do
        dec(j);
      if i<=j then
      begin
        t:=a[i];
        a[i]:=a[j];
        a[j]:=t;
        inc(i);
        dec(j);
      end;
    until i>j;
    if i<r then sort(i,r,a);
    if j>l then sort(l,j,a);
end;

function work(var a,b:aa):longint;
var
    h1,h2,t1,t2:longint;
begin
    h1:=1;h2:=1;
    t1:=n;t2:=n;
    work:=0;
    while h1<=t1 do
      begin
        if a[h1]>b[h2] then
          begin
            inc(work,2);
            inc(h1);
            inc(h2);
          end
        else
          if a[t1]>b[t2] then
            begin
              inc(work,2);
              dec(t1);
              dec(t2);
            end
          else
            if a[h1]=b[t2] then
              begin
                inc(work);
                inc(h1);
                dec(t2);
              end
            else
              begin
                inc(h1);
                dec(t2);
              end;
      end;
end;

begin
    init;
    sort(1,n,a);
    sort(1,n,b);
    writeln(work(a,b),' ',n<<1-work(b,a));
end.