Uyuw's Concert POJ2451

裸半平面交，以前没写过，先写一遍再说

我越来越不注意细节了，最后才发现空间稍微开小了（没有开那个零头，他又要多4条边，就WA了）

const
    maxn=20010;
    eps=1e-7;
type
    point=record
      x,y:double;
    end;
    poly=record
      x,y,w:point;
    end;

var
    a:array[0..maxn]of poly;
    n:longint;

operator -(a,b:point)c:point;
begin
    c.x:=a.x-b.x;
    c.y:=a.y-b.y;
end;

operator +(a,b:point)c:point;
begin
    c.x:=a.x+b.x;
    c.y:=a.y+b.y;
end;

operator *(a:point;b:double)c:point;
begin
    c.x:=a.x*b;
    c.y:=a.y*b;
end;

operator *(a,b:point)c:double;
begin
    c:=a.x*b.y-a.y*b.x;
end;

function wh(a:point):longint;
begin
    with a do
      begin
        if abs(x)<eps then
          if y>eps then exit(2)
          else exit(4)
        else
          if abs(y)<eps then
            if x>eps then exit(1)
            else exit(3)
          else
            if x>eps then
              if y>eps then exit(1)
              else exit(4)
            else
              if y>eps then exit(2)
              else exit(3);
      end;
end;

procedure swap(var x,y:poly);
var
    t:poly;
begin
    t:=x;x:=y;y:=t;
end;

procedure sort(l,r:longint);
var
    i,j:longint;
    y:point;
begin
    i:=l;
    j:=r;
    y:=a[(l+r)>>1].w;
    repeat
      while (wh(a[i].w)<wh(y)) or ((wh(a[i].w)=wh(y)) and (y*a[i].w+eps<0)) do
        inc(i);
      while (wh(a[j].w)>wh(y)) or ((wh(a[j].w)=wh(y)) and (y*a[j].w>eps)) do
        dec(j);
      if i<=j then
      begin
        swap(a[i],a[j]);
        inc(i);
        dec(j);
      end;
    until i>j;
    if i<r then sort(i,r);
    if j>l then sort(l,j);
end;

procedure init;
var
    i:longint;
begin
    read(n);
    for i:=1 to n do
      with a[i] do
        begin
          read(x.x,x.y,y.x,y.y);
          w:=y-x;
        end;
    a[n+2].x.x:=10000;
    a[n+3].x.x:=10000;
    a[n+3].x.y:=10000;
    a[n+4].x.y:=10000;
    for i:=0 to 3 do
      begin
        a[n+i+1].y:=a[n+((i+1)mod 4)+1].x;
        a[n+i+1].w:=a[n+i+1].y-a[n+i+1].x;
      end;
    inc(n,4);
    sort(1,n);
end;

function get(a,b:poly):point;
var
    s1,s2:double;
begin
    s1:=a.w*(b.y-a.x);
    s2:=a.w*(b.x-a.x);
    if s1*s2>eps then s1:=-s1
    else
      begin
        s1:=abs(s1);
        s2:=abs(s2);
      end;
    if abs(s1+s2)<eps then get:=b.x
    else get:=b.x+(b.w*(s2/(s1+s2)));
end;

var
    q:array[0..maxn]of poly;
    d:array[0..maxn]of point;
    l,r:longint;
    ans:double;

procedure work;
var
    i:longint;
begin
    l:=1;
    r:=1;
    q[1]:=a[1];
    for i:=2 to n do
      begin
        while (l<r) and (a[i].w*(d[r-1]-a[i].x)+eps<0) do
          dec(r);
        while (l<r) and (a[i].w*(d[l]-a[i].x)+eps<0) do
          inc(l);
        inc(r);
        q[r]:=a[i];
        if abs(q[r-1].w*q[r].w)<eps then
        begin
          dec(r);
          if a[i].w*(q[r].x-a[i].x)<0 then q[r]:=a[i];
        end;
        d[r-1]:=get(q[r],q[r-1]);
      end;
    while (l<r) and (q[l].w*(d[r-1]-q[l].x)+eps<0) do
      dec(r);
    if l<r then d[r]:=get(q[l],q[r]);
    if r-l<=1 then writeln('0.0')
    else
      begin
        for i:=l to r-1 do
          ans:=ans+(d[i]*d[i+1])/2;
        ans:=ans+(d[r]*d[l])/2;
        ans:=abs(ans);
        if ans<eps then writeln('0.0')
        else writeln(ans:0:1);
      end;
end;

begin
    init;
    work;
end.