zoukankan      html  css  js  c++  java
  • Direct2D (24) : 合并几何对象


    合并通过 ID2D1Geometry.CombineWithGeometry() 完成,但返回的是 ID2D1SimplifiedGeometrySink(ID2D1GeometrySink 的父对象);
    需要把 ID2D1SimplifiedGeometrySink 添加到 ID2D1PathGeometry 才能使用。

    uses Direct2D, D2D1;
    
    procedure TForm1.FormPaint(Sender: TObject);
    var
      cvs: TDirect2DCanvas;
      iEllipseGeometry1, iEllipseGeometry2: ID2D1EllipseGeometry;
      iGeometrySink: ID2D1GeometrySink;
      iPathGeometry1,iPathGeometry2,iPathGeometry3,iPathGeometry4: ID2D1PathGeometry;
      ptCenter: TD2DPoint2f;
      r: Single;
      matrix: TD2DMatrix3x2F;
    begin
      ptCenter := D2D1PointF(100, 100);
      r := 50;
      matrix := TD2DMatrix3x2F.Identity;
    
      {两个源对象}
      D2DFactory.CreateEllipseGeometry(D2D1Ellipse(ptCenter, r, r), iEllipseGeometry1);
      ptCenter.x := ptCenter.x + r;
      D2DFactory.CreateEllipseGeometry(D2D1Ellipse(ptCenter, r, r), iEllipseGeometry2);
    
      {UNION 运算}
      D2DFactory.CreatePathGeometry(iPathGeometry1);
      iPathGeometry1.Open(iGeometrySink);
        iEllipseGeometry1.CombineWithGeometry(iEllipseGeometry2, D2D1_COMBINE_MODE_UNION, matrix, 0, iGeometrySink);
      iGeometrySink.Close;
    
      {INTERSECT 运算}
      D2DFactory.CreatePathGeometry(iPathGeometry2);
      iPathGeometry2.Open(iGeometrySink);
        iEllipseGeometry1.CombineWithGeometry(iEllipseGeometry2, D2D1_COMBINE_MODE_INTERSECT, matrix, 0, iGeometrySink);
      iGeometrySink.Close;
    
      {XOR 运算}
      D2DFactory.CreatePathGeometry(iPathGeometry3);
      iPathGeometry3.Open(iGeometrySink);
        iEllipseGeometry1.CombineWithGeometry(iEllipseGeometry2, D2D1_COMBINE_MODE_XOR, matrix, 0, iGeometrySink);
      iGeometrySink.Close;
    
      {EXCLUDE 运算}
      D2DFactory.CreatePathGeometry(iPathGeometry4);
      iPathGeometry4.Open(iGeometrySink);
        iEllipseGeometry1.CombineWithGeometry(iEllipseGeometry2, D2D1_COMBINE_MODE_EXCLUDE, matrix, 0, iGeometrySink);
      iGeometrySink.Close;
    
      cvs := TDirect2DCanvas.Create(Canvas, ClientRect);
      cvs.BeginDraw;
      cvs.Pen.Color := clWebCornFlowerBlue;
      cvs.Brush.Color := clWebCornFlowerBlue;
      cvs.Brush.Handle.SetOpacity(0.75);
    
      cvs.FillGeometry(iPathGeometry1);
      cvs.DrawGeometry(iEllipseGeometry1);
      cvs.DrawGeometry(iEllipseGeometry2);
    
      cvs.RenderTarget.SetTransform(TD2DMatrix3x2F.Translation(180, 0));
      cvs.FillGeometry(iPathGeometry2);
      cvs.DrawGeometry(iEllipseGeometry1);
      cvs.DrawGeometry(iEllipseGeometry2);
    
      cvs.RenderTarget.SetTransform(TD2DMatrix3x2F.Translation(180*2, 0));
      cvs.FillGeometry(iPathGeometry3);
      cvs.DrawGeometry(iEllipseGeometry1);
      cvs.DrawGeometry(iEllipseGeometry2);
    
      cvs.RenderTarget.SetTransform(TD2DMatrix3x2F.Translation(180*3, 0));
      cvs.FillGeometry(iPathGeometry4);
      cvs.DrawGeometry(iEllipseGeometry1);
      cvs.DrawGeometry(iEllipseGeometry2);
    
      cvs.EndDraw;
      cvs.Free;
    end;
    


    效果图:



    简化后的代码:

    uses Direct2D, D2D1;
    
    procedure TForm1.FormPaint(Sender: TObject);
    var
      cvs: TDirect2DCanvas;
      iEllipseGeometry1, iEllipseGeometry2: ID2D1EllipseGeometry;
      iGeometrySink: ID2D1GeometrySink;
      iPathGeometrys: array[0..3] of ID2D1PathGeometry;
      ptCenter: TD2DPoint2f;
      r: Single;
      i: Integer;
    begin
      ptCenter := D2D1PointF(100, 100);
      r := 50;
    
      D2DFactory.CreateEllipseGeometry(D2D1Ellipse(ptCenter, r, r), iEllipseGeometry1);
      ptCenter.x := ptCenter.x + r;
      D2DFactory.CreateEllipseGeometry(D2D1Ellipse(ptCenter, r, r), iEllipseGeometry2);
    
      for i := 0 to 3 do
      begin
        D2DFactory.CreatePathGeometry(iPathGeometrys[i]);
        iPathGeometrys[i].Open(iGeometrySink);
          iEllipseGeometry1.CombineWithGeometry(iEllipseGeometry2, i, TD2DMatrix3x2F.Identity, 0, iGeometrySink);
        iGeometrySink.Close;
      end;
    
      cvs := TDirect2DCanvas.Create(Canvas, ClientRect);
      cvs.BeginDraw;
      cvs.Pen.Color := clWebCornFlowerBlue;
      cvs.Brush.Color := clWebCornFlowerBlue;
      cvs.Brush.Handle.SetOpacity(0.75);
    
      for i := 0 to 3 do
      begin
        cvs.RenderTarget.SetTransform(TD2DMatrix3x2F.Translation(180*i, 0));
        cvs.FillGeometry(iPathGeometrys[i]);
        cvs.DrawGeometry(iEllipseGeometry1);
        cvs.DrawGeometry(iEllipseGeometry2);
      end;
    
      cvs.EndDraw;
      cvs.Free;
    end;
    


  • 相关阅读:
    【赵强老师】使用Docker Compose进行服务编排
    【赵强老师】Weblogic域和域的组成
    【赵强老师】管理Docker镜像
    3. 清理统一审计 AUD$UNIFIED 基表部份数据
    4. AUD$UNIFIED 基表及 分区键创建索引
    2.更改统一审计AUD$UNIFIED基表 默认表空间
    1.更改统一审计AUD$UNIFIED 分区为1天
    9. 将APEX18.2 升级到 APEX19.2 详细步骤
    1.2 安装中文语言包
    通过VBOX 导入系统工具 搭建APEX开发环境
  • 原文地址:https://www.cnblogs.com/del/p/2007185.html
Copyright © 2011-2022 走看看