反射如何将程序集加载到仅反射上下文中

  1只反射加载上下文使您能够检查为其他平台或 .NET Framework 的其他版本编译的程序集。加载到此上下文中的代码只能检查，不能执行。这意味着无法创建对象，因为无法执行构造函数。因为该代码无法执行，所以不会自动加载依赖项。如果需要对依赖项进行检查，则必须自行加载。
  2
  3将程序集加载到只反射加载上下文中
  4使用 ReflectionOnlyLoad(String) 方法重载可加载给定了显示名称的程序集，而使用 ReflectionOnlyLoadFrom 方法可加载给定了路径的程序集。如果该程序集为二进制文件映像，则使用 ReflectionOnlyLoad(array<Byte>[]()[]) 方法重载。
  5
  6注意： 
  7您不能使用只反射上下文从非执行上下文中的 .NET Framework 版本加载 mscorlib.dll 版本。
  8 
  9
 10如果该程序集具有依赖项，ReflectionOnlyLoad 方法不会加载这些依赖项。如果需要对依赖项进行检查，则必须自行加载。
 11
 12使用程序集的 ReflectionOnly 属性确定是否将该程序集加载到了只反射上下文中。
 13
 14如果向该程序集或程序集中的类型应用了属性，则应通过使用 CustomAttributeData 类检查这些属性，以确保未尝试在只反射上下文中执行代码。使用 CustomAttributeData..::.GetCustomAttributes 方法的适当重载可获取表示应用于程序集、成员、模块或参数的属性的 CustomAttributeData 对象。
 15
 16注意： 
 17应用于该程序集或其内容的属性可能是在该程序集中定义的，也可能是在加载到只反射上下文中的另一个程序集中定义的。无法事先知道这些属性是在何处定义的。
 18 
 19
 20示例
 21下面的代码示例演示如何检查应用于加载到只反射上下文中的程序集的属性。
 22
 23该代码示例定义了一个带有两个构造函数和一个属性 (Property) 的自定义属性 (Attribute)。该属性可应用于程序集、在该程序集中声明的类型、该类型的方法以及该方法的参数。在执行时，该程序集将其本身加载到只反射上下文中，并显示应用到它及它包含的类型和成员的自定义属性的有关信息。
 24
 25注意： 
 26为简化该代码示例，该程序集自行完成加载和检查操作。通常情况下，不要在执行上下文和只反射上下文中加载同一程序集。
 27 
 28
 29Visual Basic  复制代码 
 30Imports System
 31Imports System.Reflection
 32Imports System.Collections.Generic
 33Imports System.Collections.ObjectModel
 34
 35' The example attribute is applied to the assembly.
 36<Assembly:Example(ExampleKind.ThirdKind, Note:="This is a note on the assembly.")>
 37
 38' An enumeration used by the ExampleAttribute class.
 39Public Enum ExampleKind
 40    FirstKind
 41    SecondKind
 42    ThirdKind
 43    FourthKind
 44End Enum
 45
 46' An example attribute. The attribute can be applied to all
 47' targets, from assemblies to parameters.
 48'
 49<AttributeUsage(AttributeTargets.All)> _
 50Public Class ExampleAttribute
 51    Inherits Attribute
 52
 53    ' Data for properties.
 54    Private kindValue As ExampleKind
 55    Private noteValue As String
 56    Private arrayStrings() As String
 57    Private arrayNumbers() As Integer
 58
 59    ' Constructors. The parameterless constructor (.ctor) calls
 60    ' the constructor that specifies ExampleKind and an array of
 61    ' strings, and supplies the default values.
 62    '
 63    Public Sub New(ByVal initKind As ExampleKind, ByVal initStrings() As String)
 64        kindValue = initKind
 65        arrayStrings = initStrings
 66    End Sub
 67    Public Sub New(ByVal initKind As ExampleKind)
 68        Me.New(initKind, Nothing)
 69    End Sub
 70    Public Sub New()
 71        Me.New(ExampleKind.FirstKind, Nothing)
 72    End Sub
 73
 74    ' Properties. The Note and Numbers properties must be read/write, so they 
 75    ' can be used as named parameters.
 76    '
 77    Public ReadOnly Property Kind As ExampleKind
 78        Get
 79            Return kindValue 
 80        End Get
 81    End Property
 82    Public ReadOnly Property Strings As String()
 83        Get
 84            Return arrayStrings 
 85        End Get
 86    End Property
 87    Public Property Note As String
 88        Get
 89            Return noteValue 
 90        End Get
 91        Set
 92            noteValue = value
 93        End Set
 94    End Property
 95    Public Property Numbers As Integer()
 96        Get
 97            Return arrayNumbers 
 98        End Get
 99        Set
            arrayNumbers = value
        End Set
    End Property
