解决WebBrowser多次触发LoadCompleted事件的问题

一、起因

最近有个WPF的项目，需要频繁的加载不同的网页并提取网页的数据，随后就使用了WebBrowser控件。WPF使用WebBrowser控件获取网页，一般步骤是:

1、使用Navgiate方法或者WebBrowser的Source属性。

2、监听LoadCompleted事件，当该事件触发时,可以获取DOM。

由于我需要查看的网页比较多，需要依次向WebBrowser控件加载多个指定网址，随后获取各个DOM。一开始我是使用WithEvents来声明WebBrowser控件。但是随后发现会多次触发LoadCompleted事件。随着历史Navgiate方法的调用，该LoadCompleted事件会被越来越多的触发。

举个例子来说明：窗体加载时，首次调用Navgiate方法，导航到URL1，此时只会触发一次LoadCompleted；如果第二次调用Navgiate方法，导航到URL2，此时LoadCompleted将被触发2次，依次是URL1和URL2;依次类推，当加载很多次后，该事件将多次触发。

其实要避免这样的事情发生，可以通过手动绑定及解除LoadCompleted事件监听即可。我单独写了一个HtmlLoader类，来完成该操作，该类的详细代码如下:

二、HtmlLoader类模块

Imports mshtml
Public Class HtmlLoader
    Private mWindow As Window
    Private wb As WebBrowser
    Private mURL As String
    Public Property URL() As String
        Get
            Return mURL
        End Get
        Set(ByVal value As String)
            mURL = value
        End Set
    End Property

    Private mLoadCompleted As Boolean

    Public Sub New(CurWindow As Window, webBrowser As WebBrowser)
        mWindow = CurWindow
        wb = webBrowser
    End Sub

    Public Sub New(CurWindow As Window, webBrowser As WebBrowser, URL As String)
        mWindow = CurWindow
        wb = webBrowser
        Me.Reload(URL)
    End Sub

    Public Sub Reload()
        mLoadCompleted = False
        If Me.URL Is Nothing OrElse Me.URL.Trim.Length = 0 Then Exit Sub
        mWindow.Dispatcher.Invoke(Sub()
                                      LogNote.WriteLine(wb.Name & "-StartLoad", Me.URL)
                                      AddHandler wb.LoadCompleted, AddressOf wb_LoadCompleted
                                      'wb.Source = New Uri(Me.URL)
                                      wb.Navigate(Me.URL)
                                  End Sub)
    End Sub

    Public Sub Reload(URL As String)
        Me.URL = URL
        Reload()
    End Sub

    Private Sub wb_LoadCompleted(sender As Object, e As NavigationEventArgs)
        mWindow.Dispatcher.Invoke(Sub()
                                      LogNote.WriteLine(wb.Name & "-LoadCompleted", Me.URL)
                                      RemoveHandler wb.LoadCompleted, AddressOf wb_LoadCompleted
                                  End Sub)
        mLoadCompleted = True
    End Sub

    Public Function GetDocument() As HTMLDocument
        Do Until mLoadCompleted

        Loop
        Return mWindow.Dispatcher.Invoke(Function() As HTMLDocument
                                             Return wb.Document
                                         End Function)
    End Function
End Class

三、说明

这个类接受WebBrowser控件所在窗体、WebBrowser控件对象及定位的URL做为参数。由于涉及到UI更新问题，需要使用Window对象的Dispatcher来操作，所以需要传递Window。

LogNote是我自己写的日志静态类，这里就不提供代码了，可以简单的将其注释掉就行了。