Unity Shader 噪声消融特效

噪声是个很神奇的东西，以前接触的时候就是在自动生成地图上，因为噪声本来就近自然所以，很多特效也是基于噪声的。

前几篇文章介绍了纹理和光照，这回其实也就是用这么多。就是光照加一个噪声的法线纹理。

你可能就玩过一款游戏，剑灵，游戏中怪物死亡的时候会有一种消融的效果。让我们来看一看是怎么实现的。

下面三个图片分别是BurnAmount = 0、BurnAmount = 0.25、BurnAmount = 0.5时的效果。

  

这里我们用两个Pass来处理这个效果

• 第一个Pass：渲染模型的正常颜色和消融的混合颜色
• 第二个Pass：处理消融的阴影，如不特殊处理则影子不会有消融效果。

下面给出代码（有必要的注释）

Shader "Shader/Shader"
{
    Properties
    {
        _MainTex ("Main Tex", 2D) = "white" {}
        // 法线贴图
        _BumpMap ("Bump Map", 2D) = "bump" {}
        // 噪声贴图
        _BurnMap ("Burn Map", 2D) = "white" {}
        // 控制消融程度
        _BurnAmount ("Burn Amount", Range(0, 1)) = 0
        // 控制模型烧焦效果的线宽
        _LineWidth ("Burn Line Width", Range(0.0, 0.2)) = 0.1
        // 烧焦边缘的颜色
        _BurnColor ("Burn Color", Color) = (1, 0, 0, 1)
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" "Queue"="Geometry" }

        Pass
        {
            Tags { "LightMode"="ForwardBase" }
            
            // 所有面都不被剔除，因为消融的时候应该可以看到物体的内部。
            Cull Off

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // 为得到正确的光照设置的编译指令
            #pragma multi_compile_fwdbase

            #include "Lighting.cginc"
            #include "AutoLight.cginc"

            sampler2D _MainTex;
            sampler2D _BumpMap;
            sampler2D _BurnMap;
            float4 _MainTex_ST;
            float4 _BumpMap_ST;
            float4 _BurnMap_ST;
            fixed _BurnAmount;
            fixed _LineWidth;
            fixed4 _BurnColor;

            struct a2v
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                float2 texcoord : TEXCOORD0;
                fixed4 tangent : TANGENT;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                float2 uvMainTex : TEXCOORD0;
                float2 uvBumpMap : TEXCOORD1;
                float2 uvBurnMap : TEXCOORD2;
                // 切线视图的光照方向
                float3 lightDir : TEXCOORD3;
                float3 worldPos : TEXCOORD4;
                // Shader 阴影宏：用于对阴影纹理采样的坐标
                // 参数：一个可用的差值寄存器的索引值，用世界的顶点坐标。即5（从0开始）
                SHADOW_COORDS(5)
            };

            v2f vert(a2v v)
            {
                v2f o;

                o.pos = UnityObjectToClipPos(v.vertex);

                o.uvMainTex = TRANSFORM_TEX(v.texcoord, _MainTex);
                o.uvBumpMap = TRANSFORM_TEX(v.texcoord, _BumpMap);
                o.uvBurnMap = TRANSFORM_TEX(v.texcoord, _BurnMap);

                TANGENT_SPACE_ROTATION;
                o.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex));
                o.worldPos = UnityObjectToWorldDir(v.vertex);

                // 阴影宏：在顶点着色器中计算上一步中声明的阴影纹理坐标
                TRANSFER_SHADOW(o);

                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                // 取噪声贴图进行采样
                fixed3 burn = tex2D(_BurnMap, i.uvBurnMap);
                // 用于剔除像素点，if (采样结果-消融程度阀值 > 0) 存留 or 丢弃
                clip(burn.r - _BurnAmount);

                fixed3 albedo = tex2D(_MainTex, i.uvMainTex).rgb;

                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;

                fixed3 tangentLightDir = normalize(i.lightDir);
                fixed3 tangentNormal = UnpackNormal(tex2D(_BumpMap, i.uvBumpMap));
                fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(tangentLightDir, tangentNormal));

                // 阴影宏：计算阴影值，最后与漫反射的颜色叠加
                UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);

                // smoothsetp(e1,e2,x)平滑过度函数
                // 原理：if (x < e1) 结果 = 0
                // if (x > e2) 结果 = 1
                // if (e1 < x < e2) 结果 = 3 * pow(x, 2) - 2 * pow(x, 3)
                // t = 0时，该像素为正常的模型颜色
                // t = 1时，该像素位于消融的边界处
                fixed t = 1 - smoothstep(0.0, _LineWidth, burn.r - _BurnAmount);

                // 最终颜色，在消融和正常中差值，系数为t
                fixed3 finalColor = lerp(ambient + diffuse * atten, _BurnColor, t);

                return fixed4(finalColor, 1);
            }
            ENDCG
        }

        // 此Pass是处理阴影的，我们需要按照正常的Pass的处理来剔除片元或进行顶点动画。以便阴影可以和物体正常渲染的结果相匹配。
        Pass
        {
            // 光照模式定义为阴影
            Tags { "LightMode"="ShadowCaster" }

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // 处理阴影的编译指令
            #pragma multi_compile_shadowcaster
            
            #include "UnityCG.cginc"

            fixed _BurnAmount;
            sampler2D _BurnMap;
            float4 _BurnMap_ST;

            struct a2v
            {
                float4 vertex : POSITION;
                float2 texcoord : TEXCOORD0;
                float3 normal : NORMAL;
                float4 tangent: TANGENT;
            };

            struct v2f
            {
                // 定义阴影投射需要定义的变量
                V2F_SHADOW_CASTER;
                float2 uvBurnMap : TEXCOORD0;
            };
            
            v2f vert (a2v v)
            {
                v2f o;

                // 填充V2F_SHADOW_CASTER定义的变量
                TRANSFER_SHADOW_CASTER_NORMALOFFSET(o)
                o.uvBurnMap = TRANSFORM_TEX(v.texcoord, _BurnMap);

                return o;
            }
            
            fixed4 frag (v2f i) : SV_Target
            {
                fixed3 burn = tex2D(_BurnMap, i.uvBurnMap);
                
                clip(burn - _BurnAmount);

                // 让Unity完成阴影投射
                SHADOW_CASTER_FRAGMENT(i)
            }
            ENDCG
        }
    }
}

本文引自Unity Shader 入门精要