延迟渲染之由深度重建世界位置

前面一篇文章介绍了混合方式的延迟渲染(Hybrid deferred shading)，本文来讲解一下其中的一个细节，由深度构建世界位置，我们这里假定使用D3D9以及左手坐标系。

我在这里介绍两种方式，这两种方式也就跟实现方式有一定的关系。

方法1：

如果我们在第一遍中写深度时使用的是经过透视除法的z值

// 第一遍时输出深度
float4x4 matViewProjection;
struct VS_INPUT 
{
   float4 Position : POSITION0;
   
};
struct VS_OUTPUT 
{
   float4 Position : POSITION0;
   float2 Depth    : TEXCOORD0;   
};

VS_OUTPUT vs_main( VS_INPUT Input )
{
   VS_OUTPUT Output;
   Output.Position = mul( Input.Position, matViewProjection );
   // 除w为非线性运算，需要放到ps除
   Output.Depth = Output.Position.zw; 
   return( Output );  
}

float4 ps_main(float2 iDepth : TEXCOORD0) : COLOR0
{   
    // 输出除w后的值
   return iDepth.x / iDepth.y;
}

// 在计算光照时获取世界位置，此处仅为示例代码
struct VS_OUTPUT
{
   float4 Pos: POSITION;
   float4 TexCoord: TEXCOORD0;
};
VS_OUTPUT vs_main( float4 Pos: POSITION )
{
   VS_OUTPUT Out = (VS_OUTPUT) 0; 
   Out.Pos = float4(Pos.xy, 0.0, 1.0);
   Out.TexCoord.x = Out.Pos.x * 0.5 + 0.5;
   Out.TexCoord.y = 1.0 - (Out.Pos.y * 0.5 + 0.5);
   Out.TexCoord.zw = Pos.xy;
   return Out;
}

float4x4 fInvMatViewProj;
sampler2D depthTexture;        // 第一遍保存的深度纹理
float4 ps_main(float4 iUV : TEXCOORD0) : COLOR0
{   
   float fDepth = tex2D(depthTexture, iUV.xy).x;
   float4 vPos =  mul (float4(iUV.zw, fDepth, 1.0), fInvMatViewProj);
   // 需要除以w得到世界位置
   vPos = vPos / vPos.w;
   return vPos; 
}

如果是在d3d10或者更高版本的dx中，我们可以直接读取深度纹理，这样就可以减少一张RT，所以用这种 方法会比较省。D3D9下通过一些方法也可以得到，比如INTZ或者驱动暴露给D3D9的接口[1]。

第二种方法为直接保存摄像机空间中的z除以远裁剪面后的值。

// 第一遍时输出摄像机空间的z值除以远裁剪面的值
float4x4 matViewProjection;
float fFarClipPlane;
struct VS_INPUT 
{
   float4 Position : POSITION0;
   
};
struct VS_OUTPUT 
{
   float4 Position : POSITION0;
   float Depth    : TEXCOORD0;
   
};

VS_OUTPUT vs_main( VS_INPUT Input )
{
   VS_OUTPUT Output;

   Output.Position = mul( Input.Position, matViewProjection );
   // z值除以远裁剪面的值，此处为线性运算，帮可以放在vs中做除法，利用硬件插值传给ps使用
   Output.Depth = Output.Position.w / fFarClipPlane ; 
   return( Output );  
}

float4 ps_main(float iDepth : TEXCOORD0) : COLOR0
{   
   return iDepth;  
}



// 在计算光照时获取世界位置，利用相似三角形来求得。此处仅为示例代码
struct VS_OUTPUT
{
   float4 Pos         : POSITION;
   float2 UV          : TEXCOORD0;
   // 此处为世界空间内的摄像机远裁剪面四个点的值分别减去摄像机位置得到的向量
   float4 vFarCorner  : TEXCOORD1;        
};
VS_OUTPUT vs_main( float4 Pos: POSITION , float4 vFarCorner : TEXCOORD0)
{
   VS_OUTPUT Out = (VS_OUTPUT) 0; 
   Out.Pos = float4(Pos.xy, 0.0, 1.0);
   Out.vFarCorner = vFarCorner;
   Out.UV.x = Out.Pos.x * 0.5 + 0.5;
   Out.UV.y = 1.0 - (Out.Pos.y * 0.5 + 0.5);
   return Out;
}
    
float3 vCamPos;
sampler2D depthTexture; // 第一遍保存的深度纹理
float4 ps_main(float2 iUV : TEXCOORD0, float4 vFarCorner : TEXCOORD1) : COLOR0
{   
   float fDepth = tex2D(depthTexture, iUV.xy).x;
   // 根据相似三角形，反算世界位置。
   float4 vPos = float4(vCamPos + fDepth * vFarCorner, 1.0f);
   return vPos;
}

　　我们目前使用的是第二种方法，效率也还好，不过如果我们不考虑更大范围的支持老硬件，可能会使用参考文献[1]中的方法直接读取深度，这样第一种方法就比较合适了，当然还有其它一些方法，我也没有仔细去研究，读者如果有兴趣可以自己google，也可以参考[2]。相似三角形原理如下图所示：

其中x.z/fFarDist即为上面代码中的 Output.Depth = Output.Position.w / fFarClipPlane ;  ，乘以fFarVec这样就得到了一个向量，再加上世界空间中的摄像机位置就得到了最终的世界位置 。

　　最近看到自己的文章被别的网站盗用了，地址在这，转载也不写，文章最后的地址也是他们自己的，好像文章是他们写的一样--!对这种无耻的行为感到有点无奈，希望以后如果觉得文章还可以，转载文章请说明下，并注明出处，这也是对别人最基本的尊重吧。

参考文章：

[1] http://aras-p.info/texts/D3D9GPUHacks.html

[2] http://mynameismjp.wordpress.com/2009/03/10/reconstructing-position-from-depth/