Oracle数据库之开发PL/SQL子程序和包

PL/SQL块分为匿名块与命名块，命名块又包含子程序、包和触发器。

过程和函数统称为PL/SQL子程序，我们可以将商业逻辑、企业规则写成过程或函数保存到数据库中，以便共享。

过程和函数均存储在数据库中，并通过参数与其调用者交换信息。过程和函数的唯一区别是函数总向调用者返回数据，而过程不返回数据。

1. 存储过程概念

存储过程（Stored Procedure）是在大型数据库系统中，一组为了完成特定功能的SQL语句集，存储在数据库中。经过第一次编译后再次调用不需要再次编译，用户通过指定存储过程的名字并给出参数（如果该存储过程带有参数）来执行它。

存储过程是数据库中的一个重要对象，任何一个设计良好的数据库应用程序都应该用到存储过程。

2. 创建过程

语法：

CREATE [ OR REPLACE ] PROCEDURE [ schema. ] procedure_name
   [ ( parameter_declaration [, parameter_declaration ]... ) ]
   [ invoker_rights_clause ]
   { IS | AS }
   { [ declare_section ] body | call_spec | EXTERNAL} ;

说明：

procedure_name：过程名称。

parameter_declaration：参数声明，格式如下：

parameter_name [ [ IN ] datatype [ { := | DEFAULT } expression ]
          | { OUT | IN OUT } [ NOCOPY ] datatype 

IN：输入参数。

OUT：输出参数。

IN OUT：输入输出参数。

invoker_rights_clause：这个过程使用谁的权限运行，格式：

AUTHID { CURRENT_USER | DEFINER }

declare_section：声明部分。

body：过程块主体，执行部分。

一般只有在确认procedure_name过程是新过程或是要更新的过程时，才使用OR REPALCE关键字，否则容易删除有用的过程。

示例1：

CREATE PROCEDURE remove_emp (employee_id NUMBER) AS
   tot_emps NUMBER;
   BEGIN
      DELETE FROM employees
      WHERE employees.employee_id = remove_emp.employee_id;
      tot_emps := tot_emps - 1;
   END;

 示例2：

CREATE OR REPLACE PROCEDURE insert_emp(
   v_empno     in employees.employee_id%TYPE,
   v_firstname in employees.first_name%TYPE,
   v_lastname  in employees.last_name%TYPE,
   v_deptno    in employees.department_id%TYPE
   )
AS
   empno_remaining EXCEPTION;
   PRAGMA EXCEPTION_INIT(empno_remaining, -1);
BEGIN
   INSERT INTO EMPLOYEES(EMPLOYEE_ID, FIRST_NAME, LAST_NAME, HIRE_DATE,DEPARTMENT_ID)
   VALUES(v_empno, v_firstname,v_lastname, sysdate, v_deptno);
   DBMS_OUTPUT.PUT_LINE('插入成功！');
EXCEPTION
   WHEN empno_remaining THEN
      DBMS_OUTPUT.PUT_LINE('违反数据完整性约束!');
      DBMS_OUTPUT.PUT_LINE(SQLCODE||'---'||SQLERRM);
   WHEN OTHERS THEN
      DBMS_OUTPUT.PUT_LINE(SQLCODE||'---'||SQLERRM);
END;

3. 使用过程参数

当建立过程时，既可以指定过程参数，也可以不提供任何参数。

过程参数包括输入参数、输出参数和输入输出参数，其中输入参数（IN）用于接收调用环境的输入数据，输出参数（OUT）用于将输出数据传递到调用环境，而输入输出参数（IN OUT）不仅要接收输入数据，而且还要输出数据到调用环境。

3.1 带有输入参数的过程

通过使用输入参数，可以将应用程序数据传递到过程。当定义过程参数时，默认参数模式是输入参数，另外可以使用IN关键字显式定义输入参数。

示例：

CREATE OR REPLACE PROCEDURE insert_emp(
    empno employee.empno%TYPE,
    ename employee.ename%TYPE,
    job employee.job%TYPE,
    sal employee.sal%TYPE,
    comm IN employee.comm%TYPE,
    deptno IN employee.deptno%TYPE
    )
IS
BEGIN
    INSERT INTO employee VALUES(empno, ename, job, sal, comm, depno);
END;

3.2 带有输出参数的过程

通过在过程中使用输出参数，可以将数据或消息传递到调用环境和应用程序。当定义输出参数时，需要指定参数模式OUT。

示例：

CREATE OR REPLACE PROCEDURE update_sal(
    eno NUMBER,
    salary NUMBER,
    name out VARCHAR2) 
IS
BEGIN
    UPDATE employee SET sal=salary WHERE empno=eno
    RETURNING ename INTO name;
END;

3.3 带有输入输出参数的过程

通过在过程中使用输入输出参数，可以在调用过程时输入数据到过程，在调用结束后输出数据到调用环境和应用程序。当定义输入输出参数时，需要指定参数模式为IN OUT。

示例：

CREATE OR REPLACE PROCEDURE divide(
    num1 IN OUT NUMBER,
    num2 IN OUT NUMBER) 
IS
    v1 NUMBER;
    v2 NUMBER;
BEGIN
    v1 := trunc(num1 / num2);
    v2 := mod(num1,num2);
    num1 := v1;
    num2 := v2;
END; 

4. 调用过程

当在SQL*PLUS中调用过程时，需要使用CALL或者EXECUTE命令，而在PL/SQL块中过程可以直接引用。

ORACLE使用EXECUTE语句来调用存储过程语法：

 EXEC[UTE] procedure_name(parameter1, parameter2, …); 

示例：

-- 调用删除员工的过程
EXEC remove_emp(1);

-- 调用插入员工的过程
EXECUTE insert_emp(1, 'tommy', 'lin', 2);

 示例：

DECLARE
    v_name employee.ename%type;
BEGIN
    update_sal(&eno,&salary,v_name);
    dbms_output.put_line('姓名:'||v_name);
END;

5. 函数介绍

函数是一段独立的PL/SQL程序代码，它执行某个特定的、明确的任务。通常，函数将处理从程序的调用部分传递给它的信息，然后返回单个值。信息通过称为参数的特殊标识符传递给函数，然后通过RETURN语句返回。

6. 创建函数

语法：

CREATE [ OR REPLACE ] FUNCTION [ schema. ] function_name
  [ ( parameter_declaration [, parameter_declaration]... ) 
  ]
  RETURN datatype
  [ { invoker_rights_clause
    | DETERMINISTIC
    | parallel_enable_clause
    | RESULT_CACHE  [ relies_on_clause ]
    }...
  ]
  { { AGGREGATE | PIPELINED }  USING [ schema. ] implementation_type
  | [ PIPELINED ] { IS | AS } { [ declare_section ] body 
                              | call_spec
                              | EXTERNAL
                              }
  } ;

示例：

CREATE FUNCTION get_bal(acc_no IN NUMBER) 
   RETURN NUMBER 
   IS
     acc_bal NUMBER(11,2);
   BEGIN 
      SELECT order_total INTO acc_bal FROM orders 
      WHERE customer_id = acc_no; 
      RETURN(acc_bal); 
    END;

函数参数也有输入、输出、输入输出三种模式：IN、OUT、IN OUT是形参的模式。若省略，则为IN模式。

和过程一样，IN模式的形参只能将实参传递给形参，进入函数内部，但只能读不能写，函数返回时实参的值不变。

OUT模式的形参会忽略调用时的实参值（或说该形参的初始值总是NULL），但在函数内部可以被读或写，函数返回时形参的值会赋予给实参。

IN OUT具有前两种模式的特性，即调用时，实参的值总是传递给形参，结束时，形参的值传递给实参。

调用时，对于IN模式的实参可以是常量或变量，但对于OUT和IN OUT模式的实参必须是变量。

示例：

CREATE OR REPLACE FUNCTION get_salary(
  dept_no IN NUMBER DEFAULT 1,
  emp_count OUT NUMBER)
  RETURN NUMBER
IS
  V_sum NUMBER;
BEGIN
  SELECT SUM(SALARY), count(*) INTO V_sum, emp_count FROM EMPLOYEES
  WHERE DEPARTMENT_ID=dept_no;
  RETURN v_sum;
EXCEPTION
   WHEN NO_DATA_FOUND THEN
      DBMS_OUTPUT.PUT_LINE('数据不存在');
   WHEN OTHERS THEN
      DBMS_OUTPUT.PUT_LINE('其它异常：');
      DBMS_OUTPUT.PUT_LINE('错误号：' || SQLCODE||'，错误消息：'||SQLERRM);
END get_salary;

7 函数调用

语法：

function_name([[parameter_name1 =>] value1[, [parameter_name2 =>] value2, ...]]);

示例1：

DECLARE
  v_num NUMBER;
  v_sum NUMBER;
BEGIN
  v_sum := get_salary(27, v_num);
  DBMS_OUTPUT.PUT_LINE('部门27的工资总和：'||v_sum||'，人数为：'||v_num);
END;

示例二：

DECLARE
  v_num NUMBER;
  v_sum NUMBER;
BEGIN
  v_sum := get_salary(dept_no => 27, emp_count => v_num);
  DBMS_OUTPUT.PUT_LINE('部门27的工资总和：'||v_sum||'，人数为：'||v_num);
END;

示例3：

DECLARE
  v_num NUMBER;
  v_sum NUMBER;
BEGIN
  v_sum := get_salary(emp_count => v_num);
  DBMS_OUTPUT.PUT_LINE('部门27的工资总和：'||v_sum||'，人数为：'||v_num);
END;

8. 删除过程或函数

删除过程语法：

DROP PROCEDURE [schema.]procudure_name;

删除函数语法：

DROP FUNCTION [schema.]function_name;

9. 过程与函数比较

过程	函数
作为PL/SQL语句执行	作为表达式的一部分执行
在规范中不包含RETURN子句	必须在规范中包含RETURN子句
不返回任何值	必须返回单个值
可以RETURN语句，但是与函数不同，它不能用于返回值	必须包含至少一条RETURN语句

过程与函数的相同功能有：

1. 都使用IN模式的参数传入数据、OUT模式的参数返回数据。
2. 输入参数都可以接受默认值，都可以传值或传引导。
3. 调用时的实际参数都可以使用位置表示法、名称表示法或组合方法。
4. 都有声明部分、执行部分和异常处理部分。
5. 其管理过程都有创建、编译、授权、删除、显示依赖关系等。

-- 包

1. 简介

包(PACKAGE)是一种数据对象，它是一组相关过程、函数、变量、常量和游标等PL/SQL程序设计元素的组合，作为一个完整的单元存储在数据库中，用名称来标识。

包类似于JAVA或C#语言中的类，包中的变量相当于类中的成员变量，过程和函数相当于类方法。

通过使用包，可以简化应用程序设计，提高应用性能，实现信息隐藏、子程序重载等面向对象语言所具有的功能。

与高级语言中的类相同，包中的程序元素也分为公用元素和私用元素两种，这两种元素的区别是他们允许访问的程序范围不同。公用元素不仅可以被包中的函数、过程所调用，也可以被包外的PL/SQL程序访问，而私有元素只能被包内的函数和过程序所访问。

一般是先编写独立的过程与函数，待其较为完善或经过充分验证无误后，再按逻辑相关性组织为程序包。

2. 包的优点

1. 模块化：使用包，可以封装相关的类型、对象和子程序。把一个大的功能模块划分成多个小的功能模块，分别完成各自的功能，这样组织的程序易于编写，理解和管理。
2. 更轻松的应用程序设计：包规范部分和包体部分可以分别创建并编译。换言之，我们可以在没有编写包体的情况下编写包规范的代码并进行编译。
3. 信息隐藏：包中的元素可以分为公有元素和私有元素，公有元素可被程序包内的过程、函数等访问，还可以被包外的PL/SQL访问。但对于私有元素只能被包内的过程、函数等访问。对于用户，只需知道包规范，不用了解包体的具体细节。
4. 性能更佳：应用程序第一次调用程序包中的某个元素时，就将整个程序包加载到内存中，当第二次访问程序包中的元素时，ORACLE将直接从内在中读取，而不需要进行磁盘I/O操作而影响速度，同时位于内存中的程序包可被同一会话期间的其它应用程序共享。因此，程序包增加了重用性并改善了多用户、多应用程序环境的效率。

3. 包的定义

PL/SQL中的包由包规范和包体两部分组成。建立包时，首先要建立包规范，然后再建立对包规范的实现–包体。

包规范用于声明包的公用组件，如变量、常量、自定义数据类型、异常、过程、函数、游标等。包规范中定义的公有组件不仅可以在包内使用，还可以由包外其他过程、函数使用。但需要说明与注意的是，为了实现信息的隐藏，建议不要将所有组件都放在包规范处声明，只应把公共组件放在包规范部分。

包体是包的具体实现细节，它实现在包规范中声明的所有公有过程、函数、游标等。也可以在包体中声明仅属于自己的私有过程、函数、游标等。

3.1 建立包规范

语法：

CREATE [ OR REPLACE ] [ EDITIONABLE | NONEDITIONABLE ]
 PACKAGE [ schema. ] package_name
  [ invoker_rights_clause ]
  { IS | AS } item_list_1 END [ package_name ] ;

item_list_1：声明包的公用组件列表

{ type_definition -- 数据类型
| cursor_declaration -- 游标
| item_declaration -- 变量、常量等
| function_declaration -- 函数
| procedure_declaration -- 过程
}
  [ { type_definition
    | cursor_declaration
    | item_declaration
    | function_declaration
    | procedure_declaration
    | pragma
    }
  ]...

示例：

CREATE OR REPLACE PACKAGE emp_mgmt AS 
   -- 函数
   FUNCTION hire (last_name VARCHAR2, job_id VARCHAR2, 
      manager_id NUMBER, salary NUMBER, 
      commission_pct NUMBER, department_id NUMBER) 
      RETURN NUMBER; 
   FUNCTION create_dept(department_id NUMBER, location_id NUMBER) 
      RETURN NUMBER; 
   -- 过程
   PROCEDURE remove_emp(employee_id NUMBER); 
   PROCEDURE remove_dept(department_id NUMBER); 
   PROCEDURE increase_sal(employee_id NUMBER, salary_incr NUMBER); 
   PROCEDURE increase_comm(employee_id NUMBER, comm_incr NUMBER); 
   -- 异常
   no_comm EXCEPTION; 
   no_sal EXCEPTION; 
END emp_mgmt; 

3.2 建立包体
语法：

CREATE [ OR REPLACE ] PACKAGE BODY [ schema. ] package_name
{ IS | AS } 
    BEGIN statement [ statement | pragma ]...
      [ EXCEPTION exception_handler [ exception_handler ]... ]
 [ initialize_section ]
END [ package_name ] ;

示例：

CREATE OR REPLACE PACKAGE BODY emp_mgmt AS 
   tot_emps NUMBER; 
   tot_depts NUMBER; 
FUNCTION hire 
   (last_name VARCHAR2, job_id VARCHAR2, 
    manager_id NUMBER, salary NUMBER, 
    commission_pct NUMBER, department_id NUMBER) 
   RETURN NUMBER IS new_empno NUMBER; 
BEGIN 
   SELECT employees_seq.NEXTVAL 
      INTO new_empno 
      FROM DUAL; 
   INSERT INTO employees 
      VALUES (new_empno, 'First', 'Last','first.example@example.com', 
              '(415)555-0100','18-JUN-02','IT_PROG',90000000,00, 
              100,110); 
      tot_emps := tot_emps + 1; 
   RETURN(new_empno); 
END; 
FUNCTION create_dept(department_id NUMBER, location_id NUMBER) 
   RETURN NUMBER IS 
      new_deptno NUMBER; 
   BEGIN 
      SELECT departments_seq.NEXTVAL 
         INTO new_deptno 
         FROM dual; 
      INSERT INTO departments 
         VALUES (new_deptno, 'department name', 100, 1700); 
      tot_depts := tot_depts + 1; 
      RETURN(new_deptno); 
   END; 
PROCEDURE remove_emp (employee_id NUMBER) IS 
   BEGIN 
      DELETE FROM employees 
      WHERE employees.employee_id = remove_emp.employee_id; 
      tot_emps := tot_emps - 1; 
   END; 
PROCEDURE remove_dept(department_id NUMBER) IS 
   BEGIN 
      DELETE FROM departments 
      WHERE departments.department_id = remove_dept.department_id; 
      tot_depts := tot_depts - 1; 
      SELECT COUNT(*) INTO tot_emps FROM employees; 
   END; 
PROCEDURE increase_sal(employee_id NUMBER, salary_incr NUMBER) IS 
   curr_sal NUMBER; 
   BEGIN 
      SELECT salary INTO curr_sal FROM employees 
      WHERE employees.employee_id = increase_sal.employee_id; 
      IF curr_sal IS NULL 
         THEN RAISE no_sal; 
      ELSE 
         UPDATE employees 
         SET salary = salary + salary_incr 
         WHERE employee_id = employee_id; 
      END IF; 
   END; 
PROCEDURE increase_comm(employee_id NUMBER, comm_incr NUMBER) IS 
   curr_comm NUMBER; 
   BEGIN 
      SELECT commission_pct 
      INTO curr_comm 
      FROM employees 
      WHERE employees.employee_id = increase_comm.employee_id; 
      IF curr_comm IS NULL 
         THEN RAISE no_comm; 
      ELSE 
         UPDATE employees 
         SET commission_pct = commission_pct + comm_incr; 
      END IF; 
   END; 
END emp_mgmt;

4. 调用包的组件

包的名称是唯一的，但对于两个包中的公有组件的名称可以相同，用“包名.公有组件名“加以区分。

示例：

DECLARE
    new_dno NUMBER; -- 部门编号
BEGIN
    -- 调用emp_mgmt包的create_dept函数创建部门：
    new_dno := emp_mgmt.create_dept(85, 100);
    DBMS_OUTPUT.PUT_LINE('部门编号：' || new_dno);

    -- 调用emp_mgmt包的increase_sal过程为员工加薪：
    emp_mgmt.increase_sal(23, 800);
END;

5. 包中的游标

在包中使用无参游标，示例：

--定义包规范
CREATE OR REPLACE PACKAGE PKG_STU IS
    CURSOR getStuInfo RETURN stuInfo%ROWTYPE; 
END PKG_STU;

--定义包体
CREATE OR REPLACE PACKAGE BODY PKG_STU AS
    CURSOR getStuInfo RETURN stuInfo%ROWTYPE IS
        SELECT * FROM stuInfo; 
END PKG_STU;

--调用包组件
BEGIN
    FOR stu_Record IN PKG_STU.getStuInfo LOOP  
       DBMS_OUTPUT.PUT_LINE('学员姓名:'||stu_Record.name||'，学号:'||stu_Record.id||'，年龄:'||stu_Record.age);      
    END LOOP; 
END;  

在包中使用有参数的游标，示例：

--定义包规范
CREATE OR REPLACE PACKAGE PKG_STU IS
    CURSOR getStuInfo(studentNo VARCHAR2) RETURN stuInfo%ROWTYPE; 
END PKG_STU;

--定义包体
CREATE OR REPLACE PACKAGE BODY PKG_STU AS
    CURSOR getStuInfo(studentNo VARCHAR2) RETURN stuInfo%ROWTYPE IS
        SELECT * FROM stuInfo WHERE id=studentNo; 
END PKG_STU;

--调用包组件
BEGIN
    FOR stu_Record IN PKG_STU.getStuInfo(2) LOOP  
        DBMS_OUTPUT.PUT_LINE('学员姓名:'||stu_Record.name||'，学号:'||stu_Record.id||'，年龄:'||stu_Record.age);      
    END LOOP; 
END;

由于游标变量是一个指针，其状态是不确定的，因此它不能随同包存储在数据库中，即不能在PL/SQL包中声明游标变量。但在包中可以创建游标变量参照类型，并可向包中的子程序传递游标变量参数。

示例：

-- 创建包规范
CREATE OR REPLACE PACKAGE CURROR_VARIBAL_PKG AS
  TYPE dept_cur_type IS REF CURSOR RETURN dept%ROWTYPE; --强类型

  TYPE cur_type IS REF CURSOR;-- 弱类型

  PROCEDURE proc_open_dept_var(
    dept_cur IN OUT dept_cur_type,
    choice INTEGER DEFAULT 0,
    dept_no NUMBER DEFAULT 50,
    dept_name VARCHAR DEFAULT '%');
END;

-- 创建包体
CREATE OR REPLACE PACKAGE BODY CURROR_VARIBAL_PKG
AS
  PROCEDURE proc_open_dept_var(
    dept_cur IN OUT dept_cur_type,
    choice INTEGER DEFAULT 0,
    dept_no NUMBER DEFAULT 50,
    dept_name VARCHAR DEFAULT '%')
  IS 
  BEGIN
    IF choice = 1 THEN
      OPEN dept_cur FOR SELECT * FROM dept WHERE deptno = dept_no;
    ELSIF choice = 2 THEN
      OPEN dept_cur FOR SELECT * FROM dept WHERE dname LIKE dept_name;
    ELSE
      OPEN dept_cur FOR SELECT * FROM dept;
    END IF;
  END proc_open_dept_var;
END CURROR_VARIBAL_PKG;

定义一个过程，打开弱类型的游标变量：

--定义过程
CREATE OR REPLACE PROCEDURE proc_open_cur_type(
  cur IN OUT CURROR_VARIBAL_PKG.cur_type,
  first_cap_in_table_name CHAR) 
AS
BEGIN
  IF first_cap_in_table_name = 'D' THEN
    OPEN cur FOR SELECT * FROM dept;
  ELSE
    OPEN cur FOR SELECT * FROM emp;
  END IF;
END proc_open_cur_type;

测试包中游标变量类型的使用：

DECLARE 
  dept_rec Dept%ROWTYPE;
  emp_rec Emp%ROWTYPE;
  dept_cur CURROR_VARIBAL_PKG.dept_cur_type;
  cur CURROR_VARIBAL_PKG.cur_type;
BEGIN
  DBMS_OUTPUT.PUT_LINE('游标变量强类型：');
  CURROR_VARIBAL_PKG.proc_open_dept_var(dept_cur, 1, 30);
  FETCH dept_cur INTO dept_rec;
  WHILE dept_cur%FOUND LOOP
    DBMS_OUTPUT.PUT_LINE(dept_rec.deptno||':'||dept_rec.dname);
    FETCH dept_cur INTO dept_rec;
  END LOOP;
  CLOSE dept_cur;

  DBMS_OUTPUT.PUT_LINE('游标变量弱类型：');
  CURROR_VARIBAL_PKG.proc_open_dept_var(cur, 2, dept_name => 'A%');
  FETCH cur INTO dept_rec;
  WHILE cur%FOUND LOOP
    DBMS_OUTPUT.PUT_LINE(dept_rec.deptno||':'||dept_rec.dname);
    FETCH cur INTO dept_rec;
  END LOOP;

  DBMS_OUTPUT.PUT_LINE('游标变量弱类型—dept表：');
  proc_open_cur_type(cur, 'D');
  FETCH cur INTO dept_rec;
  WHILE cur%FOUND LOOP
    DBMS_OUTPUT.PUT_LINE(dept_rec.deptno||':'||dept_rec.dname);
    FETCH cur INTO dept_rec;
  END LOOP;

  DBMS_OUTPUT.PUT_LINE('游标变量弱类型—emp表：');
  proc_open_cur_type(cur, 'E');
  FETCH cur INTO emp_rec;
  WHILE cur%FOUND LOOP
    DBMS_OUTPUT.PUT_LINE(emp_rec.empno||':'||emp_rec.ename);
    FETCH cur INTO emp_rec;
  END LOOP;
  CLOSE cur;
END;

6. 子程序重载

所谓重载时指两个或多个子程序有相同的名称，但拥有不同的参数变量、参数顺序或参数数据类型。

在调用重载子程序时，主程序将根据实际参数的类型和数目，自动确定调用哪个子程序。

PL/SQL允许对包内子程序和本地子程序进行重载。

示例：

-- 定义包规范
CREATE OR REPLACE PACKAGE PKG_EMP AS
    FUNCTION get_salary(eno NUMBER) RETURN NUMBER;
    FUNCTION get_salary(empname VARCHAR2) RETURN NUMBER;
END PKG_EMP;

-- 定义包体
CREATE OR REPLACE PACKAGE BODY PKG_EMP AS
    FUNCTION get_salary(eno NUMBER) RETURN NUMBER
      IS
        v_salary NUMBER(10, 4);
      BEGIN
        SELECT sal INTO v_salary FROM emp WHERE empno=eno;
        RETURN v_salary;
      END;

    FUNCTION get_salary(empname VARCHAR2) RETURN NUMBER
      IS
        v_salary NUMBER(10, 4);
      BEGIN
        SELECT sal INTO v_salary FROM emp WHERE ename=empname;
        RETURN v_salary;
      END;
END PKG_EMP;

测试：

DECLARE
  v_sal NUMBER(10, 4);
BEGIN  
  v_sal := PKG_EMP.get_salary(7499);
  DBMS_OUTPUT.PUT_LINE('工资：' || v_sal);
  v_sal := PKG_EMP.get_salary('MARTIN');
  DBMS_OUTPUT.PUT_LINE('工资：' || v_sal);
END;