CG之菲涅尔效果简单实现

　　菲涅尔效果，指当光到达两种材质的接触面时，一些光在接触面的表面被反射出去，而另一部分光将发生折射穿过接触面。

　　现在要用shader来实现这种效果，如果要精确地描述这种底层的物理，其计算公式是非常复杂的，性能消耗也比较大。我们的目的是使创建的图像看上去真实，因此我们不使用菲涅尔公式本身，而是使用以下经验公式，它能够用非常少的计算获得很好的效果。

reflectionCoefficient = max(0, min(1, bias + scale * pow(1 + dot(I,N), power)))

finalColor = reflectionCoefficient * reflectedColor + (1 - reflectionCoefficient ) * refractedColor

 

在unity3d中的渲染效果如下：

shader如下：

Shader "Custom/Test"
{
    Properties
    {
        _Cube("Cube", Cube) = "white" {}
        _EtaRatio("Eta ratio", float) = 0.8
        _FresnelPower("Fresnel power", float) = 2
        _FresnelScale("Fresnel scale", float) = 1
        _FresnelBias("Fresnel bias", float) = 0
    }

    SubShader
    {
        Tags
        {
            "RenderType" = "Opaque"
        }

        Pass
        {
            CGPROGRAM
            #pragma vertex Vert
            #pragma fragment Frag

            #include "UnityCG.cginc"

            uniform samplerCUBE _Cube;
            uniform float _EtaRatio;
            uniform float _FresnelPower;
            uniform float _FresnelScale;
            uniform float _FresnelBias;

            struct AppData
            {
                float4 pos : POSITION;
                float3 nor : NORMAL;
            };

            struct V2F
            {
                float4 pos : SV_POSITION;
                float reflectionFactor : Color;
                float3 r : TEXCOORD0;
                float3 t : TEXCOORD1;
            };

            V2F Vert(AppData vi)
            {
                V2F fi;
                fi.pos = mul(UNITY_MATRIX_MVP, vi.pos);

                float3 n = normalize(mul(vi.nor, (float3x3)_World2Object));
                float3 viewDir = WorldSpaceViewDir(vi.pos);
                float3 i = normalize(-viewDir);

                fi.r = reflect(i, n);                                                                        // 反射向量
                fi.t = refract(i, n, _EtaRatio);                                                            // 折射向量
                fi.reflectionFactor = _FresnelBias + _FresnelScale * pow(1 + dot(i, n), _FresnelPower);        // 反射颜色所占比例

                return fi;
            }

            float4 Frag(V2F fi) : Color
            {
                float4 reflectC = texCUBE(_Cube, fi.r);
                float4 refractC = texCUBE(_Cube, fi.t);
                return lerp(refractC, reflectC, fi.reflectionFactor);
            }

            ENDCG
        }
    }
}

转载请注明出处： http://www.cnblogs.com/jietian331/p/5564901.html