解析XML和XMLNS

在不知道夫节点和属性情况下，查找XML中某节点或属性

var xml:XML = <order>
                <item name="00">
                    <item1 >
                        <item2 name="22">222</item2>
                    </item1>
                </item>
                   <item>
                    <item1>123</item1>
                    <item2>222</item2>
                </item>
                </order>;
//查找节点
trace(xml..item)
trace(xml.descendants("item"))
//查找属性
trace(xml..@["name"])
for each (var i:String in xml.descendants("item1"))
{
    trace(i);
}

读取WebService返回的数据位XMLNS，即XML Namespaces的缩写，具有有命名空间的XML。

至于如何连接WebService和读取数据，可以用这封装好的WebService类包:http://labs.alducente.com/gophr/ 。

xmlns解析代码如下：

import alducente.services.WebService;
import flash.events.*;

var ws:WebService = new WebService();
ws.addEventListener(Event.CONNECT, connected);
ws.connect("http://searcher.ce4.cn/mobile/default.asmx?wsdl");
ws.cacheResults = true;

var initTime:Number;
var serviceRespone:XML;

function connected(evt:Event):void
{
    initTime = getTimer();
    ws.GetTotals(getTotals,"12");
    ws.GetDataList(getDataList,"广州",1,10);
}
//获取信息总数
function getTotals(serviceRespone:XML):void
{
    //trace(serviceRespone);
    var soapNS:Namespace = serviceRespone.namespace("soap");
    var wNS:Namespace = new Namespace("w","http://tempuri.org/");
    serviceRespone.addNamespace(wNS);
    var totals:XMLList = serviceRespone.soapNS::Body.wNS::GetTotalsResponse.wNS::GetTotalsResult;
    //trace(totals)
}
//获取详细信息
function getDataList(serviceRespone:XML):void
{
    trace(serviceRespone);
    var soapNS:Namespace = serviceRespone.namespace("soap");
    var wNS:Namespace = new Namespace("w","http://tempuri.org/");
    var title:XMLList = new XMLList();
    var content:XMLList = new XMLList();
    var prevurl:XMLList = new XMLList();
    serviceRespone.addNamespace(wNS);
    //命名空间::节点名
    title = serviceRespone.soapNS::Body.wNS::GetDataListResponse.wNS::GetDataListResult.wNS::DataInfo.wNS::title;
    content = serviceRespone.soapNS::Body.wNS::GetDataListResponse.wNS::GetDataListResult.wNS::DataInfo.wNS::content;
    prevurl = serviceRespone.soapNS::Body.wNS::GetDataListResponse.wNS::GetDataListResult.wNS::DataInfo.wNS::prevurl;
    for each (var item_content in content)
    {
        trace(item_content);
    }
}