Delphi修改Access密码,压缩与修复,建立Access数据库文件

unit UAccessOperate;

interface

uses Windows, Sysutils, ComObj, Dialogs, ActiveX;



//修改ACCESS数据库密码
function ChangeDatabasePassword(AFileName,AOldPassWord,ANewPassWord:string):boolean;

//压缩与修复数据库,覆盖源文件
function CompactDatabase(AFileName,APassWord:string):boolean;

//建立Access文件，如果文件存在则失败
function CreateAccessFile(FileName:String;PassWord:string=''):boolean;

implementation

//声明连接字符串
Const
SConnectionString       = 'Provider=Microsoft.Jet.OLEDB.4.0;Data Source=%s;'

                               +'Jet OLEDB:Database Password=%s;';



//=============================================================================

// Procedure: GetTempPathFileName

// Author   : ysai

// Date     : 2003-01-27

// Arguments: (None)

// Result   : string

//=============================================================================

function GetTempPathFileName():string;

//取得临时文件名
var
SPath,SFile:array [0..254] of char;
begin
GetTempPath(254,SPath);
GetTempFileName(SPath,'~SM',0,SFile);
result:=SFile;
DeleteFile(PChar(result));
end;



//=============================================================================

// Procedure: CreateAccessFile

// Author   : ysai

// Date     : 2003-01-27

// Arguments: FileName:String;PassWord:string=''

// Result   : boolean

//=============================================================================
//建立Access文件，如果文件存在则失败
function CreateAccessFile(FileName:String;PassWord:string=''):boolean;
var
STempFileName:string;
vCatalog:OleVariant;
begin
STempFileName:=GetTempPathFileName;
try
   vCatalog:=CreateOleObject('ADOX.Catalog');
   vCatalog.Create(format(SConnectionString,[STempFileName,PassWord]));
   result:=CopyFile(PChar(STempFileName),PChar(FileName),True);
   DeleteFile(STempFileName);
except
   result:=false;
end;
end;



//=============================================================================

// Procedure: CompactDatabase

// Author   : ysai

// Date     : 2003-01-27

// Arguments: AFileName,APassWord:string

// Result   : boolean

//=============================================================================

function CompactDatabase(AFileName,APassWord:string):boolean;
//压缩与修复数据库,覆盖源文件
var
STempFileName:string;
vJE:OleVariant;
begin
STempFileName:=GetTempPathFileName;
try
   vJE:=CreateOleObject('JRO.JetEngine');
   vJE.CompactDatabase(format(SConnectionString,[AFileName,APassWord]),
       format(SConnectionString,[STempFileName,APassWord]));
   result:=CopyFile(PChar(STempFileName),PChar(AFileName),false);
   DeleteFile(STempFileName);
except
   result:=false;
end;
end;



//=============================================================================
// Procedure: ChangeDatabasePassword
// Author   : ysai
// Date     : 2003-01-27
// Arguments: AFileName,AOldPassWord,ANewPassWord:string
// Result   : boolean
//=============================================================================
//修改ACCESS数据库密码
function ChangeDatabasePassword(AFileName,AOldPassWord,ANewPassWord:string):boolean;
var
  STempFileName:string;
  vJE:OleVariant;
begin
STempFileName:=GetTempPathFileName;
try
   vJE:=CreateOleObject('JRO.JetEngine');
   vJE.CompactDatabase(format(SConnectionString,[AFileName,AOldPassWord]),
                       format(SConnectionString,[STempFileName,ANewPassWord]));
   result:=CopyFile(PChar(STempFileName),PChar(AFileName),false);
   DeleteFile(STempFileName);
except
   result:=false;
end;
end;

end.