表变量在存储过程或sql server中的运用

经常遇见过这种情况，在存储过程中经常用with创建临时表，这个临时表这这个功能模块中多次运用，如果都用With创建相同功能的临时表，好性能和存储过程中有很多冗余代码，为此，我用表变量来实现此种功能(不是表值变量)

定义表变量的语法：

DECLARE 表变量名字 TABLE(

列名 列类型 是否为空,

列名 列类型 是否为空,

列名 列类型 是否为空，

列名 列类型 是否为空

)

下面是我这项目中运用的存储过程：

USE [xb_quotation_dev2]
GO

/****** Object:  StoredProcedure [dbo].[usp_UpdateTodayPriceMange]    Script Date: 02/18/2012 14:34:43 ******/
SET ANSI_NULLS ON
GO

SET QUOTED_IDENTIFIER ON
GO

CREATE PROCEDURE [dbo].[usp_UpdateTodayPriceMange] 
    @dt Ty_PublicTodayPrice READONLY
AS
BEGIN
    SET NOCOUNT ON;
    DECLARE @ERRORSMALL SMALLINT =0;
    BEGIN TRAN;
        SET @ERRORSMALL=-1;
        DECLARE @dt_Prices TABLE(AreaID INT NOT NULL ,GoodsId INT NOT NULL,GuidePrice DECIMAL(18,4) NOT NULL );
            WITH temp_1 AS(
                SELECT AreaID,GoodsId,GuidePrice FROM @dt
                UNION ALL
                SELECT a.AreaId,t.GoodsId,t.GuidePrice FROM MD_Area a INNER JOIN @dt t
                    ON a.QuotationType= t.AreaID 
                    AND EXISTS(SELECT 0 FROM MD_Goods g WHERE g.TypeId=a.GoodsTypeId AND g.ID= t.GoodsId)
            )
        INSERT INTO @dt_Prices SELECT AreaID,GoodsId,GuidePrice FROM temp_1;
            UPDATE  up SET up.GuidePrice=tp.GuidePrice  FROM  MD_UpdatePrice up INNER JOIN  @dt_Prices tp on up.AreaId=tp.AreaId and up.GoodsId=tp.GoodsId
            AND CONVERT(VARCHAR(10),up.PriceDate,120)=CONVERT(VARCHAR(10),GETDATE(),120)
                IF(@@ERROR<>0) GOTO ERROR_Handler;
        SET @ERRORSMALL=-2;
            INSERT INTO MD_UpdatePrice(AreaID,GoodsId,GuidePrice, PriceDate) 
                SELECT t.*,GETDATE() FROM @dt_Prices t WHERE NOT EXISTS(SELECT 0 FROM MD_UpdatePrice up WHERE up.AreaID=T.AreaID AND up.GoodsId= t.GoodsId)    
                IF(@@ERROR<>0) GOTO ERROR_Handler;
        SET @ERRORSMALL=-3;
            UPDATE h SET h.GuidePrice=t.GuidePrice  FROM  MD_HistoryPrices h,@dt_Prices t WHERE  h.GoodsId = t.GoodsId
                 AND h.AreaID=t.AreaID AND CONVERT(VARCHAR(10),h.PriceDate,120)=CONVERT(VARCHAR(10),GETDATE(),120);
                IF(@@ERROR<>0) GOTO ERROR_Handler;
        SET @ERRORSMALL=-4;
            UPDATE p SET  p.GuidePrice=tt.GuidePrice  FROM MD_Prices p inner join @dt_Prices tt
                 on  P.GoodsId = tt.GoodsId AND
                 p.AreaID =tt.AreaID AND CONVERT(VARCHAR(10),p.PriceDate,120)=CONVERT(VARCHAR(10),GETDATE(),120);
        IF(@@ERROR<>0) GOTO ERROR_Handler;
    COMMIT TRAN;
    RETURN 0;
ERROR_Handler:
    ROLLBACK TRAN;
    RETURN @ERRORSMALL;
END



GO

可以看到这上面的存储过程中，定义一个表变量，

DECLARE @dt_Prices TABLE(AreaID INT NOT NULL ,GoodsId INT NOT NULL,GuidePrice DECIMAL(18,4) NOT NULL );

此表变量@dt_Prices 有3列，分别是AreaID,GoodsId,GuidePrice，他们类型分别是整形，整形，双精度，都是非空；

 可以看到在下面的功能模块中我分别用到这个表变量@dt_Prices

对于上面的存储过程，我定义了一个表值变量Ty_PublicTodayPrice，创建这个表值变量的语法是：

USE [xb_quotation_dev2]
GO

/****** Object:  UserDefinedTableType [dbo].[Ty_PublicTodayPrice]    Script Date: 02/18/2012 14:43:42 ******/
CREATE TYPE [dbo].[Ty_PublicTodayPrice] AS TABLE(
    [AreaID] [int] NOT NULL,
    [GoodsId] [int] NOT NULL,
    [GuidePrice] [decimal](18, 4) NULL
)
GO