美化图片滤镜

效果：

　　

转载请注明出处：http://www.cnblogs.com/TheViper/p/4031768.html 

新浪微博，美图秀秀还有其他的那些都是把滤镜的swf编译进了他的flex里面，不好取出，只有qq空间的是按需加载，点击一个滤镜，加载一个滤镜swf，所以qq空间，对不起了。。。

1.获取滤镜的swf，去qq空间的美化图片，点击一个滤镜，用firebug之类的得到滤镜，最后得到的滤镜：

"abao.swf","colorfulmood.swf","enhance.swf","lordkelvin.swf","blackenhance.swf","sweetjelly.swf","lightred.swf","aladin.swf","mellow.swf","rainbow.swf","romanticstar.swf","smokedval.swf","sweetlight.swf","sweet.swf","nashville.swf","lomored.swf"

对应的滤镜名称：

"阿宝色","缤纷心情","自动增强","枫叶","黑白画映","琥珀","亮红","潘多拉","午茶","彩虹","浪漫星光","掠影","甜美光影","甜美可人","往昔","晚秋"

2.用Loader类加载滤镜swf,对swf的content var a:BitmapData =content.execute(bmpData);bmpData 是目标图片的bitmapdata..那个execute方法是接口暴露出来渲染滤镜效果的方法，，qq空间美化图片里面美化和磨皮的swf也是用的类似方法。

其他都是些小细节，很简单的。

