2435: [Noi2011]道路修建

Description

在 W 星球上有 n 个国家。为了各自国家的经济发展，他们决定在各个国家
之间建设双向道路使得国家之间连通。但是每个国家的国王都很吝啬，他们只愿
意修建恰好 n – 1条双向道路。 每条道路的修建都要付出一定的费用， 这个费用等于道路长度乘以道路两端的国家个数之差的绝对值。例如，在下图中，虚线所示道路两端分别有 2 个、4个国家，如果该道路长度为 1，则费用为1×|2 – 4|=2。图中圆圈里的数字表示国家的编号。


由于国家的数量十分庞大，道路的建造方案有很多种，同时每种方案的修建
费用难以用人工计算，国王们决定找人设计一个软件，对于给定的建造方案，计
算出所需要的费用。请你帮助国王们设计一个这样的软件。
Input


输入的第一行包含一个整数n，表示 W 星球上的国家的数量，国家从 1到n
编号。接下来 n – 1行描述道路建设情况，其中第 i 行包含三个整数ai、bi和ci，表
示第i 条双向道路修建在 ai与bi两个国家之间，长度为ci。


Output

输出一个整数，表示修建所有道路所需要的总费用。
Sample Input

6
1 2 1
1 3 1
1 4 2
6 3 1
5 2 1
Sample Output

20
HINT



n = 1,000,000 1≤ai, bi≤n

0 ≤ci≤ 10^6

卡时间卡的真厉害，wikioi上总时间1.5s左右过了，BZOJ上最后没办法cheat最大的点，但是还是9s+过的

const
    maxn=1000100;
var
    first:array[0..maxn]of longint;
    next,last,len:array[0..maxn*2]of longint;
    n,tot:longint;
    ans:int64;
 
procedure insert(x,y:longint);
begin
    inc(tot);
    last[tot]:=y;
    next[tot]:=first[x];
    first[x]:=tot;
end;
 
var
    q,size,fa:array[0..maxn]of longint;
    l,r:longint;
 
procedure bfs;
var
    i,u,v:longint;
begin
    l:=1;r:=1;q[1]:=1;
    while l<=r do
        begin
            u:=q[l];
            i:=first[u];
            while i<>0 do
                begin
                    v:=last[i];
                    if v<>fa[u] then
                    begin
                        fa[v]:=u;
                        inc(r);q[r]:=v;
                    end;
                    i:=next[i];
                end;
            inc(l);
        end;
    for l:=n downto 1 do
        begin
            u:=q[l];inc(size[u]);
            i:=first[u];
            while i<>0 do
                begin
                    v:=last[i];
                    if v<>fa[u] then
                    begin
                        inc(size[u],size[v]);
                        inc(ans,int64(len[i])*abs(size[v]<<1-n));
                    end;
                    i:=next[i];
                end;
        end;
end;
 
procedure main;
var
    i,x,y:longint;
begin
    read(n);
    for i:=1 to n-1 do
        begin
            read(x,y,len[tot+1]);
            len[tot+2]:=len[tot+1];
            insert(x,y);insert(y,x);
        end;
    bfs;
    writeln(ans);
end;
 
begin
    main;
end.