PL-SQL 包的创建和应用



PL-SQL 包的创建和应用

①简单介绍
    包是一组相关过程、函数、变量、常量和游标等PL/SQL程序设计元素的组合，它具有面向对象程序设计语言的特点。是对这些PL/SQL 程序设计元素的封装。
包类似于C++和JAVA语言中的类，当中变量相当于类中的成员变量，过程和函数相当于类方法。

把相关的模块归类成为包，可使开发者利用面向对象的方法进行存储过程的开发，从而提高系统性能。
    与类同样，包中的程序元素也分为公用元素和私用元素两种。这两种元素的差别是他们同意訪问的程序范围不同，即它们的作用域不同。

公用元素不仅能够被包中的函数、过程所调用，也能够被包外的PL/SQL程序訪问。而私有元素仅仅能被包内的函数和过程序所訪问。
    在PL/SQL程序设计中，使用包不仅能够使程序设计模块化，对外隐藏包内所使用的信息（通过使用私用变量），并且能够提高程序的运行效率。
由于。当程序首次调用包内函数或过程时，ORACLE将整个包调入内存，当再次訪问包内元素时，ORACLE直接从内存中读取。而不须要进行磁盘I/O操作。
从而使程序运行效率得到提高。

一个包由两个分开的部分组成：
包定义（PACKAGE）：包定义部分声明包内数据类型、变量、常量、游标、子程序和异常错误处理等元素。这些元素为包的公有元素。
包主体（PACKAGE BODY）：包主体则是包定义部分的详细实现，它定义了包定义部分所声明的游标和子程序，在包主体中还能够声明包的私有元素。
包定义和包主体分开编译。并作为两部分分开的对象存放在数据库字典中，详见数据字典user_source, all_source, dba_source.

②包的定义
包定义的语法例如以下：
1.创建包定义:
CREATE[OR REPLACE] PACKAGE package_name
    [AUTHID {CURRENT_USER | DEFINER}]
{IS| AS}
    [公有数据类型定义[公有数据类型定义]…]
    [公有游标声明[公有游标声明]…]
    [公有变量、常量声明[公有变量、常量声明]…]
    [公有子程序声明[公有子程序声明]…]
END[package_name];
当中：AUTHID CURRENT_USER和AUTHID DEFINER选项说明应用程序在调用函数时所使用的权限模式。
它们与CREATE FUNCTION语句中invoker_right_clause子句的作用同样。

创建包主体:
CREATE[OR REPLACE] PACKAGE BODYpackage_name
{IS| AS}
    [私有数据类型定义[私有数据类型定义]…]
    [私有变量、常量声明[私有变量、常量声明]…]
    [私有子程序声明和定义[私有子程序声明和定义]…]
    [公有游标定义[公有游标定义]…]
    [公有子程序定义[公有子程序定义]…]
BEGIN
    PL/SQL 语句
END[package_name];
当中：在包主体定义公有程序时。它们必须与包定义中所声明子程序的格式全然一致。

对包内共同拥有元素的调用格式为：包名.元素名称

③子程序重载
PL/SQL 同意对包内子程序和本地子程序进行重载。
所谓重载时指两个或多个子程序有同样的名称。但拥有不同的參数变量、參数顺序或參数数据类型。

④删除包
能够使用DROP PACKAGE命令对不须要的包进行删除，语法例如以下：
DROP PACKAGE [BODY] [user.]package_name;

⑤包的管理
DBA_SOURCE, USER_SOURCE, USER_ERRORS, DBA-OBJECTS

⑥样例：
创建的包为demo_pack, 该包中包括一个记录变量DeptRec、两个函数和一个过程。
CREATE OR REPLACE PACKAGE demo_pack
IS
    DeptRec dept%ROWTYPE;
    FUNCTION add_dept(dept_no NUMBER, dept_name VARCHAR2, location VARCHAR2)
        RETURN NUMBER;
    FUNCTION remove_dept(dept_no NUMBER)
        RETURN NUMBER;
    PROCEDURE query_dept(dept_no IN NUMBER);
END demo_pack

包主体的创建方法。它实现上面所声明的包定义
CREATE OR REPLACE PACKAGE BODY demo_pack
IS
    --函数定义
    FUNCTION add_dept(dept_no NUMBER, dept_name VARCHAR2, location VARCHAR2)
        RETURN NUMBER
    IS
        empno_remaining EXCEPTION;
        PRAGMA EXCEPTION_INIT(empno_remaining, -1);
        /* -1 是违反唯一约束条件的错误代码*/
    BEGIN
        INSERT INTO dept VALUES(dept_no, dept_name, location);
        IF SQL%FOUND THEN
            RETURN 1;
        END IF;
   EXCEPTION
        WHEN empno_remaining THEN
            RETURN 0;
        WHEN OTHERS THEN
            RETURN -1;
   END add_dept;

   --函数定义
   FUNCTION remove_dept(dept_no NUMBER)
       RETURN NUMBER
   IS
   BEGIN
       DELETE FROM dept WHERE deptno=dept_no;
       IF SQL%FOUND THEN
          RETURN 1;
       ELSE
          RETURN 0;
       END IF;
   EXCEPTION
       WHEN OTHERS THEN
          RETURN -1;
   END remove_dept;

   --过程定义
   PROCEDURE query_dept(dept_no IN NUMBER)
   IS
   BEGIN
       SELECT * INTO DeptRec FROM dept WHERE deptno=dept_no;
   EXCEPTION
       WHEN NO_DATA_FOUND THEN 
          DBMS_OUTPUT.PUT_LINE('数据库中没有编码为'||dept_no||'的部门');
       WHEN TOO_MANY_ROWS THEN
          DBMS_OUTPUT.PUT_LINE('程序执行错误!请使用游标');
       WHEN OTHERS THEN
          DBMS_OUTPUT.PUT_LINE(SQLCODE||’----‘||SQLERRM);
   END query_dept;
BEGIN
   Null;
END demo_pack;