package 
{
    import flash.display.*;
    import flash.events.Event;
    import flash.net.*;
    import fl.controls.*;
    import flash.events.*;
    import flash.geom.*;
    import flash.utils.getDefinitionByName;
    import bloom.containers.*;
    import bloom.core.Margin;
    import bloom.themes.*;
    import bloom.*;
    import flash.text.*;
    import com.adobe.images.JPGEncoder;
    import flash.utils.ByteArray;
    import flash.external.ExternalInterface;

    public class Main extends MovieClip
    {
        var urlLoader:Loader=new Loader();
        var urlLoader1:Loader=new Loader();
        var image:DisplayObject;
        private var _bmd:BitmapData;
        private var scrollContainer:ScrollContainer;
        private var filter_bm:Bitmap;
        private var ori_height;
        private var ori_width;
        private var filter_name=["阿宝色","缤纷心情","自动增强","枫叶","黑白画映","琥珀","亮红","潘多拉","午茶","彩虹","浪漫星光","掠影","甜美光影",
         "甜美可人","往昔","晚秋"];
        private var filter_file = ["abao.swf","colorfulmood.swf","enhance.swf","lordkelvin.swf","blackenhance.swf","sweetjelly.swf","lightred.swf",
        "aladin.swf","mellow.swf","rainbow.swf","romanticstar.swf","smokedval.swf","sweetlight.swf","sweet.swf","nashville.swf","lomored.swf"];
        public function Main()
        {
            urlLoader1.load(new URLRequest("2.jpg"));
            urlLoader1.contentLoaderInfo.addEventListener( Event.COMPLETE,load_complete);
            ThemeBase.setTheme(new ColorTheme());
            scrollContainer = new ScrollContainer(null);
            scrollContainer.content.addChild(filter_list);
            scrollContainer.margin.reset(0, 0, 0, 0);
            scrollContainer.direction = ScrollContainer.VERTICALLY;
            scrollContainer.calculateContentSize();
            scrollContainer.setScrollBar(false, true);
            scrollContainer.width = 185;
            scrollContainer.height = 516;
            stage.addChild(scrollContainer);
            add_flag();
            filter_list.selected_filter.visible = false;
            filter_list.wrap_small_img.visible = false;
            filter_list.addEventListener(MouseEvent.MOUSE_OUT,filter_out);
            back_btn.addEventListener(MouseEvent.CLICK,back_img);
            ExternalInterface.addCallback("beautify_image_upload",upload_handler);
        }
        private function add_flag():void
        {
            for (var i=1; i<17; i++)
            {
                var cls:Class = getDefinitionByName("filter"+i) as Class;
                var bmpdata:BitmapData = new cls(0,0);
                var bmp:Bitmap = new Bitmap(bmpdata);
                var item:Sprite=new Sprite();
                var s:Sprite=new Sprite();
                var tf:TextField=new TextField();
                s.x =(i%2==0?8:90);
                s.y=Math.floor((i-1)/2)*102+8;
                s.name = "filter" + i;
                tf.text = filter_name[i - 1];
                tf.y = 78;
                tf.x = 0;
                tf.width = 82;
                tf.autoSize = TextFieldAutoSize.CENTER;
                tf.selectable = false;
                s.addChild(bmp);
                s.addChild(tf);
                s.buttonMode = true;
                s.addEventListener(MouseEvent.MOUSE_OVER,filter_hover);
                s.addEventListener(MouseEvent.CLICK,filter_click);
                filter_list.addChild(s);
            }
        }
        private function back_img(event:MouseEvent):void
        {
            image.visible = true;
            if (img_panel.numChildren > 2)
            {
                img_panel.removeChildAt(2);
            }
        }
        private function filter_out(event:MouseEvent):void
        {
            filter_list.wrap_small_img.visible = false;
        }
        private function filter_click(event:MouseEvent):void
        {
            filter_list.selected_filter.x = event.target.x;
            filter_list.selected_filter.y = event.target.y;
            filter_list.selected_filter.visible = true;
            var i = event.target.name.substring(6);
            var urlRequest:URLRequest = new URLRequest("filter/"+filter_file[i-1]);
            urlLoader.contentLoaderInfo.addEventListener( Event.COMPLETE, apply_filter);
            urlLoader.load( urlRequest );
        }
        private function filter_hover(event:MouseEvent):void
        {
            if (event.target is Sprite)
            {
                filter_list.wrap_small_img.x = event.target.x;
                filter_list.wrap_small_img.y = event.target.y;
                filter_list.wrap_small_img.visible = true;
            }
        }
        function load_complete( event:Event ):void
        {
            image = event.target.content;
            ori_height = image.height;
            ori_width = image.width;
            scaleInBox(image,560,516);
            do_center(image);
            img_panel.addChild(image);
        }
        private function do_center(target:DisplayObject):void
        {
            image.x = (560 - target.width) * 0.5;
            image.y = (516 - target.height) * 0.5;
            //trace(img_panel.numChildren);
        }
        private function apply_filter(event:Event):void
        {
            urlLoader.contentLoaderInfo.removeEventListener( Event.COMPLETE, apply_filter);
            var _content = event.target.content;
            trace(image.height);
            var scale:Number = Math.min((560 / ori_width),516 / ori_height);
            var bmpData:BitmapData = new BitmapData(image.width,image.height);
            var matrix:Matrix = new Matrix();
            matrix.scale(scale, scale);
            bmpData.draw(image,matrix);
            var a = _content.execute(bmpData);
            var filter_bm:Bitmap=new Bitmap();
            filter_bm.bitmapData = a;
            image.visible = false;
            filter_bm.x = (560 - filter_bm.width) * 0.5;
            filter_bm.y = (516 - filter_bm.height) * 0.5;
            if (img_panel.numChildren > 2)
            {
                img_panel.removeChildAt(2);
            }
            img_panel.addChild(filter_bm);
        }
        private function upload_handler(event:MouseEvent):void
        {
            var bitmapData:BitmapData = filter_bm.bitmapData;
            var _encoder:JPGEncoder = new JPGEncoder(100);
            bitmapData.draw(bitmapData);
            var Data:ByteArray = _encoder.encode(bitmapData);
            var req:URLRequest = new URLRequest("http://localhost/youtube/util/upload.php");
            req.data = Data;
            req.method = URLRequestMethod.POST;
            req.contentType = "application/octet-stream";
            var loader:URLLoader = new URLLoader  ;
            loader.dataFormat = URLLoaderDataFormat.BINARY;
            loader.load(req);
            loader.addEventListener(Event.COMPLETE,upload_complete);
        }
        private function upload_complete(event:Event):void
        {
            ExternalInterface.call("upload_complete");
        }
        private function scaleInBox(target:DisplayObject,boxWidth:Number,boxHeight:Number):void
        {
            var scale:Number = Math.min((boxWidth / target.width),boxHeight / target.height);
            if (scale<1)
            {
                target.scaleX = scale;
                target.scaleY = scale;
            }

        }
    }
}