1062: [NOI2008]糖果雨

题目链接：http://www.lydsy.com:808/JudgeOnline/problem.php?id=1062

神题一个，直接讲思路了（全都是看别人的）

首先我们把一个云用一个平面上的点（t，length）表示，t表示云的左端到0时的时间，因为运动周期为len*2，所以mod len*2

然后我们要做的就是回答询问(t,l,r)

对于时间>t的点，时间不超过t+r，因为超过t+r，云的左端点就到了r的右边，然后length要在（l-（时间-t），r-（时间-t））之间
对于时间<t的点，时间不小于t-r，因为小于t-r，云的左端点就到了r的右边，然后length要在（l-（t-时间），r-（t-时间））之间

我们要求的答案就是在这两个平行四边形的内部的点的个数，用两个树状数组维护平行四边形内部点的个数（一个左偏45度，一个右偏45度）

实际情况要求4个平行四边形，因为有可能t+r或t-r越界

const
        maxl=1010;
        maxn=1000010;
type
        arr=array[0..maxl*2,0..maxl*4]of longint;
var
        a,b:arr;
        t,l:array[0..maxn]of longint;
        n,len:longint;

procedure add(var a:arr;x,y,z:longint);
var
        i:longint;
begin
        inc(x);
        inc(y);
        if (x<=0) or (y<=0) then exit;
        while x<=len*2+1 do
          begin
            i:=y;
            while i<=len*4+1 do
              begin
                inc(a[x,i],z);
                i:=i+(i and(-i));
              end;
            x:=x+(x and(-x));
          end;
end;

function sum(var a:arr;x,y:longint):longint;
var
        i:longint;
begin
        inc(x);
        inc(y);
        sum:=0;
        if x>len*2 then x:=len*2+1;
        if y>len*4 then y:=len*4+1;
        sum:=0;
        while x>0 do
          begin
            i:=y;
            while i>0 do
              begin
                inc(sum,a[x,i]);
                i:=i-(i and(-i));
              end;
            x:=x-(x and (-x));
          end;
end;

procedure add(x,y,z:longint);
begin
        add(a,x,y+x,z);
        add(b,x,y-x+len*2,z);
end;

function area(var a:arr;x1,y1,x2,y2:longint):longint;
begin
        exit(sum(a,x2,y2)+sum(a,x1-1,y1-1)-sum(a,x1-1,y2)-sum(a,x2,y1-1));
end;

procedure main;
var
        i,k,tt,cc,ll,rr,dd,s,ans:longint;
begin
        read(n,len);
        for i:=1 to n do
          begin
            read(k);
            case k of
              1:begin
                read(tt,cc,ll,rr,dd);
                t[cc]:=(tt-dd*ll+len*2)mod (len*2);
                l[cc]:=rr-ll;
                add(t[cc],l[cc],1);
              end;
              2:begin
                read(tt,ll,rr);
                tt:=tt mod (len*2);
                s:=longint(rr=len);
                ans:=area(a,tt,ll+tt,rr+tt,len*4)
                +area(a,0,ll+tt-len*2,rr+tt-len*2-s,len*4)
                +area(b,tt-rr+len*2+s,ll-tt,len*2,len*4)
                +area(b,tt-rr,ll-tt+len*2,tt-1,len*4);
                writeln(ans);
              end;
              3:begin
                read(tt,cc);
                add(t[cc],l[cc],-1);
              end;
            end;
          end;
end;

begin
        main;
end.