Unity shader学习之卡通渲染，轮廓线

效果如下（头部无轮廓）：

原理：使用2个pass来渲染。

第一个pass中，使用轮廓线颜色渲染整个背面，并在视角空间下把模型顶点沿着法线方法向外扩张一段距离，来让轮廓线可见，公式为：

viewPos += viewNormal * _Outline;

注意：如果直接使用顶点法线进行扩展，对于一些内凹的模型，就可能发生背面面片遮挡正面面片的情况。为了尽可能防止出现这样的情况，在扩张背面顶点之前，我们首先对顶点法线的z分量进行处理，使它们等于一个定值，然后把法线归一化后再对顶点进行扩张。这样的好处在于，扩展后的背面更加扁平化，从而降低了遮挡正面面片的可能性。代码如下：

viewNormal.z = -0.5;

viewNormal = normalize(viewNormal);

viewPos += viewNormal * _Outline;

第二个pass中，正常渲染物体。

参考shader代码如下：

Shader "America/Character/America-Diffuse-AlphaTest-Face"
{
    Properties
    {
        _Color ("Main Color", Color) = (1,1,1,1)
        _MainTex ("Base (RGB)", 2D) = "white" {}
        _NormalMap("Normal Map", 2D) = "bump" {}

        _DiffuseRate ("Diffuse Rate", float) = 2
        _Ramp ("Toon Ramp (RGB)", 2D) = "gray" {}
        _RampRate ("Ramp Rate", float) = 1

        _OverlyingColor("Overlying Color", Color) = (0.5, 0.5, 0.5, 1)

    }

    SubShader
    {
        Tags 
        {
            "RenderType" = "Transparent"
            "IgnoreProjector" = "True"
            "Queue" = "Transparent+100"
        }
        LOD 200
        
        
        Pass
        {
            NAME "OUTLINE"

            Cull Front

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            struct appdata
            {
                float4 vertex : POSITION;
                float4 normal : NORMAL;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
            };

            v2f vert(appdata v)
            {
                v2f o;

                float4 viewPos = mul(UNITY_MATRIX_MV, v.vertex);
                float4 viewNormal = mul(UNITY_MATRIX_IT_MV, v.normal);

                viewNormal.z = -0.5;
                o.pos = mul(UNITY_MATRIX_P, viewPos + normalize(viewNormal) * 0.01);

                return o;
            };

            float4 frag(v2f i) : SV_TARGET
            {
                return float4(0, 0, 0, 1);
            };

            ENDCG
        }

        Pass
        {
            Tags
            {
                "LightMode" = "ForwardBase"
            }
            Cull Off

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fwdbase

            #include "UnityCG.cginc"
            #include "AutoLight.cginc"
            #include "Lighting.cginc"

            #include "../AmericaCG.cginc"

            fixed4 _Color;
            sampler2D _MainTex;
            sampler2D _NormalMap;
            float _DiffuseRate;
            sampler2D _Ramp;
            float _RampRate;
            fixed4 _OverlyingColor;

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
                float3 normal : NORMAL;
                float4 tangent : TANGENT;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                float2 uv : TEXCOORD0;
                float4 T2W1 : TEXCOORD1;
                float4 T2W2 : TEXCOORD2;
                float4 T2W3 : TEXCOORD3;
            };

            v2f vert(appdata v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.uv = v.uv;
                
                float3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
                float3 worldNormal = UnityObjectToWorldNormal(v.normal);
                float3 binormal = cross(normalize(worldNormal), normalize(worldTangent)) * v.tangent.w;
                float3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
                o.T2W1 = float4(worldTangent.x, binormal.x, worldNormal.x, worldPos.x);
                o.T2W2 = float4(worldTangent.y, binormal.y, worldNormal.y, worldPos.y);
                o.T2W3 = float4(worldTangent.z, binormal.z, worldNormal.z, worldPos.z);
                return o;
            }

            fixed4 frag(v2f i) : SV_TARGET
            {
                float3 worldPos = float3(i.T2W1.w, i.T2W2.w, i.T2W3.w);
                float3 worldLight = normalize(UnityWorldSpaceLightDir(worldPos));
                //float3 worldView = normalize(UnityWorldSpaceViewDir(worldPos));
                float3 tangentNormal = UnpackNormal(tex2D(_NormalMap, i.uv));
                float3x3 tanToWorld = float3x3(i.T2W1.xyz, i.T2W2.xyz, i.T2W3.xyz);
                float3 worldNormal = mul(tanToWorld, tangentNormal);
                
                fixed4 albedo = tex2D(_MainTex, i.uv) * _Color;
                fixed3 diffuse = CalcDiffuse(albedo, worldLight, worldNormal, _Ramp, _RampRate);
                
                fixed4 col = fixed4(diffuse * _DiffuseRate, albedo.a);
                col.rgb = Overlay(col, _OverlyingColor);

                return col;
            }

            ENDCG
        }

    } 

    Fallback "Diffuse"
}

转载请注明出处：https://www.cnblogs.com/jietian331/p/13633051.html