效果比较好的头发shader

效果如下：

渲染头发时可能会遇到如下问题：

1. 因为头发本质上是一个一个的透明的面片，理所当然会想到使用 blend 混合方式来渲染。

但当由于用 blend 时，要关闭Z缓存写，即执行 Zwirte Off，不然透明的区域也会遮挡后面的像素。

此时就会出现问题，头发之间的层级会完全混乱，因为头发是多个面片穿插在一起的。

2. 因此不能使用blend的方式，就只能使用 Alpha Test 的方式来强制丢弃透明的像素。

但 Alpha Test 的问题的边缘部分不够平滑，剧齿感明显。

解决此问题的思路是，一个通道执行 Alpha Test，把透明区域直接丢弃掉。

另一个通道执行 Blend 混合，把 Alpha Test 丢弃的像素再重新渲染一遍。

示例代码如下：

Shader "Character/Example-Diffuse-Hair"
{
    Properties
    {
        _Color ("Main Color", Color) = (1,1,1,1)
        _MainTex ("Base (RGB)", 2D) = "white" {}
        _Cutoff( "Cutoff", Range (0,1)) = 0.5
    }

    SubShader
    {
        Tags 
        {
            "RenderType" = "Transparent"
            "IgnoreProjector" = "True"
            "Queue" = "Transparent+100"
        }
        LOD 200

        Pass
        {
            Tags
            {
                "LightMode" = "ForwardBase"
            }
            Blend SrcAlpha OneMinusSrcAlpha
            Cull Off

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fwdbase

            #include "UnityCG.cginc"
            #include "AutoLight.cginc"
            #include "Lighting.cginc"

            fixed4 _Color;
            sampler2D _MainTex;
            float _Cutoff;
            
            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
                float3 normal : NORMAL;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                float2 uv : TEXCOORD0;
                float3 worldPos : TEXCOORD1;
                float3 worldNormal : TEXCOORD2;
            };

            v2f vert(appdata v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.uv = v.uv;
                o.worldPos = mul(unity_ObjectToWorld, v.vertex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                return o;
            }

            fixed4 frag(v2f i) : SV_TARGET
            {
                fixed4 albedo = tex2D(_MainTex, i.uv) * _Color;
                clip(albedo.a - _Cutoff);

                fixed3 ambient = albedo.rgb * UNITY_LIGHTMODEL_AMBIENT.rgb;

                fixed3 worldLight = UnityWorldSpaceLightDir(i.worldPos);
                float d = dot(worldLight, i.worldNormal) * 0.5 + 0.5;
                fixed3 diffuse = albedo.rgb * _LightColor0.rgb * d;
                
                fixed4 col = fixed4(ambient + diffuse * 2, albedo.a);

                return col;
            }

            ENDCG
        }

        Pass
        {
            Tags
            {
                "LightMode" = "ForwardBase"
            }
            Blend SrcAlpha OneMinusSrcAlpha
            ZWrite Off

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fwdbase

            #include "UnityCG.cginc"
            #include "AutoLight.cginc"
            #include "Lighting.cginc"

            fixed4 _Color;
            sampler2D _MainTex;
            float _Cutoff;
            
            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
                float3 normal : NORMAL;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                float2 uv : TEXCOORD0;
                float3 worldPos : TEXCOORD1;
                float3 worldNormal : TEXCOORD2;
            };

            v2f vert(appdata v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.uv = v.uv;
                o.worldPos = mul(unity_ObjectToWorld, v.vertex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                return o;
            }

            fixed4 frag(v2f i) : SV_TARGET
            {
                fixed4 albedo = tex2D(_MainTex, i.uv) * _Color;
                clip(_Cutoff - albedo.a);

                fixed3 ambient = albedo.rgb * UNITY_LIGHTMODEL_AMBIENT.rgb;

                fixed3 worldLight = normalize(UnityWorldSpaceLightDir(i.worldPos));
                float d = dot(worldLight, i.worldNormal) * 0.5 + 0.5;
                fixed3 diffuse = albedo.rgb * _LightColor0.rgb * d;
                
                fixed4 col = fixed4(ambient + diffuse * 2, albedo.a);

                return col;
            }

            ENDCG
        }
        
        
    } 

    Fallback "Diffuse"
}

转载请注明出处：https://www.cnblogs.com/jietian331/p/12621455.html