如果将纹理的内存使用减半

ATF纹理能明显降低纹理的内存使用，但是有时候你可能不会用到它。如果你是动态生成纹理或者从第三方加载，那就不需要使用压缩的ATF纹理了。今天此文主要讲述如果在不使用ATF的情况下节省内存。

首先，确保你的应用时运行在Flash Player11.7或者AIR3.7下，可以通过Capabilities.version快速查看下。编译的时候也需要将Player11.7设为目标Flash player，可以用如下参数：-target-player=11.7.0，-swf-version=20.输入上面参数可以解锁郎中类型的纹理，这两种纹理都是每个像素是用16位来表示，而不是平常的24位或者32位。

当然需要将Context3DTextureFormat.BGR_PACKED或者Context3DTextureFormat.BGRA_PACKED传递给Context3D.createTexture,这样就可以获得16位/像素的纹理了。

Context3DTextureFormat.BGR_PACKED这种纹理的红色通道需要5位，绿色为6为，蓝色为5位。因为人眼睛对绿色的识别要好于红色跟蓝色。我们可以用RGB565来简化记忆。如果需要alpha值，那就使用Context3DTextureFormat.BGRA_PACKED,每个颜色都有一个4位的alpha值。虽然颜色不怎么精确，但是那就是支持alpha付出的代价。

建立纹理后，只需像以前那样调用Texture.uploadFromBitmapData，BitmapData就会自动样式化为16位/像素。这样在不需要透明度的图片上就减少了33%内存使用，需要透明度的减少了50%的内存使用。

试试这个。我只做了一个小的应用，此应用显示了一个512*512不透明土地纹理和一个128*128的带有一点透明的Flash标志。点击下面的按钮来改变不同的纹理类型。

