bat（dos）命名通过adb给多个手机安装多个apk文件

1

::echo off关闭回显功能，加上@命令行自身也不回显；
::echo 输出提示信息；
::if条件判断语句，格式：if [not] exist filename command;
::*号表示任意n个字符；表示任意一个字符使用？；
::goto s1跳转到标号:s1处，然后执行标号后的命令；以命令goto :eof结尾；

@echo off
if not exist *.apk goto s1
if exist *.apk goto s2

::冒号后紧跟一个以字母数字开头的字符串，goto语句可以识别，如:s1标号；
::冒号后紧跟一个非字符数字的一个特殊符号，goto无法识别，可以起到注释作用，如::；::后的内容不会执行且不会回显；
::pause停止系统命令的执行；

:s1:
 echo 【请添加apk文件到apk目录中】
 pause
 goto :eof

::del删除文件夹里面的文件，/q安静模式不要求确认；
::for循环，格式：for %%v in (set) do command 
::%%v指一个可替换的参数；set指定一个或一组文件，可以使用通配符；command指定对每个文件执行的命令；
::for有4个参数/d,/l,/r/f；下面使用/f参数，使用文件解析来处理命令输出、字符串及文件内容；加了/f参数，set可以是文件，如a.txt；可以是执行命令，如'adb devices'；可以是字符串，如"abcdef"；
::echo 文件内容>>文件名；向文件中追加内容；>>重定向符；
::&&(and命令）把多个命令组合起来当一个命令来执行， 碰到执行出错的命令将不执行后面的命令；
::()括号中可以包括多行命令，这些命令将被看成一个整体，视为一条命令行；
::skip=n 指在文件开始时忽略的行数；
::业务1,查出设备序列号，并追加写入devices_sn.txt文件
::循环读取devices_sn.txt文件中除第一个外的设备序列号，每读取到一个设备序列号，循环读取.apk文件，每读取到一个.apk文件时，根据设备序列、允许覆盖安装.apk的模式安装apk文件；每一个设备序列号安装成功一个apk文件，则输出【成功】提示信息；
::所有识别到的手机，安装完所有apk文件后，删除devices_sn.txt文件；

:s2 
 echo adb devices查到的内容如下：
 for /f %%x in ('adb devices') do echo %%x >> devices_sn.txt && echo %%x
 echo ----------------------
 for /f "skip=1" %%i in (devices_sn.txt) do (
for %%y in (*.apk) do adb -s %%i install -r %%y && echo 【结果】：%%i安装%%y【成功】！
)
 del devices_sn.txt
 pause
 goto :eof