2124: 等差子序列

Description

给一个1到N的排列{Ai}，询问是否存在1<=p1=3），使得Ap1,Ap2,Ap3,…ApLen是一个等差序列。

Input

输入的第一行包含一个整数T，表示组数。下接T组数据，每组第一行一个整数N，每组第二行为一个1到N的排列，数字两两之间用空格隔开。

Output

对于每组数据，如果存在一个等差子序列，则输出一行“Y”，否则输出一行“N”。

Sample Input

2

3

1 3 2

3

3 2 1

Sample Output

N

Y

HINT

对于100%的数据，N<=10000，T<=7

首先觉得题目不错（2013年我竟然在wikioi过了，代码还很短，然后把代码翻出来，发现是暴力n方加优化代码。。。。。。汗，我当时怎么想的）

今天看到题目觉得没什么想法，于是就翻了题解http://seter.is-programmer.com/posts/31902.html

就是维护每一个数字a[i]之前出现a[i]-1,a[i]-2,a[i]-3...的出现情况和a[i]+1,a[i]+2,a[i]+3...的出现情况（用二进制）

如果这两个二进制数的第k位不同，那么就是a[i]-k在a[i]前出现了，a[i]+k在a[i]之后出现或者a[i]+k在a[i]前出现了，a[i]-k在a[i]之后出现，所以我们只要判断两个二进制不同，就可以用hash值来判断了（不放心的话可以做两个hash），用线段树维护hash值就行了

const
    maxn=10010;
    h=1000000007;
type
    node=record
      l,r,lc,rc:longint;
      h1,h2:int64;
    end;
var
    f:array[0..maxn*2]of node;
    a:array[0..maxn]of longint;
    p:array[0..maxn]of int64;
    t,n,tot:longint;

function min(x,y:longint):longint;
begin
    if x<y then exit(x);
    exit(y);
end;

function max(x,y:longint):longint;
begin
    if x>y then exit(x);
    exit(y);
end;

procedure add(x,now:longint);
var
    mid:longint;
begin
    if f[now].l=f[now].r then
    begin
      f[now].h1:=1;
      f[now].h2:=1;
      exit;
    end;
    mid:=(f[now].l+f[now].r)>>1;
    if x>mid then add(x,f[now].rc)
    else add(x,f[now].lc);
    f[now].h1:=(f[f[now].lc].h1*p[f[now].r-mid]+f[f[now].rc].h1)mod h;
    f[now].h2:=(f[f[now].rc].h2*p[mid-f[now].l+1]+f[f[now].lc].h2)mod h;
end;

procedure build(l,r:longint);
var
    now,mid:longint;
begin
    inc(tot);
    now:=tot;
    f[now].l:=l;
    f[now].r:=r;
    f[now].h1:=0;
    f[now].h2:=0;
    f[now].lc:=0;
    f[now].rc:=0;
    if l=r then exit;
    mid:=(l+r)>>1;
    f[now].lc:=tot+1;
    build(l,mid);
    f[now].rc:=tot+1;
    build(mid+1,r);
end;

function hash1(l,r,now:longint):int64;
var
    mid:longint;
begin
    if (l<=f[now].l) and (r>=f[now].r) then exit(f[now].h1);
    mid:=(f[now].l+f[now].r)>>1;
    if l>mid then exit(hash1(l,r,f[now].rc));
    if r<=mid then exit(hash1(l,r,f[now].lc));
    exit((hash1(l,r,f[now].lc)*p[min(r,f[now].r)-mid]+hash1(l,r,f[now].rc))mod h);
end;

function hash2(l,r,now:longint):int64;
var
    mid:longint;
begin
    if (l<=f[now].l) and (r>=f[now].r) then exit(f[now].h2);
    mid:=(f[now].l+f[now].r)>>1;
    if l>mid then exit(hash2(l,r,f[now].rc));
    if r<=mid then exit(hash2(l,r,f[now].lc));
    exit((hash2(l,r,f[now].rc)*p[mid-max(l,f[now].l)+1]+hash2(l,r,f[now].lc))mod h);
end;

procedure main;
var
    i:longint;
begin
    read(n);
    for i:=1 to n do
      read(a[i]);
    tot:=0;
    build(1,n);
    for i:=2 to n-1 do
      begin
        add(a[i-1],1);
        if hash1(a[i]-min(a[i]-1,n-a[i]),a[i],1)=hash2(a[i],a[i]+min(a[i]-1,n-a[i]),1) then continue;
        writeln('Y');
        exit;
      end;
    writeln('N');
end;

begin
    p[0]:=1;
    for t:=1 to maxn do
      p[t]:=p[t-1]*2 mod h;
    read(t);
    while t>0 do
      begin
        dec(t);
        main;
      end;
end.