【暑假训练 7.10】 codevs 2492 上帝造题的七分钟2

Description

XLk觉得《上帝造题的七分钟》不太过瘾，于是有了第二部。
“第一分钟，X说，要有数列，于是便给定了一个正整数数列。
第二分钟，L说，要能修改，于是便有了对一段数中每个数都开平方(下取整)的操作。
第三分钟，k说，要能查询，于是便有了求一段数的和的操作。
第四分钟，彩虹喵说，要是NOIP难度，于是便有了数据范围。
第五分钟，诗人说，要有韵律，于是便有了时间限制和内存限制。
第六分钟，和雪说，要省点事，于是便有了保证运算过程中及最终结果均不超过64位有符号整数类型的表示范围的限制。
第七分钟，这道题终于造完了，然而，造题的神牛们再也不想写这道题的程序了。”
——《上帝造题的七分钟·第二部》
所以这个神圣的任务就交给你了。

Input

第一行一个整数n，代表数列中数的个数。
第二行n个正整数，表示初始状态下数列中的数。
第三行一个整数m，表示有m次操作。
接下来m行每行三个整数k,l,r，k=0表示给[l,r]中的每个数开平方(下取整)，k=1表示询问[l,r]中各个数的和。

Output

对于询问操作，每行输出一个回答。

Sample Input

10
1 2 3 4 5 6 7 8 9 10
5
0 1 10
1 1 10
1 1 5
0 5 8
1 4 8

Sample Output

19
7
6

HINT

1：对于100%的数据，1<=n<=100000，1<=l<=r<=n，数列中的数大于0，且不超过1e12。
2：数据不保证L<=R 若L>R，请自行交换L,R，谢谢！

其实就是就是如果一个结点值为0或者1就不再更新；如果一棵树左右儿子都不再更新，它也不再更新。

代码:

type node=record
       l,r:longint;
       num:int64;
       tag:boolean;
     end;

var
  f:array[1..500000]of node;
  a:array[1..100000]of int64;
  n,m,i,k,x,y:longint;

procedure swap(var x,y:longint);
var
  t:longint;
begin
  t:=x; x:=y; y:=t;
end;

procedure build(h,l,r:longint);
begin
  f[h].l:=l; f[h].r:=r;
  if l=r then
    begin
      f[h].num:=a[l];
      if (a[l]=0)or(a[l]=1) then f[h].tag:=true;
      exit;
    end;
  build(h*2,l,(l+r) div 2);
  build(h*2+1,(l+r) div 2+1,r);
  f[h].num:=f[h*2].num+f[h*2+1].num;
  f[h].tag:=f[h*2].tag and f[h*2+1].tag;
end;

procedure change(h,l,r:longint);
begin
  if f[h].tag then exit;
  if f[h].l=f[h].r then
    begin
      f[h].num:=trunc(sqrt(f[h].num));
      if (f[h].num=0)or(f[h].num=1) then f[h].tag:=true;
      exit;
    end;
  if l<=f[h*2].r then change(h*2,l,r);
  if r>=f[h*2+1].l then change(h*2+1,l,r);
  f[h].num:=f[h*2].num+f[h*2+1].num;
  f[h].tag:=f[h*2].tag and f[h*2+1].tag;
end;

function find(h,l,r:longint):int64;
begin
  find:=0;
  if (f[h].l>=l)and(f[h].r<=r) then exit(f[h].num);
  if l<=f[h*2].r then inc(find,find(h*2,l,r));
  if r>=f[h*2+1].l then inc(find,find(h*2+1,l,r));
end;

begin
  readln(n);
  for i:=1 to n do read(a[i]);
  build(1,1,n);
  readln(m);
  for i:=1 to m do
    begin
      readln(k,x,y);
      if x>y then swap(x,y);
      if k=0 then change(1,x,y)
             else writeln(find(1,x,y));
    end;
end.