王爽 汇编 实验12

主要思路:  1.将中断的处理程序以数据方式写入到内存中.(显示overflow字符串.)

　　　　　 2.修改中断向量表的值,使0号表项指向中断处理程序的开始地址

　　　　    3.开始除法运算,引发除法溢出错误.　　　　　

assume cs:codeseg

data segment
    db 16 dup (0)
data ends
codeseg segment
    start:
        ;do0程序的安装,将do0程序写入到内存0:200处
        mov ax,cs
        mov ds,ax
        mov si,offset do0    
        mov ax,0
        mov es,ax
        mov di,200h
        mov cx,offset do0end-offset do0    ;算出cx要循环的长度
        cld            ;正向
        rep movsb
        
        ;将do0的入口地址送入中断向量表0号表中.
        mov ax,0
        mov es,ax
        mov word ptr es:[4*0],200h    ;低地址存放偏移地址
        mov word ptr es:[4*0+2],0    ;高地址存放段地址
                                    
        mov ax,1000h    ;进行除法运算,引发除法溢出错误.
        mov bh,1
        div bh
        
        mov ax,4c00h
        int 21h
            
        ;显示字符串
        do0:jmp short do0start
            db "overflow tri"
        do0start:
            mov ax,cs
            mov ds,ax
            mov si,202h
            
            mov ax,0b800h
            mov es,ax
            mov di,12*160+36*2
            
            mov bl,42h
            mov cx,12        ;共12个字符
        s:    mov al,[si]
            mov es:[di],al        
            mov es:[di+1],bl    ;设置字符颜色为红底绿字
            inc si
            add di,2            ;一个字符占两字节.低位ASCII码.高位字符属性
            loop s
        
            mov ax,4c00h
            int 21h
        do0end:nop        
        
codeseg ends

end start