如何实现化妆功能

如何实现化妆功能，更换眉毛，嘴唇，眼球，胡子等？

即如下效果：

首先是shader，这个实现起来想必非常简单，相当于把一张要替换的图片叠加到脸部纹理上，当然还要给定一个具体的纹理坐标。

示例代码如下：

Shader "America/Character/Tattoo/America-Diffuse-AlphaTest-Face"
{
    Properties
    {
        _Color ("Main Color", Color) = (1,1,1,1)
        _MainTex ("Base (RGB)", 2D) = "white" {}
        _Ramp ("Toon Ramp (RGB)", 2D) = "gray" {}
        
        _OverlyingColor("Overlying Color", Color) = (0.5, 0.5, 0.5, 1)

        _TattooTex1 ("Tattoo 1 (RGBA)", 2D) = "black" {}
        _TattooPos1 ("Tattoo Position 1", Vector) = (0,0,1,1)
        _TattooTex2 ("Tattoo 2 (RGBA)", 2D) = "black" {}
        _TattooPos2 ("Tattoo Position 2", Vector) = (0,0,1,1)
        _TattooTex3 ("Tattoo 3 (RGBA)", 2D) = "black" {}
        _TattooPos3 ("Tattoo Position 3", Vector) = (0,0,1,1)
        _TattooTex4 ("Tattoo 4 (RGBA)", 2D) = "black" {}
        _TattooPos4 ("Tattoo Position 4", Vector) = (0,0,1,1)
    }

    SubShader
    {
        Tags 
        {
            "RenderType" = "Transparent"
            "IgnoreProjector" = "True"
            "Queue" = "Transparent+100"
        }
        LOD 200
        
        Pass
        {
            Tags
            {
                "LightMode" = "ForwardBase"
            }
            Cull Off

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fwdbase

            #include "UnityCG.cginc"
            #include "AutoLight.cginc"
            #include "Lighting.cginc"

            #include "../AmericaCG.cginc"

            fixed4 _Color;
            sampler2D _MainTex;
            sampler2D _Ramp;
            fixed4 _OverlyingColor;
            
            sampler2D _TattooTex1;
            float4 _TattooPos1;
            sampler2D _TattooTex2;
            float4 _TattooPos2;
            sampler2D _TattooTex3;
            float4 _TattooPos3;
            sampler2D _TattooTex4;
            float4 _TattooPos4;

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
                float3 normal : NORMAL;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                float2 uv : TEXCOORD0;
                float3 worldPos : TEXCOORD1;
                float3 worldNormal : TEXCOORD2;
            };

            v2f vert(appdata v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.uv = v.uv;
                o.worldPos = mul(unity_ObjectToWorld, v.vertex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                return o;
            }

            fixed4 frag(v2f i) : SV_TARGET
            {
                fixed4 albedo = tex2D(_MainTex, i.uv);
                
                // 纹身
                albedo = ApplyTattoo(i.uv, _TattooTex1, _TattooPos1, albedo);
                albedo = ApplyTattoo(i.uv, _TattooTex2, _TattooPos2, albedo);
                albedo = ApplyTattoo(i.uv, _TattooTex3, _TattooPos3, albedo);
                albedo = ApplyTattoo(i.uv, _TattooTex4, _TattooPos4, albedo);

                albedo *= _Color;

                fixed3 ambient = albedo.rgb * UNITY_LIGHTMODEL_AMBIENT.rgb;

                fixed3 worldLight = normalize(UnityWorldSpaceLightDir(i.worldPos));
                float d = dot(worldLight, i.worldNormal) * 0.5 + 0.5;
                fixed3 rampCol = tex2D(_Ramp, float2(d, d)).rgb;
                fixed3 diffuse = albedo.rgb * _LightColor0.rgb * rampCol;
                
                fixed4 col = fixed4(ambient + diffuse * 2, albedo.a);
                col.rgb = Overlay(col, _OverlyingColor);

                return col;
            }

            ENDCG
        }


    } 

    Fallback "Diffuse"
}

其中，ApplyTattoo的实现如下：

// 应用纹身
fixed4 ApplyTattoo(float2 uv, sampler2D tattooTex, float4 tattooPos, fixed4 albedo)
{
    if (uv.x >= tattooPos.x && uv.x <= tattooPos.x+tattooPos.z && uv.y >= tattooPos.y && uv.y <= tattooPos.y + tattooPos.w)
    {
        fixed tattooU = (uv.x - tattooPos.x) / tattooPos.z;
        fixed tattooV = (uv.y - tattooPos.y) / tattooPos.w;
        fixed2 tattooUV = fixed2(tattooU, tattooV);
        fixed4 tattooCol = tex2D(tattooTex, tattooUV);
        albedo.rgb = lerp(albedo.rgb, tattooCol.rgb, tattooCol.a);
    }

    return albedo;
}

转载请注明出处：https://www.cnblogs.com/jietian331/p/12659339.html

 材质球面板如下：