End Class

' The example attribute is applied to the test class.
'
<Example(ExampleKind.SecondKind, _
         New String() { "String array argument, line 1", _
                        "String array argument, line 2", _
                        "String array argument, line 3" }, _
         Note := "This is a note on the class.", _
         Numbers := New Integer() { 53, 57, 59 })> _
Public Class Test
    ' The example attribute is applied to a method, using the
    ' parameterless constructor and supplying a named argument.
    ' The attribute is also applied to the method parameter.
    '
    <Example(Note:="This is a note on a method.")> _
    Public Sub TestMethod(<Example()> ByVal arg As Object)
    End Sub

    ' Sub Main gets objects representing the assembly, the test
    ' type, the test method, and the method parameter. Custom
    ' attribute data is displayed for each of these.
    '
    Public Shared Sub Main()
        Dim asm As [Assembly] = Assembly.ReflectionOnlyLoad("source")
        Dim t As Type = asm.GetType("Test")
        Dim m As MethodInfo = t.GetMethod("TestMethod")
        Dim p() As ParameterInfo = m.GetParameters()

        Console.WriteLine(vbCrLf & "Attributes for assembly: {0}", asm)
        ShowAttributeData(CustomAttributeData.GetCustomAttributes(asm))
        Console.WriteLine(vbCrLf & "Attributes for type: {0}", t)
        ShowAttributeData(CustomAttributeData.GetCustomAttributes(t))
        Console.WriteLine(vbCrLf & "Attributes for member: {0}", m)
        ShowAttributeData(CustomAttributeData.GetCustomAttributes(m))
        Console.WriteLine(vbCrLf & "Attributes for parameter: {0}", p)
        ShowAttributeData(CustomAttributeData.GetCustomAttributes(p(0)))
    End Sub

    Private Shared Sub ShowAttributeData( _
        ByVal attributes As IList(Of CustomAttributeData))

        For Each cad As CustomAttributeData _
            In CType(attributes, IEnumerable(Of CustomAttributeData))

            Console.WriteLine("   {0}", cad)
            Console.WriteLine("      Constructor: {0}", cad.Constructor)

            Console.WriteLine("      Constructor arguments:")
            For Each cata As CustomAttributeTypedArgument _
                In CType(cad.ConstructorArguments, IEnumerable(Of CustomAttributeTypedArgument))

                ShowValueOrArray(cata)
            Next

            Console.WriteLine("      Named arguments:")
            For Each cana As CustomAttributeNamedArgument _
                In CType(cad.NamedArguments, IEnumerable(Of CustomAttributeNamedArgument))

                Console.WriteLine("         MemberInfo: {0}", _
                    cana.MemberInfo)
                ShowValueOrArray(cana.TypedValue)
            Next
        Next
    End Sub

    Private Shared Sub ShowValueOrArray(ByVal cata As CustomAttributeTypedArgument)
        If cata.Value.GetType() Is GetType(ReadOnlyCollection(Of CustomAttributeTypedArgument)) Then
            Console.WriteLine("         Array of {0}:", cata.ArgumentType)

            For Each cataElement As CustomAttributeTypedArgument In cata.Value
                Console.WriteLine("             Type: {0} Value: {1}", _
                    cataElement.ArgumentType, cataElement.Value)
            Next
        Else
            Console.WriteLine("         Type: {0} Value: {1}", _
                cata.ArgumentType, cata.Value)
        End If       
    End Sub
End Class

