2879: [Noi2012]美食节

Description

CZ市为了欢迎全国各地的同学，特地举办了一场盛大的美食节。作为一个喜欢尝鲜的美食客，小M自然不愿意错过这场盛宴。他很快就尝遍了美食节所有的美食。然而，尝鲜的欲望是难以满足的。尽管所有的菜品都很可口，厨师做菜的速度也很快，小M仍然觉得自己桌上没有已经摆在别人餐桌上的美食是一件无法忍受的事情。于是小M开始研究起了做菜顺序的问题，即安排一个做菜的顺序使得同学们的等待时间最短。小M发现，美食节共有n种不同的菜品。每次点餐，每个同学可以选择其中的一个菜品。总共有m个厨师来制作这些菜品。当所有的同学点餐结束后，菜品的制作任务就会分配给每个厨师。然后每个厨师就会同时开始做菜。厨师们会按照要求的顺序进行制作，并且每次只能制作一人份。此外，小M还发现了另一件有意思的事情: 虽然这m个厨师都会制作全部的n种菜品，但对于同一菜品，不同厨师的制作时间未必相同。他将菜品用1, 2, ..., n依次编号，厨师用1, 2, ..., m依次编号，将第j个厨师制作第i种菜品的时间记为 ti,j 。小M认为：每个同学的等待时间为所有厨师开始做菜起，到自己那份菜品完成为止的时间总长度。换句话说，如果一个同学点的菜是某个厨师做的第k道菜，则他的等待时间就是这个厨师制作前k道菜的时间之和。而总等待时间为所有同学的等待时间之和。现在，小M找到了所有同学的点菜信息: 有 pi 个同学点了第i种菜品（i=1, 2, ..., n）。他想知道的是最小的总等待时间是多少。

Input


 输入文件的第1行包含两个正整数n和m，表示菜品的种数和厨师的数量。 第2行包含n个正整数，其中第i个数为pi，表示点第i种菜品的人数。 接下来有n行，每行包含m个非负整数，这n行中的第i行的第j个数为ti,j，表示第j个厨师制作第i种菜品所需的时间。 输入文件中每行相邻的两个数之间均由一个空格隔开，行末均没有多余空格。
Output


 输出仅一行包含一个整数，为总等待时间的最小值。
Sample Input

3 2
3 1 1
5 7
3 6
8 9
Sample Output

47

【样例说明】
厨师1先制作1份菜品2，再制作2份菜品1。点这3道菜的3个同学的等待时间分别为3，3+5=8，3+5+5=13。
厨师2先制作1份菜品1，再制作1份菜品3。点这2道菜的2个同学的等待时间分别为7，7+9=16。
总等待时间为3+8+13+7+16=47。
虽然菜品1和菜品3由厨师1制作更快，如果这些菜品都由厨师1制作，总等待时间反而更长。如果按上述的做法，将1份菜品1和1份菜品3调整到厨师2制作，这样厨师2不会闲着，总等待时间更短。
可以证明，没有更优的点餐方案。


【数据规模及约定】
对于100%的数据，n <= 40, m <= 100, p <= 800, ti,j <= 1000（其中p = ∑pi，即点菜同学的总人数）。
每组数据的n、m和p值如下：
测试点编号 n m p
1 n = 5 m = 5 p = 10
2 n = 40 m = 1 p = 400
3 n = 40 m = 2 p = 300
4 n = 40 m = 40 p = 40
5 n = 5 m = 40 p = 100
6 n = 10 m = 50 p = 200
7 n = 20 m = 60 p = 400
8 n = 40 m = 80 p = 600
9 n = 40 m = 100 p = 800
10 n = 40 m = 100 p = 800

费用流很明显啦，把做菜的顺序倒过来，那么第一个人做的第一个菜贡献是一倍，第二个菜的贡献是两倍，依此类推

但是为了省时，所以动态加边，当一个人的第k个菜做好了，我们就加一个点，表示他做第k+1个菜

const
    maxn=110;
    maxm=110;
    maxd=1300;
    maxe=3000000;
var
    a:array[0..maxn,0..maxm]of longint;
    t:array[0..maxn]of longint;
    flag:array[0..maxd]of boolean;
    first,who,q,dis,pre:array[0..maxd]of longint;
    last,next,w,liu:array[0..maxe]of longint;
    n,m,tot,cnt,sum,ans,l,r:longint;
 
procedure insert(x,y,ww,l:longint);
begin
    inc(tot);
    last[tot]:=y;
    next[tot]:=first[x];
    first[x]:=tot;
    w[tot]:=ww;liu[tot]:=l;
end;
 
procedure spfa;
var
    i:longint;
begin
    l:=0;r:=1;q[0]:=0;dis[0]:=0;
    for i:=1 to cnt do dis[i]:=maxlongint;
    for i:=1 to cnt do flag[i]:=false;
    flag[maxd]:=false;
    flag[0]:=true;
    dis[maxd]:=maxlongint;
    while l<>r do
        begin
            i:=first[q[l]];
            while i<>0 do
                begin
                    if (liu[i]>0) and (dis[q[l]]+w[i]<dis[last[i]]) then
                    begin
                        if flag[last[i]]=false then
                        begin
                            q[r]:=last[i];r:=(r+1) mod maxd;
                            flag[last[i]]:=true;
                        end;
                        dis[last[i]]:=dis[q[l]]+w[i];pre[last[i]]:=i;
                    end;
                    i:=next[i];
                end;
            flag[q[l]]:=false;l:=(l+1)mod maxd;
        end;
    inc(ans,dis[maxd]);
    i:=maxd;
    while i<>0 do
        begin
            dec(liu[pre[i]]);inc(liu[pre[i]xor 1]);
            i:=last[pre[i]xor 1];
        end;
    i:=maxd;
    while last[pre[i]xor 1]<>0 do
        i:=last[pre[i]xor 1];
    inc(cnt);
    who[cnt]:=who[i];
    inc(t[who[cnt]]);
    insert(0,cnt,0,1);insert(cnt,0,0,0);
    for i:=1 to m do
        begin
            insert(cnt,n+i,a[who[cnt],i]*t[who[cnt]],1);
            insert(n+i,cnt,-a[who[cnt],i]*t[who[cnt]],0);
        end;
end;
 
procedure main;
var
    i,j,x:longint;
begin
    read(m,n);
    tot:=1;
    cnt:=n+m;
    for i:=1 to m do
        begin
            read(x);inc(sum,x);
            insert(n+i,maxd,0,x);
            insert(maxd,n+i,0,0);
        end;
    for i:=1 to m do
        for j:=1 to n do
            read(a[j,i]);
    for i:=1 to n do
        begin
            insert(0,i,0,1);
            insert(i,0,0,0);
            t[i]:=1;who[i]:=i;
        end;
    for i:=1 to n do
        for j:=1 to m do
            begin
                insert(i,n+j,a[i,j],1);
                insert(n+j,i,-a[i,j],0);
            end;
    for i:=1 to sum do
        spfa;
    writeln(ans);
end;
 
begin
    main;
end.