Block With工具

Block With工具，用来提取开域with的工具，如下代码：

ADOQuery_Tmp.Data := fData;
ADOQuery_Tmp.Filtered := false;
ADOQuery_Tmp.Filter := '选择=1';
ADOQuery_Tmp.Filtered := true;

经过使用此工具，提取ADOQuery_Tmp字符串后，代码为：

With ADOQuery_Tmp do
Begin
    Data := fData;
    Filtered := false;
    Filter := '选择=1';
    Filtered := true;
End;

我们可以使用开源的CnPack代码进行扩展，打开CnWizards_D11.dpr(Dephi2007进行开发),在EditorWizard文件夹下，新增CnEditorCodeBlockWith单元

代码如下

{******************************************************************************}
{                       CnPack For Delphi/C++Builder                           }
{                     中国人自己的开放源码第三方开发包                         }
{                   (C)Copyright 2001-2012 CnPack 开发组                       }
{                   ------------------------------------                       }
{                                                                              }
{            本开发包是开源的自由软件，您可以遵照 CnPack 的发布协议来修        }
{        改和重新发布这一程序。                                                }
{                                                                              }
{            发布这一开发包的目的是希望它有用，但没有任何担保。甚至没有        }
{        适合特定目的而隐含的担保。更详细的情况请参阅 CnPack 发布协议。        }
{                                                                              }
{            您应该已经和开发包一起收到一份 CnPack 发布协议的副本。如果        }
{        还没有，可访问我们的网站：                                            }
{                                                                              }
{            网站地址：http://www.cnpack.org                                   }
{            电子邮件：master@cnpack.org                                       }
{                                                                              }
{******************************************************************************}

unit CnEditorCodeBlockWith;

interface

{$I CnWizards.inc}

{$IFDEF CNWIZARDS_CNEDITORWIZARD}

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, IniFiles, ToolsAPI, CnWizClasses, CnWizUtils, CnConsts, CnCommon,
  CnEditorWizard, CnWizConsts, CnEditorCodeTool,ufrmBlockSet;

type

//==============================================================================
// 赋值交换工具类
//==============================================================================

{ TCnEditorCodeSwap }

  TCnEditorCodeBlockWith = class(TCnEditorCodeTool)
  private
    FBlockWith: string;
  protected
    function ProcessText(const Text: string): string; override;
    function GetStyle: TCnCodeToolStyle; override;
  public
    function GetCaption: string; override;
    function GetHint: string; override;
    procedure GetEditorInfo(var Name, Author, Email: string); override;

    property BlockWith: string read FBlockWith write FBlockWith;
    constructor Create(AOwner: TCnEditorWizard); override;
    procedure Execute; override;
  end;

{$ENDIF CNWIZARDS_CNEDITORWIZARD}

implementation

{$IFDEF CNWIZARDS_CNEDITORWIZARD}

//==============================================================================
// 赋值交换工具类
//==============================================================================

{ TCnEditorCodeSwap }

constructor TCnEditorCodeBlockWith.Create(AOwner: TCnEditorWizard);
begin
  inherited;
  ValidInSource := True;
  BlockMustNotEmpty := True;
end;

procedure TCnEditorCodeBlockWith.Execute;
begin
  frmBlockSet :=TfrmBlockSet.create(nil);
  try
    if frmBlockSet.ShowModal=mrOk then
      FBlockWith :=frmBlockSet.Block
    else
      Exit;  
  finally
    frmBlockSet.Free;
  end;
  if Trim(FBlockWith)='' then
    Exit
  else
  begin
    if Copy(FBlockWith,Length(FBlockWith),1)='.' then
      FBlockWith :=Copy(FBlockWith,1,Length(FBlockWith)-1);
  end;
  inherited;
end;

function TCnEditorCodeBlockWith.GetStyle: TCnCodeToolStyle;
begin
  result := csSelText;
end;

function TCnEditorCodeBlockWith.GetCaption: string;
begin
  Result := SCnEditorCodeBlockWithMenuCaption;
end;

function TCnEditorCodeBlockWith.GetHint: string;
begin
  Result := SCnEditorCodeBlockWithMenuHint;
end;

function TCnEditorCodeBlockWith.ProcessText(const Text: string): string;
var
  FStrings:TStringList;
  FCount,i:Integer;
  FTemp:string;
  FHead:string;
  FEnd:string;
  EditView: IOTAEditView;
  StartPos:Integer;
  BlankStr:string;
begin
  FStrings := TStringList.Create;
  try
    FHead :=Format('With %s do',[FBlockWith]);

    FStrings.Text := Text;
    EditView :=CnOtaGetTopMostEditView;
    StartPos := EditView.Block.StartingColumn;
    BlankStr :=StringofChar(' ',StartPos-1);
    FCount := FStrings.Count;
    FHead :=FHead+#13#10+BlankStr+'Begin';
    FEnd :=BlankStr+'End;';
    for i:=0 to FCount-1 do
    begin
      FTemp :=FStrings[i];
      if i=0 then
        FTemp :=BlankStr+'  '+StringReplace(FTemp,FBlockWith+'.','',[rfIgnoreCase,rfReplaceAll])
      else
        FTemp :='  '+StringReplace(FTemp,FBlockWith+'.','',[rfIgnoreCase,rfReplaceAll]);
      FStrings[i] :=FTemp;
    end;
    Result :=FHead+#13#10+ FStrings.Text+FEnd;
  finally
    FreeAndNil(FStrings);
  end;
end;

procedure TCnEditorCodeBlockWith.GetEditorInfo(var Name, Author, Email: string);
begin
  Name := SCnEditorCodeBlockWithName;
  Author := '董继超';
  Email := 'djcsch@163.com';
end;

initialization
  RegisterCnEditor(TCnEditorCodeBlockWith); // 注册专家

{$ENDIF CNWIZARDS_CNEDITORWIZARD}
end.

然后进行编译即可。

ufrmBlockSet.pas为：

unit ufrmBlockSet;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TfrmBlockSet = class(TForm)
    edtBlock: TEdit;
    Label1: TLabel;
    Button1: TButton;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
    Block:string;
  end;

var
  frmBlockSet: TfrmBlockSet;

implementation

{$R *.dfm}

procedure TfrmBlockSet.Button1Click(Sender: TObject);
begin
  if Trim(edtBlock.Text)='' then
  begin
    edtBlock.SetFocus;
    raise Exception.Create('前缀不能为空，请重新输入！');
  end;
  Block :=Trim(edtBlock.Text);
end;

end.