2015-8-27浦东环监项目-相关性配置记录

在static table下面的 TEST_MANAGER下面

表名：DATA_RELATION_CHECK
字段名;	描述：
DATALC_NAME	相关性配置的名字
DATALC_DESCRIPTION	相关性配置的描述
DATALC_DATE	公式更改的日期
DATALC_CALCNAME	公式的名字，和CALCS_ACTIONS中的CALCDESC对应
DATALC_CALCUL	公式内容，和CALCS_ACTIONS的CALCUL对应

Form

主Form，                  DataRelationCheck。

添加公式Form，          AddDLCheck

编辑公式Form,           Dlc_CalcName

Server Script: 

1. ADD_DLCheck                      功能：添加公式，可以返回origrec定位

   :PARAMETERS DLCName , DLCDesription;
   
   :DEFAULT DLCName ,"1" ;
   :DEFAULT DLCDesription ,"2";
   
   :DECLARE strSql ,bSuccess , cSuccess;
   
   strSql :="insert into     DATA_RELATION_CHECK     (DATALC_NAME, DATALC_DESCRIPTION) 
                                       values         (?DLCName?,?DLCDesription?)";
   
   bSuccess := SQLEXECUTE(strSql);
   
   :IF(bSuccess);
       cSuccess := sqlexecute("select ORIGREC 
                               from DATA_RELATION_CHECK
                               where DATALC_NAME = ?DLCName?");
       :RETURN {.T.,cSuccess[1,1]};
   :ELSE;
       :RETURN {.F.};
   :ENDIF;

    
2. SS_UpdateDLCTime　　        功能：在公式更新时，日期更新操作

   :PARAMETERS ORIGREC;
   
   :DEFAULT ORIGREC,"3";
   
   :DECLARE StrSql, bSuccess;
   
   StrSql :="    update DATA_RELATION_CHECK 
               set DATALC_DATE = getdate() 
               where ORIGREC = ?ORIGREC?";
               
       bSuccess := sqlexecute(StrSql);
   :RETURN bSuccess;

3. DLCName_Check                  功能：查询要添加的名字是否已经存在

   :PARAMETERS DLCNAME ;
   
   :DEFAULT DLCNAME,"11";
   
   :DECLARE strSql, bSuccess;
   
   strSql :=    "    select ORIGREC 
                   from DATA_RELATION_CHECK
                   where DATALC_NAME =?DLCNAME?";
   
   bSuccess := SqlExecute(strSql);
   
   :IF .not. empty(bSuccess) .and. len(bSuccess) > 0 ;
       :RETURN .T.;
   :ELSE;
       :RETURN .F.;
   :ENDIF;

    
4. SS_Update_Calculation          功能：更新操作，实现自动增加公式标示

   :PARAMETERS CalcName, Calculation, origrec, CALCDESC;
   :DEFAULT CalcName, "";
   :DEFAULT Calculation, "";
   :DEFAULT origrec, -1;
   :DEFAULT CALCDESC, "";
   
   :DECLARE CalcNames, CurrCalcName,CurrTestCodeAnalyte,CurrTestCode,CurrAnalyte,anaTestCode,testAnalyte,analyteMethod;
   
   /*region add/update calculation;
   :IF Empty(CALCDESC);    
       :IF Empty(CalcName);
           CalcNames := SqlExecute("select Max(CALCNAME) from CALCS_ACTIONS where CALCNAME like 'CALC%'");
           
           //如果是全新的，表格为空，则设置初始值为CALC-00001
           :IF Empty(CalcNames[1,1]);
               CurrCalcName := "CALC-" + "00001";
           :ELSE;
               //Right（取最右边的几个字符）
               CurrCalcName := Val(Right(CalcNames[1,1], 5)) + 1;//val()基本意思是将字符串类型转换为数字类型
               CurrCalcName := "CALC-" + StrZero(CurrCalcName, 5, 0);
           :ENDIF;
           SqlExecute("insert into CALCS_ACTIONS (CALCNAME, CALCUL, CALCDESC, FROMDATE) 
                           values (?CurrCalcName?, ?Calculation?, ?CurrCalcName?, ?Today()?)");
                               
           SqlExecute("update DATA_RELATION_CHECK set DATALC_CALCNAME = ?CurrCalcName? where ORIGREC = ?origrec?");
           
       :ELSE;    
           SqlExecute("update CALCS_ACTIONS set CALCUL = ?Calculation? where CALCNAME = ?CalcName?");    
           SqlExecute("update DATA_RELATION_CHECK set DATALC_CALCUL = ?Calculation? where DATALC_CALCNAME = ?CalcName?");    
       :ENDIF;
   :ELSE;
       CalcNames := SqlExecute("select Max(CALCNAME) from CALCS_ACTIONS where CALCNAME Like 'CALC%'");
       
       CurrCalcName := Val(Right(CalcNames[1,1], 5)) + 1;
       CurrCalcName := "CALC-" + StrZero(CurrCalcName, 5, 0);
       
       SqlExecute("insert into CALCS_ACTIONS (CALCNAME, CALCDESC, CALCUL,FROMDATE) 
                           select ?CurrCalcName?, ?CALCDESC?, CALCUL,?Today()?
                           from    CALCS_ACTIONS 
                           where  ORIGREC = (select max(ORIGREC)
                                             from CALCS_ACTIONS
                                             where CALCDESC=?CALCDESC?)");
       SqlExecute("update DATA_RELATION_CHECK set DATALC_CALCUL = ?Calculation? where DATALC_CALCNAME = ?CalcName?");
       SqlExecute("update DATA_RELATION_CHECK set DATALC_CALCNAME = ?CurrCalcName? where ORIGREC = ?origrec?");
   :ENDIF;
   
   :RETURN CurrCalcName;

Data Sources:

1.  DS_GET_DLCheck          功能：获取新建表格的数据。