Sprite表的创建与解释（使用）

使用Sprite表一般会生成两个文件，分别是.png文件和.xml文件。

1、创建 Sprite 表，请执行以下操作：

1. 在库中选择一个或多个元件，或在舞台上选择一个或多个元件实例。所选内容还可以包含位图。
2. 右键单击所选内容，然后选择“生成 Sprite 表”。
3. 在“生成 Sprite 表”对话框中，选择选项，然后单击“导出”。

有下列导出选项可用：

图像尺寸

Sprite 表的总尺寸，以像素为单位。默认设置为“自动调整大小”，这将调整表的大小以容纳所包含的所有 Sprite。

图像格式

导出的 Sprite 表的文件格式。PNG 8 位和 PNG 32 位每个都支持使用透明背景（Alpha 通道）。PNG 24 位和 JPG 不支持透明背景。通常，PNG 8 位和 PNG 32 位之间的视觉差异很小。PNG 32 位文件大小是 PNG 8 位文件大小的 4 倍。

边框填充

Sprite 表单边缘的填充，以像素为单位

形状填充

Sprite 表中每个图像之间的填充，以像素为单位

算法

将图像打包到 Sprite 表所用的技术。有两个选项：

• 基本（默认值）
• MaxRects

数据格式

图像数据所用的内部格式。选择最适合导出后 Sprite 表预期工作流程的格式。默认为Starling 格式。

旋转

将 Sprite 旋转 90 度。此选项只适用于某些数据格式。

裁切

此选项通过修剪添加到表的每个元件帧的未使用像素，可以节省 Sprite 表上的空间。

堆栈帧

选择此选项可以防止在生成的 Sprite 表中复制选定元件中的重复帧。

 

2、使用：从Sprite表中拿出需要的位图

private function onXMLLoaded(xml:XML):void
            {
                trace( xml.toString() );
                
                this.xml = xml;
                parse();
            }
            
            private function onImageLoaded(bd:BitmapData):void
            {
                var image:Image = new Image();
                image.source = new Bitmap( bd );
                addChild( image );
                
                this.bd = bd;
                parse();
            }
            
            private function parse():void
            {
                //需要两个文件同时存在才可以使用
                if( !xml || !bd ) return;
                
                var list:XMLList = xml.SubTexture;
                var n:int = list.length();
                var item:XML;
                for( var i:int = 0; i < n; i++ )
                {
                    item = list[i];
                    // <SubTexture name="image 216.png" x="0" y="0" width="80" height="70" pivotX="0" pivotY="0"/>
                    var x:int = int( item.@x );
                    var y:int = int( item.@y );
                    var w:int = int( item.@width );
                    var h:int = int( item.@height );
                    
                    var destRect:Rectangle = new Rectangle(x,y,w,h);
                    var destPoint:Point = new Point(0,0);
                    
                    var newBD:BitmapData = new BitmapData(w,h);
                    
                    //复制Sprite表里面需要到的位图
                    newBD.copyPixels( bd, destRect, destPoint );
                    
                    //检查是否复制成功
                    /* var img:Image = new Image();
                    addChild( img );
                    img.source = new Bitmap( newBD ) ;
                    img.x = x;
                    img.y = y;
                    img.filters = [new GlowFilter()];  */
                }
            }

如果是air程序

/**
             * 把小图数据存到桌面assets目录下面
             */
            private function saveBD(bd:BitmapData, name:String):void
            {
                var ba:ByteArray = pngEnc.encode(bd);
                
                var file:File =  File.desktopDirectory.resolvePath("assets/" + name );
                var fs:FileStream = new FileStream();
                fs.open( file, FileMode.WRITE );
                fs.writeBytes(ba);
                fs.close();
            }

在air程序里可以实现拖拽功能

/**
             * 拖拽功能,得到拖放进来的文件
             */
            protected function nativeDragDropHandler(arr:Array):void
            {
                
                trace(File(arr[0]).nativePath);
                var name:String = File(arr[0]).nativePath;
                // C:UsersdzqDesktop	est.xml
                name = name.substring(0, name.indexOf(".") );
                trace(name);
                
                //置空，防止下次拖拽文件时，使用之前的.xml或.png文件
                xml = null;
                bd = null;
                
                LoaderHelper.loadXML( name + ".xml", onXMLLoaded );
                LoaderHelper.loadImage( name + ".png", onImageLoaded );
            }

    public class NativeDragHelper
    {
        
        /**
         * NativeDragHelper.init(this, nativeDragDropHandler );
         * 
         * protected function nativeDragDropHandler(arr:Array):void
            {
                
                trace(File(arr[0]).nativePath);
            }
         * 
         */
        public static function init( target:InteractiveObject, nativeDragDropHandler:Function ):void
        {
            target.addEventListener(NativeDragEvent.NATIVE_DRAG_ENTER, function(event:NativeDragEvent):void{
                NativeDragManager.acceptDragDrop( target );
            });
            target.addEventListener(NativeDragEvent.NATIVE_DRAG_DROP, function(event:NativeDragEvent):void{
                var arr:Array = event.clipboard.getData(ClipboardFormats.FILE_LIST_FORMAT) as Array;
                nativeDragDropHandler(arr);
            });
        }
    }