' This code example produces output similar to the following:
'
'Attributes for assembly: source, Version=0.0.0.0, Culture=neutral, PublicKeyToken=null
'   [ExampleAttribute((ExampleKind)2, Note = "This is a note on the assembly.")]
'      Constructor: Void .ctor(ExampleKind)
'      Constructor arguments:
'         Type: ExampleKind Value: 2
'      Named arguments:
'         MemberInfo: System.String Note
'         Type: System.String Value: This is a note on the assembly.
'   [System.Runtime.CompilerServices.CompilationRelaxationsAttribute((Int32)8)]
'      Constructor: Void .ctor(Int32)
'      Constructor arguments:
'         Type: System.Int32 Value: 8
'      Named arguments:
'
'Attributes for type: Test
'   [ExampleAttribute((ExampleKind)1, new String[3] { "String array argument, line 1", "String array argument, line 2", "String array argument, line 3" }, Note = "This is a note on the class.", Numbers = new Int32[3] { 53, 57, 59 })]
'      Constructor: Void .ctor(ExampleKind, System.String[])
'      Constructor arguments:
'         Type: ExampleKind Value: 1
'         Array of System.String[]:
'             Type: System.String Value: String array argument, line 1
'             Type: System.String Value: String array argument, line 2
'             Type: System.String Value: String array argument, line 3
'      Named arguments:
'         MemberInfo: System.String Note
'         Type: System.String Value: This is a note on the class.
'         MemberInfo: Int32[] Numbers
'         Array of System.Int32[]:
'             Type: System.Int32 Value: 53
'             Type: System.Int32 Value: 57
'             Type: System.Int32 Value: 59
'
'Attributes for member: Void TestMethod(System.Object)
'   [ExampleAttribute(Note = "This is a note on a method.")]
'      Constructor: Void .ctor()
'      Constructor arguments:
'      Named arguments:
'         MemberInfo: System.String Note
'         Type: System.String Value: This is a note on a method.
'
'Attributes for parameter: System.Object arg
'   [ExampleAttribute()]
'      Constructor: Void .ctor()
'      Constructor arguments:
'      Named arguments:


 
C#  复制代码 
using System;
using System.Reflection;
using System.Collections.Generic;
using System.Collections.ObjectModel;

// The example attribute is applied to the assembly.
[assembly:Example(ExampleKind.ThirdKind, Note="This is a note on the assembly.")]

// An enumeration used by the ExampleAttribute class.
public enum ExampleKind
{
    FirstKind, 
    SecondKind, 
    ThirdKind, 
    FourthKind
};

// An example attribute. The attribute can be applied to all
// targets, from assemblies to parameters.
//
[AttributeUsage(AttributeTargets.All)]
public class ExampleAttribute : Attribute
{
    // Data for properties.
    private ExampleKind kindValue;
    private string noteValue;
    private string[] arrayStrings;
    private int[] arrayNumbers;

    // Constructors. The parameterless constructor (.ctor) calls
    // the constructor that specifies ExampleKind and an array of 
    // strings, and supplies the default values.
    //
    public ExampleAttribute(ExampleKind initKind, string[] initStrings)
    {
        kindValue = initKind;
        arrayStrings = initStrings;
    }
    public ExampleAttribute(ExampleKind initKind) : this(initKind, null) {}
    public ExampleAttribute() : this(ExampleKind.FirstKind, null) {}

    // Properties. The Note and Numbers properties must be read/write, so they
    // can be used as named parameters.
    //
    public ExampleKind Kind { get { return kindValue; }}
    public string[] Strings { get { return arrayStrings; }}
    public string Note    
    {
        get { return noteValue; }
        set { noteValue = value; }
    }
    public int[] Numbers
    {
        get { return arrayNumbers; }
        set { arrayNumbers = value; }
    }
}

// The example attribute is applied to the test class.
//
[Example(ExampleKind.SecondKind, 
         new string[] { "String array argument, line 1", 
                        "String array argument, line 2", 
                        "String array argument, line 3" }, 
         Note="This is a note on the class.",
         Numbers = new int[] { 53, 57, 59 })] 
public class Test
{
    // The example attribute is applied to a method, using the
    // parameterless constructor and supplying a named argument.
    // The attribute is also applied to the method parameter.
    //
    [Example(Note="This is a note on a method.")]
    public void TestMethod([Example] object arg) { }

