「Nescafé XXVI」杯HE两校联赛(Day2)

A.小猫爬山

        宿敌啊，真面目是USACO Fence Rails (fence8)。我Training就是卡在这题目上了，居然没认出来，一开始还想到纪念品分组，高兴太早了。卡时+剪枝得64分。

        显然车越多越容易装上猫，有单调性所以可以二分。

program catclimb;
uses math;
var w,n,timer:Qword;
    A,C:array[1..18] of Qword;
    i,l,r,mid:longint;
function  DFS(k:byte):boolean;
          var i:longint;
          begin
          if k>n then exit(true);DFS:=false;
          for i:=1 to min(k,mid) do
            if A[i]+C[k]<=w
              then begin
                   inc(A[i],C[k]);
                   if DFS(k+1)then exit(true);
                   dec(A[i],C[k]);
                   end;
          end;
begin
readln(n,w);l:=0;r:=n;
for i:=1 to n do read(c[i]);
while l<r-1 do begin
  fillchar(A,sizeof(A),0);
  mid:=(l+r)>>1;
  if dfs(1)
    then r:=mid
    else l:=mid;
  end;
writeln(r);
end.

B.Freda的传呼机

       这题目太猥琐了，A类很显然，B、C就不会了。以为B类可以通过两次删边解决，结果还是WA30。。。只有40分

program communicate;
uses math;
const Filename='communicate';
      maxn=10000;
      maxm=12000;
var x,y,t,n,m,s,i,tot,sum,forbidden:longint;
    w,v,next:array[0..maxn*2+100] of longint;
    right,p:array[0..maxm*2+100] of longint;
    q,head,list,dis,father,ancester:array[1..maxn+10] of longint;
    vis:array[1..maxn] of boolean;
    a,b,ans:array[1..maxm] of longint;
procedure build(x,y,t:longint);
          begin
          inc(tot);
          v[tot]:=y;w[tot]:=t;
          next[tot]:=head[x];
          head[x]:=tot;
          end;
procedure add(x,y:longint);
          begin
          inc(sum);P[sum]:=y;
          right[sum]:=list[x];
          list[x]:=sum;
          end;
function  find(x:longint):longint;
          begin
          if father[x]=x then exit(x);
          find:=find(father[x]);
          father[x]:=find;
          end;
procedure union(x,y:longint);
          begin father[find(y)]:=find(x);end;
procedure Tarjan(u:longint);
          var i,temp:longint;
          begin
          father[u]:=u;ancester[find(u)]:=u;
          vis[u]:=true;i:=head[u];
          while i<>0 do begin
            if(not vis[v[i]])and
              (i>>1<>forbidden)
              then begin
                   Tarjan(v[i]);
                   union(u,v[i]);
                   ancester[find(u)]:=u;
                   end;
            i:=next[i];end;
          i:=list[u];
          while i<>0 do begin
            if vis[p[i]]
              then begin
                   temp:=dis[A[i>>1]]+dis[B[i>>1]]-
                         dis[ancester[find(p[i])]]<<1;
                   ans[i>>1]:=min(ans[i>>1],temp);
                   end;
            i:=right[i];end;
          end;
procedure APro(forb:longint);
          var i,h,t:longint;
          begin
          fillchar(vis,sizeof(vis),false);
          h:=0;t:=1;Q[1]:=1;forbidden:=forb;
          dis[1]:=0;vis[1]:=true;
          while h<t do begin
            inc(h);i:=head[Q[h]];
            while i<>0 do begin
              if not vis[v[i]]
                then begin
                     vis[v[i]]:=true;
                     dis[v[i]]:=dis[Q[h]]+w[i];
                     inc(t);Q[t]:=v[i];
                     end;
              i:=next[i];end;end;
          fillchar(vis,sizeof(vis),false);Tarjan(1);
          end;
procedure BPro;
          var i,h,t,c1,c2:longint;
          begin
          h:=0;t:=1;Q[1]:=1;c1:=0;
          dis[1]:=0;vis[1]:=true;
          while(h<t)and(c1=0)do begin
            inc(h);i:=head[Q[h]];
            while i<>0 do begin
              if not vis[v[i]]
                then begin
                     vis[v[i]]:=true;
                     dis[v[i]]:=dis[Q[h]]+w[i];
                     father[v[i]]:=i>>1;
                     inc(t);Q[t]:=v[i];
                     end
                else if v[i]<>father[Q[h]]
                       then begin
                            c1:=i>>1;
                            c2:=father[v[i]];
                            end;
              i:=next[i];end;
            end;
          APro(c1);APro(c2);
          end;
