DATEDIFF 和 DATEADD

/* 
  DATEDIFF函数计算两个日期之间的小时、天、周、月、年等时间间隔总数
  语法 DATEDIFF(interval, date1, date2[, firstdayofweek[, firstweekofyear]])
  interval 参数的设定值如下
  yyyy 年 
  q,qq 季 
  m,mm 月 
  y 一年的日数 
  d,dd 日 
  w 一周的日数 
  ww 周 
  h 时 
  n 分钟 
  s 秒 
  DATEADD函数计算一个日期通过给时间间隔加减来获得一个新的日期
  语法 DATEADD (datepart , number , date )
  datepart 参数的设定值如下
  year            yy,yyyy 年
  quarter        qq,q    季度
  month            mm,m    月
  dayofyear        dy,y    一年的日数
  day            dd,d    日
  week            wk,ww   周
  weekday        dw,w    周的日数
  hour            hh      时
  minute        mi,n    分
  second        ss,s    秒
  millisecond   ms        毫秒
  microsecond    mcs        微妙
  nanosecond    ns        纳秒          

  0相当于'1900-1-1'

  使用DATEDIFF和DATEADD函数来计算日期，和本来从当前日期转换到你需要的日期的考虑方法有点不同。
  你必须从时间间隔这个方面来考虑。比如，从当前日期到你要得到的日期之间有多少时间间隔，
  或者，从今天到某一天（比如1900-1-1）之间有多少时间间隔，等等。
  理解怎样着眼于时间间隔有助于你轻松的理解我的不同的日期计算例子。 
*/
 --本月第一天
 -- 我将告诉你如何从当前日期去这个月的最后一天。
 -- 每一个例子都将通过计算当前的时间间隔，然后进行加减来得到想要计算的日期
 
 SELECT  DATEDIFF(mm, 0, GETDATE())
 --本月第一天
 --先看1900-1-1距离当前时间有n个月,然后在让1900-1-1加上n月则等于当月第一天
 SELECT DATEADD(mm, DATEDIFF(mm, 0, GETDATE()), 0); 
 --本周第一天
 SELECT DATEADD(wk, DATEDIFF(wk, 0, GETDATE()), 0);  
 --本年第一天
 SELECT DATEADD(yy, DATEDIFF(yy, 0, GETDATE()), 0);  
 --本季度第一天
 SELECT DATEADD(qq, DATEDIFF(qq, 0, GETDATE()), 0);
 --当天的半夜   
 SELECT DATEADD(dd, DATEDIFF(dd, 0, GETDATE()), 0);  
--上个月的最后一天 
--它通过从一个月的最后一天这个例子上减去3毫秒来获得。有一点要记住，在SqlServer中时间是精确到3毫秒。这就是为什么我需要减去3毫秒来获得我要的日期和时间
SELECT DATEADD(ms, -3, DATEADD(mm, DATEDIFF(mm, 0, GETDATE()), 0)); 
--去年的最后一天 
SELECT DATEADD(ms, -3, DATEADD(yy, DATEDIFF(yy, 0, GETDATE()), 0));  
--本月的最后一天  
SELECT DATEADD(ms, -3, DATEADD(mm, DATEDIFF(m, 0, GETDATE()) + 1, 0));  
--本年的最后一天  
SELECT DATEADD(ms,-3, DATEADD(yy, DATEDIFF(yy, 0, GETDATE()) + 1, 0)); 
--本月的第一个星期一  
SELECT DATEADD(wk,DATEDIFF(wk, 0, DATEADD(dd, 6 - DATEPART(DAY, GETDATE()), GETDATE())), 0);     

--今天的所有数据：
SELECT * FROM [Table] WHERE DATEDIFF(dd, [datetime类型字段], GETDATE()) = 0;
                                                           
--昨天的所有数据：                                           
SELECT * FROM [Table] WHERE DATEDIFF(dd, [datetime类型字段], GETDATE()) = 1;
                                                           
--7天内的所有数据：                                           
SELECT * FROM [Table] WHERE DATEDIFF(dd, [datetime类型字段], GETDATE())< = 7;
                                                           
--30天内的所有数据：                                       
SELECT * FROM [Table] WHERE DATEDIFF(dd, [datetime类型字段], GETDATE())< = 30;
                                                           
--本月的所有数据：                                           
SELECT * FROM [Table] WHERE DATEDIFF(mm, [datetime类型字段], GETDATE()) = 0;
                                                           
--本年的所有数据：                                           
SELECT * FROM [Table] WHERE DATEDIFF(yy, [datetime类型字段], GETDATE()) = 0;


--查询今天是今年的第几天： 
SELECT DATEPART(DAYOFYEAR, GETDATE());

--查询今天是本月的第几天：
--1. 
SELECT DATEPART(dd, GETDATE());  
--2.
SELECT DAY(GETDATE());

--查询本周的星期一日期是多少 （注意：指定日期不能是周日，如果是周日会计算到下周一去。所以如果是周日要减一天）
SELECT DATEADD(wk, DATEDIFF(wk, 0, GETDATE()), 0);

--查询昨天日期：
SELECT CONVERT(CHAR, DATEADD(DD, -1, GETDATE()), 111);  --111是样式号，（100-114）


--查询本月第一天日期：
SELECT DATEADD(mm, DATEDIFF(mm, 0, GETDATE()), 0) AS firstday;

--查询本月最后一天日期：
SELECT DATEADD(ms, -3, DATEADD(mm, DATEDIFF(m, 0, GETDATE()) + 1, 0)) as lastday;      --修改-3的值会有相应的变化

--本月有多少天：
SELECT DATEPART(dd, DATEADD(dd, -1, DATEADD(mm,1, CAST((CAST(YEAR(GETDATE()) AS VARCHAr) + '-' + CAST(MONTH(GETDATE()) AS VARCHAR)+'-01' ) AS DATETIME ))));

--求两个时间段相差几天：
SELECT DATEDIFF(day, '2012/8/1',' 2012/8/20') as daysum;
--在指定的日期上±N天：
SELECT CONVERT(CHAR,DATEADD(dd,1,'2012/8/20'),111) as riqi;    --输出2012/8/21

--在指定的日期上±N分钟：
SELECT DATEADD(mi, -15, GETDATE());  --查询当前时间15分钟之前的日期