    // Main() gets objects representing the assembly, the test
    // type, the test method, and the method parameter. Custom
    // attribute data is displayed for each of these.
    //
    public static void Main()
    {
        Assembly asm = Assembly.ReflectionOnlyLoad("Source");
        Type t = asm.GetType("Test");
        MethodInfo m = t.GetMethod("TestMethod");
        ParameterInfo[] p = m.GetParameters();

        Console.WriteLine("\r\nAttributes for assembly: {0}", asm);
        ShowAttributeData(CustomAttributeData.GetCustomAttributes(asm));
        Console.WriteLine("\r\nAttributes for type: {0}", t);
        ShowAttributeData(CustomAttributeData.GetCustomAttributes(t));
        Console.WriteLine("\r\nAttributes for member: {0}", m);
        ShowAttributeData(CustomAttributeData.GetCustomAttributes(m));
        Console.WriteLine("\r\nAttributes for parameter: {0}", p);
        ShowAttributeData(CustomAttributeData.GetCustomAttributes(p[0]));
    }

    private static void ShowAttributeData(
        IList<CustomAttributeData> attributes)
    {
        foreach( CustomAttributeData cad in attributes )
        {
            Console.WriteLine("   {0}", cad);
            Console.WriteLine("      Constructor: {0}", cad.Constructor);

            Console.WriteLine("      Constructor arguments:");
            foreach( CustomAttributeTypedArgument cata 
                in cad.ConstructorArguments )
            {
                ShowValueOrArray(cata);
            }

            Console.WriteLine("      Named arguments:");
            foreach( CustomAttributeNamedArgument cana 
                in cad.NamedArguments )
            {
                Console.WriteLine("         MemberInfo: {0}", 
                    cana.MemberInfo);
                ShowValueOrArray(cana.TypedValue);
            }
        }
    }

    private static void ShowValueOrArray(CustomAttributeTypedArgument cata)
    {
        if (cata.Value.GetType() == typeof(ReadOnlyCollection<CustomAttributeTypedArgument>))
        {
            Console.WriteLine("         Array of {0}:", cata.ArgumentType);

            foreach (CustomAttributeTypedArgument cataElement in 
                (ReadOnlyCollection<CustomAttributeTypedArgument>) cata.Value)
            {
                Console.WriteLine("             Type: {0} Value: {1}",
                    cataElement.ArgumentType, cataElement.Value);
            }
        }
        else
        {
            Console.WriteLine("         Type: {0} Value: {1}", 
                cata.ArgumentType, cata.Value);
        }
    }
}

/**//* This code example produces output similar to the following:

Attributes for assembly: source, Version=0.0.0.0, Culture=neutral, PublicKeyToken=null
   [ExampleAttribute((ExampleKind)2, Note = "This is a note on the assembly.")]
      Constructor: Void .ctor(ExampleKind)
      Constructor arguments:
         Type: ExampleKind Value: 2
      Named arguments:
         MemberInfo: System.String Note
         Type: System.String Value: This is a note on the assembly.
   [System.Runtime.CompilerServices.CompilationRelaxationsAttribute((Int32)8)]
      Constructor: Void .ctor(Int32)
      Constructor arguments:
         Type: System.Int32 Value: 8
      Named arguments:

Attributes for type: Test
   [ExampleAttribute((ExampleKind)1, new String[3] { "String array argument, line 1", "String array argument, line 2", "String array argument, line 3" }, Note = "This is a note on the class.", Numbers = new Int32[3] { 53, 57, 59 })]
      Constructor: Void .ctor(ExampleKind, System.String[])
      Constructor arguments:
         Type: ExampleKind Value: 1
         Array of System.String[]:
             Type: System.String Value: String array argument, line 1
             Type: System.String Value: String array argument, line 2
             Type: System.String Value: String array argument, line 3
      Named arguments:
         MemberInfo: System.String Note
         Type: System.String Value: This is a note on the class.
         MemberInfo: Int32[] Numbers
         Array of System.Int32[]:
             Type: System.Int32 Value: 53
             Type: System.Int32 Value: 57
             Type: System.Int32 Value: 59

Attributes for member: Void TestMethod(System.Object)
   [ExampleAttribute(Note = "This is a note on a method.")]
      Constructor: Void .ctor()
      Constructor arguments:
      Named arguments:
         MemberInfo: System.String Note
         Type: System.String Value: This is a note on a method.

Attributes for parameter: System.Object arg
   [ExampleAttribute()]
      Constructor: Void .ctor()
      Constructor arguments:
      Named arguments:
*/