procedure SPFA(s:longint);
          var h,t:longint;
          begin
          filldword(dis,sizeof(dis)>>2,maxlongint);
          fillchar(vis,sizeof(vis),false);
          h:=0;t:=1;Q[1]:=s;vis[s]:=true;dis[s]:=0;
          while h<>t do begin
            inc(h);if h>n then h:=0;
            i:=head[Q[h]];
            while i<>0 do begin
              if dis[Q[h]]+w[i]<dis[v[i]]
                then begin
                     dis[v[i]]:=dis[Q[h]]+w[i];
                     if not vis[v[i]]
                       then begin
                            inc(t);if t>n then t:=0;
                            Q[t]:=v[i];vis[v[i]]:=true;
                            end;end;
              i:=next[i];end;
            vis[Q[h]]:=false;end;
          end;
procedure SONGFEN;
          var u,i:longint;
          begin
          for u:=1 to n do
            if list[u]<>0 then begin
              SPFA(u);i:=list[u];
              while i<>0 do begin
                ans[i>>1]:=dis[P[i]];
                i:=right[i];end;end;
          end;
begin
readln(n,m,s);
tot:=1;sum:=1;
for i:=1 to m do begin
  read(x,y,t);
  build(x,y,t);
  build(y,x,t);
  end;
for i:=1 to s do begin
  read(A[i],B[i]);
  ans[i]:=maxlongint;
  add(A[i],B[i]);
  add(B[i],A[i]);
  end;
if m<n then APro(-1);
if m=n then BPro;
if m>n then SONGFEN;
for i:=1 to s do writeln(ans[i]);
end.

A.Freda的队列

        亮点在于队列顶多存N个元素，还有就是各种细节不要错了。

program FQueue;
const maxn=1000000;
var   Q:array[0..maxn+10] of longint;
      x,n,h,t,i,j,finish:longint;
function  next(x:longint):longint;
          begin
 	  next:=x+1;
 	  if x=n then next:=0;
 	  end;
function  pre(x:longint):longint;
          begin
	  pre:=x-1;
	  if x=0 then pre:=n;
	  end;
procedure add(x:longint);
          begin
          t:=next(t);
          Q[t]:=x;
          end;
function  del:longint;
          begin
	  h:=next(h);
          del:=Q[h];
          end;
begin
readln(n);h:=0;t:=0;
for i:=1 to n do
  begin
  read(x);
  case x of
    -1:if h<>t then writeln(del);
     0:begin
       if(h=t)or(h=next(t))
         then continue;
       j:=h;finish:=t;
       repeat
         j:=next(j);
         add(Q[j]);
       until (next(t)=h)or(j=finish);
       end;
     else begin
          Q[h]:=x;
          h:=pre(h);
	  if h=t then t:=pre(t);
	  end;
    end;
  end;
end.

Rainbow的信号

      考虑期望的可加性，把P拆成32个P做即可。拆完以后就是0/1的了，然后求方案数，再除个N^2即为答案。and和or的求法类似去年NOIp Hotel(?)。xor乱搞，记录从当前位置向左经过了奇数和偶数个1的位置数。

WA40是因为Q爆maxlongint，日。

program signal;
uses math;
const maxn=100000;
      Filename='signal';
var   ansxor,ansand,ansor:extended;
      P:array[1..maxn] of longint;
      n,Q:int64;
      i:longint;
procedure swap(var a,b:longint);
var t:longint;begin t:=a;a:=b;b:=t;end;
procedure solve(w:longint);
          var xorcnt,last:array[0..1] of longint;
              Ai,i:longint;
              x:extended;
          begin
          fillchar(xorcnt,sizeof(xorcnt),0);
          fillchar(last  ,sizeof(last),  0);
          x:=extended(int64(1)<<(w+1));
          for i:=1 to n do begin
            Ai:=(P[i]>>w)and 1;
            ansxor:=ansxor+X/Q*xorcnt[Ai xor 1];
            case Ai of
              1:begin
                ansand:=ansand+X/Q*(i-1-last[0]);
                ansor :=ansor +X/Q*(i-1);
                ansand:=ansand+x/Q/2;
                ansor :=ansor +x/Q/2;
                ansxor:=ansxor+x/Q/2;
                swap(xorcnt[0],xorcnt[1]);
                inc(xorcnt[1]);
                end;
              0:begin
                ansor:=ansor+X/Q*last[1];
                inc(xorcnt[0]);
                end;
              end;Last[Ai]:=i;end;
          end;
begin
readln(n);Q:=N*N;
for i:=1 to n do read(P[i]);
for i:=0 to 30 do solve(i);
writeln(ansxor:3:3,' ',ansand:3:3,' ',ansor:3:3);
end.

94分 62名