Delphi PointerMath编译指令

我们知道在C和C++里面声明一个指针,但是可以像数组一样去访问里面的成员.

在Delphi2009之后我们有了{$POINTERMATH ON}编译开关,我们也可以了.
一般在Delphi2009之前的版本中,我们会用如下几个方法:

1

var
  P: PByteArray;
begin
  P:= PByteArray(某指针);
  P^[0]:= 1;
  P^[1]:= 2;
  ...
end;

2

var
  P: PByte;
begin
  P:= PByte(某地址);
  P^:= 1;
  P:= PByte(Integer(P)+需要偏移的地址);
  P^:= 2;
  ...
end;

3

var
  P: PByte;//或者PChar也可以
begin
  P:= PByte(某地址);
  P^:= 1;
  Inc(P);   //地址+1
  P^:= 2;
  Dec(P);   //地址-1
  P^:= 2;
end;

在用第2 和 3方法的时候,如果内存空间不是我们例子上面转换过来,而是自己申请的,那么释放的时候,请记得偏移后的指针一定要归位,所以一般在偏移前,我们会用一个临时变量来存放指针的初始位置.切记.

好,现在说说Delphi2009中POINTERMATH的用法:

{$POINTERMATH ON}
procedure TForm4.btn1Click(Sender: TObject);
var
  P: PByte;
begin
  GetMem(P, 4);
  try
    //01 03 05 07
    P[0]:= 1;
    P[1]:= 3;
    P[2]:= 5;
    P[3]:= 7;
    //$07050301
    ShowMessage(IntToHex(PInteger(P)^,8));//07050301
  finally
    FreeMem(P);
  end;
end;
{$POINTERMATH OFF}

和C++就一样了.
自己定义的结构体也可以.

type
  PRect = ^TRect;
var
  P: PRect;
begin
  GetMem(P, 4 * SizeOf(TRect));
  try
    //01 03 05 07
    P[0].Left:= 12;
    P[1].Top:= 22;
    P[2].Right:= 32;
    P[3].Bottom:= 42;
    //$07050301
    ShowMessage(IntToStr(P[2].Right));//07050301
  finally
    FreeMem(P);
  end;
end;
{$POINTERMATH OFF}

再看一个有用的.下面是用GDIPlus对图像进行均值灰度化.

uses
  GdiPlus,GdiPlusHelpers;

{$R *.dfm}
type
  PABGR = ^TABGR;
  //像素点的4个通道
  TABGR = record
    B,G,R,A: Byte;
  end;
{$POINTERMATH ON}
procedure TForm4.btn1Click(Sender: TObject);
var
  B: IGPBitmap;
  RC: TGPRect;
  BD: TGPBitmapData;
  P: PABGR;
  I,J: Integer;
begin
  B:= TGPBitmap.Create('C:\1.png');
  RC.Initialize(0,0,B.Width, B.Height);//需要处理的图像的区域
  //因为我们结构体定义的是4个字节的ABGR的,所以第3个参数必须是PixelFormat32bppARGB
  BD:= B.LockBits(RC, [ImageLockModeRead, ImageLockModeWrite], PixelFormat32bppARGB);
  try
    P:= PABGR(Bd.Scan0);//实际像素区域.
    for I := 0 to BD.Width * BD.Height -1 do
    begin
      J:= (P[I].B + P[I].G + P[I].R) ;//防止溢出
      P[I].B:= J div 3;
      P[I].G:= P[I].B;
      P[I].R:= P[I].B;
    end;
  finally
    B.UnlockBits(BD);
  end;
  Form4.Canvas.ToGPGraphics.DrawImage(B,10,10);//画出灰度化的图像
end;
{$POINTERMATH OFF}

实验发现在GDIPlus中我们必须用4字节的结构体,Packed Record的3字节的结构体会报错.

今天就只说这么点儿了.byebye各位.