主角场景Shader效果：描边

基本思路：Shader用两个Pass，一个渲染描边部分，一个渲染物体部分。

Pass1：剔除正面，渲染背面，把顶点延法线方向外围扩展一定宽度，用来表现描边的粗细，这部分用自己设定的颜色。

Pass2：剔除背面，渲染正面，正常渲染所看到的物体模型。

// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'mul(UNITY_MATRIX_MVP,*)'

Shader "xj/ModelEffect/Outline" {
    Properties {
        _Color ("模型颜色", Color) = (1,1,1,1)
        _OutlineColor ("描边颜色", Color) = (1,0,0,1)
        _Outline ("描边宽度", float) = 0.03
        _MainTex ("模型贴图", 2D) = "white" {}
        _AlphaTex ("Alpha (A)", 2D) = "white" {}
        _intensity ("强度", float ) = 1.0
    }
 
    CGINCLUDE
        #include "UnityCG.cginc"
 
        struct appdata {
            float4 vertex : POSITION;
            float3 normal : NORMAL;
            half2 texcoord : TEXCOORD0;
        };
 
        struct v2f {
            float4 pos : SV_POSITION;
            fixed4 color : COLOR;
            half2 texcoord : TEXCOORD0;
        };

        struct basevt {
            float4 pos : SV_POSITION;
            half2 texcoord : TEXCOORD0;
        };
 
        sampler2D _MainTex;
        sampler2D _AlphaTex;
        uniform fixed _Outline;
        uniform fixed4 _OutlineColor;
        uniform fixed4 _Color;
        fixed _intensity;
 
        v2f outline_vert(appdata v) 
        {
            //在vertex阶段，每个顶点按照法线的方向偏移一部分，不过这种会造成近大远小的透视问题
            //正确的做法是转换到投影空间下做偏移
            //v.vertex.xyz += v.normal * _Outline;

            v2f o;
            o.pos = mul(UNITY_MATRIX_MVP,v.vertex);
            float3 norm = mul ((float3x3)UNITY_MATRIX_IT_MV, v.normal);
            float2 offset = TransformViewToProjection(norm.xy);
            o.pos.xy += offset * _Outline;
            o.color = _OutlineColor;
            o.texcoord = v.texcoord;
            return o;
        }

        fixed4 outline_frag(v2f i): SV_Target
        {
            fixed4 color = i.color;
            color.a = tex2D(_AlphaTex, i.texcoord).a;
            return color;
        }

        basevt base_vert(appdata v)
        {
            basevt o;
            o.pos = mul(UNITY_MATRIX_MVP,v.vertex);
            o.texcoord = v.texcoord;
            return o;
        }

        fixed4 base_frag(basevt i): SV_Target
        {
            fixed4 col = tex2D(_MainTex, i.texcoord) * _Color * _intensity;
            col.a = tex2D(_AlphaTex, i.texcoord).a * _Color.a;
            return col;
        }    
    ENDCG
 
    SubShader {
        Tags { "Queue" = "Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}
        Fog {Mode Off}

        Pass 
        {
            Name "OUTLINE"
            Cull Front //剔除正面
            CGPROGRAM

            #pragma vertex outline_vert
            #pragma fragment outline_frag
            #pragma fragmentoption ARB_precision_hint_fastest
         
            ENDCG
        }
 
        Pass 
        {
            Name "BASE"
            Cull Back //剔除背面
            CGPROGRAM

            #pragma vertex base_vert
            #pragma fragment base_frag
            #pragma fragmentoption ARB_precision_hint_fastest
         
            ENDCG
        }
    }
    FallBack "xj/Default"
}