1072: [SCOI2007]排列perm

Description

给一个数字串s和正整数d, 统计s有多少种不同的排列能被d整除（可以有前导0）。例如123434有90种排列能被2整除，其中末位为2的有30种，末位为4的有60种。
Input

输入第一行是一个整数T，表示测试数据的个数，以下每行一组s和d，中间用空格隔开。s保证只包含数字0, 1, 2, 3, 4, 5, 6, 7, 8, 9.
Output

每个数据仅一行，表示能被d整除的排列的个数。
Sample Input
7
000 1
001 1
1234567890 1
123434 2
1234 7
12345 17
12345678 29

Sample Output
1
3
3628800
90
3
6
1398

HINT

在前三个例子中，排列分别有1, 3, 3628800种，它们都是1的倍数。 【限制】 20%的数据满足：s的长度不超过5, 1<=T<=5 50%的数据满足：s的长度不超过8 100%的数据满足：s的长度不超过10, 1<=d<=1000, 1<=T<=15,

状压dp

f[s,i]表示状态为s（用二进制表示选的数字的情况），余数为i的方案数

最后把重复的去掉，即除以每一种数字的个数的阶乘

var
        flag,f:array[0..1024,0..1000]of longint;
        x,y:array[0..1000000]of longint;
        t,time,d,n:longint;
        s:array[0..10]of longint;

procedure init;
var
        c:char;
begin
        read(c);
        n:=0;
        while c<>' ' do
          begin
            inc(n);
            s[n]:=ord(c)-ord('0');
            read(c);
          end;
        readln(d);
end;

procedure work;
var
        head,tail,i,j,k,nx,ny:longint;
begin
        flag[0,0]:=time;
        f[0,0]:=1;
        head:=1;
        tail:=1;
        x[1]:=0;
        y[1]:=0;
        while head<=tail do
          begin
            for i:=1 to n do
              if x[head] and (1<<(i-1))=0 then
              begin
                nx:=x[head]+1<<(i-1);
                ny:=(y[head]*10+s[i])mod d;
                if flag[nx,ny]<>time then
                begin
                  flag[nx,ny]:=time;
                  f[nx,ny]:=0;
                  inc(tail);
                  x[tail]:=nx;
                  y[tail]:=ny;
                end;
                inc(f[nx,ny],f[x[head],y[head]]);
              end;
            inc(head);
          end;
        for i:=1 to n do
          begin
            k:=0;
            for j:=1 to i do
              if s[j]=s[i] then inc(k);
            f[1<<n-1,0]:=f[1<<n-1,0] div k;
          end;
        if flag[1<<n-1,0]=time then writeln(f[1<<n-1,0])
        else writeln(0); 
end;

begin
        readln(t);
        while t>0 do
          begin
            dec(t);
            inc(time);
            init;
            work;
          end;
end.