2140: 稳定婚姻

Description

我国的离婚率连续7年上升，今年的头两季，平均每天有近5000对夫妇离婚，大城市的离婚率上升最快，有研究婚姻问题的专家认为，是与简化离婚手续有关。 25岁的姗姗和男友谈恋爱半年就结婚，结婚不到两个月就离婚，是典型的“闪婚闪离”例子，而离婚的导火线是两个人争玩电脑游戏，丈夫一气之下，把电脑炸烂。有社会工作者就表示，80后求助个案越来越多，有些是与父母过多干预有关。而根据民政部的统计，中国离婚五大城市首位是北京，其次是上海、深圳，广州和厦门，那么到底是什么原因导致我国成为离婚大国呢?有专家分析说，中国经济急速发展，加上女性越来越来越独立，另外，近年来简化离婚手续是其中一大原因。 ——以上内容摘自第一视频门户 现代生活给人们施加的压力越来越大，离婚率的不断升高已成为现代社会的一大问题。而其中有许许多多的个案是由婚姻中的“不安定因素”引起的。妻子与丈夫吵架后，心如绞痛，于是寻求前男友的安慰，进而夫妻矛盾激化，最终以离婚收场，类似上述的案例数不胜数。我们已知n对夫妻的婚姻状况，称第i对夫妻的男方为Bi，女方为Gi。若某男Bi与某女Gj曾经交往过（无论是大学，高中，亦或是幼儿园阶段，i≠j），则当某方与其配偶（即Bi与Gi或Bj与Gj）感情出现问题时，他们有私奔的可能性。不妨设Bi和其配偶Gi感情不和，于是Bi和Gj旧情复燃，进而Bj因被戴绿帽而感到不爽，联系上了他的初恋情人Gk……一串串的离婚事件像多米诺骨牌一般接踵而至。若在Bi和Gi离婚的前提下，这2n个人最终依然能够结合成n对情侣，那么我们称婚姻i为不安全的，否则婚姻i就是安全的。给定所需信息，你的任务是判断每对婚姻是否安全。

Input

第一行为一个正整数n，表示夫妻的对数；以下n行，每行包含两个字符串，表示这n对夫妻的姓名（先女后男），由一个空格隔开；第n+2行包含一个正整数m，表示曾经相互喜欢过的情侣对数；以下m行，每行包含两个字符串，表示这m对相互喜欢过的情侣姓名（先女后男），由一个空格隔开。

Output

输出文件共包含n行，第i行为“Safe”（如果婚姻i是安全的）或“Unsafe”（如果婚姻i是不安全的）。

Sample Input

【样例输入1】

2

Melanie Ashley

Scarlett Charles

1

Scarlett Ashley

【样例输入2】

2

Melanie Ashley

Scarlett Charles

2

Scarlett Ashley

Melanie Charles

Sample Output

【样例输出1】

Safe

Safe

【样例输出2】

Unsafe

Unsafe

【数据规模和约定】

对于100%的数据，所有姓名字符串中只包含英文大小写字母，大小写敏感，长度不大于8，保证每对关系只在输入文件中出现一次，输入文件的最后m行不会出现未在之前出现过的姓名，这2n个人的姓名各不相同，1≤n≤4000，0≤m≤20000。

我们判断一个匹配是否一定会选，一般都是拆掉之后看有木有完备匹配，但是这题不可能是这样做的

判断是否是必选边其实还有一种方法，就是看这条边是否在一条增广环上，如果是，那这条边就不是必选边，如果不是，那就是必选边

判断边是否在环上，我们可以tarjan求强连通分量，然后看边的两个端点是否在同一个强连通分量里

const
    maxn=4040;
    maxm=20020;
type
    node=array['A'..'z']of longint;
var
    tree:array[0..maxn*20]of node;
    id:array[0..maxn*20]of longint;
    next,last:array[0..maxm+maxn]of longint;
    a,b,first:array[0..maxn*2]of longint;
    n,m,cnt,tot,num:longint;

procedure insert(x,y:longint);
begin
    inc(num);
    last[num]:=y;
    next[num]:=first[x];
    first[x]:=num;
end;

function nextt(x:longint;c:char):longint;
begin
    if tree[x,c]>0 then exit(tree[x,c]);
    inc(tot);
    tree[x,c]:=tot;
    exit(tot);
end;

function find(s:string):longint;
var
    i,k:longint;
begin
    k:=0;
    for i:=1 to length(s) do
      k:=nextt(k,s[i]);
    if id[k]>0 then exit(id[k]);
    inc(cnt);
    id[k]:=cnt;
    exit(cnt);
end;

procedure get(var s1,s2:string);
var
    c:char;
begin
    read(c);
    s1:='';
    while c<>' ' do
      begin
        s1:=s1+c;
        read(c);
      end;
    readln(s2);
end;

procedure init;
var
    i:longint;
    s1,s2:string;
begin
    readln(n);
    for i:=1 to n do
      begin
        get(s1,s2);
        a[i]:=find(s1);
        b[i]:=find(s2);
        insert(a[i],b[i]);
      end;
    readln(m);
    for i:=1 to m do
      begin
        get(s1,s2);
        insert(find(s2),find(s1));
      end;
end;

var
    flag:array[0..maxn*2]of boolean;
    dfn,low,z,c:array[0..maxn*2]of longint;
    s,time:longint;

procedure dfs(x:longint);
var
    i:longint;
begin
    inc(time);
    dfn[x]:=time;
    low[x]:=time;
    flag[x]:=true;
    inc(s);
    z[s]:=x;
    i:=first[x];
    while i<>0 do
      begin
        if dfn[last[i]]=0 then
          begin
            dfs(last[i]);
            if low[x]>low[last[i]] then low[x]:=low[last[i]];
          end
        else
          if flag[last[i]] and (low[x]>low[last[i]]) then low[x]:=low[last[i]];
        i:=next[i];
      end;
    if dfn[x]=low[x] then
    while z[s+1]<>x do
      begin
        c[z[s]]:=x;
        flag[z[s]]:=false;
        dec(s);
      end;
end;

procedure tarjan;
var
    i:longint;
begin
    for i:=1 to n do
      if dfn[a[i]]=0 then dfs(a[i]);
    for i:=1 to n do
      if c[a[i]]=c[b[i]] then writeln('Unsafe')
      else writeln('Safe');
end;

begin
    init;
    tarjan;
end.