package
{
import com.adobe.utils.AGALMiniAssembler;

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.Sprite;
import flash.display.Stage3D;
import flash.display.StageAlign;
import flash.display.StageScaleMode;
import flash.display3D.Context3D;
import flash.display3D.Context3DBlendFactor;
import flash.display3D.Context3DProgramType;
import flash.display3D.Context3DRenderMode;
import flash.display3D.Context3DTextureFormat;
import flash.display3D.Context3DVertexBufferFormat;
import flash.display3D.IndexBuffer3D;
import flash.display3D.Program3D;
import flash.display3D.VertexBuffer3D;
import flash.display3D.textures.Texture;
import flash.events.Event;
import flash.events.MouseEvent;
import flash.text.TextField;
import flash.text.TextFieldAutoSize;
import flash.text.TextFormat;
import flash.utils.ByteArray;

public class Texture16BPP extends Sprite
{
private static const PAD:Number = 5;

[Embed(source="earth.jpg")]
private static const TEXTURE_RGB:Class;

[Embed(source="flash_logo_alpha.png")]
private static const TEXTURE_RGBA:Class;

private var program:Program3D;
private var posUV:VertexBuffer3D;
private var tris:IndexBuffer3D;
private var textureRGB888:Texture;
private var textureRGB565:Texture;
private var textureRGBA8888:Texture;
private var textureRGBA4444:Texture;
private var curTexture:Texture;
private var context3D:Context3D;

private var modeDisplay:TextField;

public function Texture16BPP()
{
stage.align = StageAlign.TOP_LEFT;
stage.scaleMode = StageScaleMode.NO_SCALE;
stage.frameRate = 60;

var stage3D:Stage3D = stage.stage3Ds[0];
stage3D.addEventListener(Event.CONTEXT3D_CREATE, onContextCreated);
stage3D.requestContext3D(Context3DRenderMode.AUTO);
}

protected function onContextCreated(ev:Event): void
{
var stage3D:Stage3D = stage.stage3Ds[0];
stage3D.removeEventListener(Event.CONTEXT3D_CREATE, onContextCreated);
context3D = stage3D.context3D; 
context3D.configureBackBuffer(stage.stageWidth, stage.stageHeight, 0);
context3D.enableErrorChecking = true;

makeButtons("RGB888", "RGB565", "RGBA8888", "RGBA4444");

var assembler:AGALMiniAssembler = new AGALMiniAssembler();
assembler.assemble(
Context3DProgramType.VERTEX,
"mov op, va0\n" +
"mov v0, va1"
);
var vertexProgram:ByteArray = assembler.agalcode;

assembler.assemble(
Context3DProgramType.FRAGMENT,
"tex oc, v0, fs0 <2d,linear,mipnone,clamp,dxt1>"
);
var fragmentProgram:ByteArray = assembler.agalcode;

program = context3D.createProgram();
program.upload(vertexProgram, fragmentProgram);

posUV = context3D.createVertexBuffer(4, 5);
posUV.uploadFromVector(
new <Number>[
// X, Y, Z, U, V
-1, -1, 0, 0, 1,
-1, 1, 0, 0, 0,
1, 1, 0, 1, 0,
1, -1, 0, 1, 1
], 0, 4
);

// Create the triangles index buffer
tris = context3D.createIndexBuffer(6);
tris.uploadFromVector(
new <uint>[
0, 1, 2,
2, 3, 0
], 0, 6
);

var opaque:BitmapData = (new TEXTURE_RGB() as Bitmap).bitmapData;
var alpha:BitmapData = (new TEXTURE_RGBA() as Bitmap).bitmapData;

textureRGB888 = context3D.createTexture(
opaque.width,
opaque.height,
Context3DTextureFormat.BGRA,
false
);
textureRGB888.uploadFromBitmapData(opaque);

textureRGB565 = context3D.createTexture(
opaque.width,
opaque.height,
Context3DTextureFormat.BGR_PACKED,
false
);
textureRGB565.uploadFromBitmapData(opaque);

textureRGBA8888 = context3D.createTexture(
alpha.width,
alpha.height,
Context3DTextureFormat.BGRA,
false
);
textureRGBA8888.uploadFromBitmapData(alpha);

textureRGBA4444 = context3D.createTexture(
alpha.width,
alpha.height,
Context3DTextureFormat.BGRA_PACKED,
false
);
textureRGBA4444.uploadFromBitmapData(alpha);

curTexture = textureRGB888;

modeDisplay = new TextField();
modeDisplay.autoSize = TextFieldAutoSize.LEFT;
modeDisplay.defaultTextFormat = new TextFormat("_sans", 36);
modeDisplay.text = "RGB888";
addChild(modeDisplay);

addEventListener(Event.ENTER_FRAME, onEnterFrame);
}

private function makeButtons(...labels): Number
{
var curX:Number = PAD;
var curY:Number = stage.stageHeight - PAD;
for each (var label:String in labels)
{
var tf:TextField = new TextField();
tf.mouseEnabled = false;
tf.selectable = false;
tf.defaultTextFormat = new TextFormat("_sans");
tf.autoSize = TextFieldAutoSize.LEFT;
tf.text = label;
tf.name = "lbl";

var button:Sprite = new Sprite();
button.buttonMode = true;
button.graphics.beginFill(0xF5F5F5);
button.graphics.drawRect(0, 0, tf.width+PAD, tf.height+PAD);
button.graphics.endFill();
button.graphics.lineStyle(1);
button.graphics.drawRect(0, 0, tf.width+PAD, tf.height+PAD);
button.addChild(tf);
button.addEventListener(MouseEvent.CLICK, onButton);
if (curX + button.width > stage.stageWidth - PAD)
{
curX = PAD;
curY -= button.height + PAD;
}
button.x = curX;
button.y = curY - button.height;
addChild(button);

curX += button.width + PAD;
}

return curY - button.height;
}

private function onButton(ev:MouseEvent): void
{
var mode:String = ev.target.getChildByName("lbl").text;
switch (mode)
{
case "RGB888":
curTexture = textureRGB888;
modeDisplay.text = "RGB888";
break;
case "RGB565":
curTexture = textureRGB565;
modeDisplay.text = "RGB565";
break;
case "RGBA8888":
curTexture = textureRGBA8888;
modeDisplay.text = "RGBA8888";
break;
case "RGBA4444":
curTexture = textureRGBA4444;
modeDisplay.text = "RGBA4444";
break;
}
}

private function onEnterFrame(ev:Event): void
{
context3D.clear(0.5, 0.5, 0.5);
context3D.setProgram(program);
context3D.setBlendFactors(
Context3DBlendFactor.SOURCE_ALPHA,
Context3DBlendFactor.ONE_MINUS_SOURCE_ALPHA
);

// Draw selected texture
context3D.setTextureAt(0, curTexture);
context3D.setVertexBufferAt(0, posUV, 0, Context3DVertexBufferFormat.FLOAT_3);
context3D.setVertexBufferAt(1, posUV, 3, Context3DVertexBufferFormat.FLOAT_2);
context3D.drawTriangles(tris);

context3D.present();
}
}
}

结果会根据你先则的纹理图片而又稍微的不同。土地纹理使用16位的与24位的相比没多大区别，但是内存却能节省不少。Flash 标志则看起来要糟糕点。即使是阴影模式,图片的网格还是看起来很糟糕， 这可能不是一个降低内存的好例子，但是你还是降低了50%的内存消耗。

原文链接：如果将纹理的内存使用减半