8259中断实验

利用系统总线上中断请求信号PCI_INTR，设计一个单中断应用。使用单次脉冲模拟中断产生。编写中断处理程序，在显示器屏幕上显示一个字符“9”

实验程序清单：

INTR_IVADD   EQU   003CH          ;INTR对应的中断矢量地址
                             
STACK1 SEGMENT STACK
        DW 256 DUP(?)
STACK1 ENDS

DATA SEGMENT
MES      DB   'Press any key to exit!',0AH,0DH,0AH,0DH,'$'
CS_BAK   DW  ?                    ;保存INTR原中断处理程序入口段地址的变量
IP_BAK   DW  ?                    ;保存INTR原中断处理程序入口偏移地址的变量
IM_BAK   DB  ?                    ;保存INTR原中断屏蔽字的变量
DATA ENDS

CODE SEGMENT
        ASSUME CS:CODE,DS:DATA

START: MOV AX,DATA
       MOV DS,AX
       MOV DX,OFFSET MES          ;显示退出提示
       MOV AH,09H  
       INT 21H 
       CLI

       MOV AX,0000H               ;替换INTR的中断矢量
       MOV ES,AX
       MOV DI,INTR_IVADD         
       MOV AX,ES:[DI]
       MOV IP_BAK,AX              ;保存INTR原中断处理程序入口偏移地址    
       MOV AX,OFFSET MYISR
       MOV ES:[DI],AX             ;设置当前中断处理程序入口偏移地址

       ADD DI,2
       MOV AX,ES:[DI]
       MOV CS_BAK,AX              ;保存INTR原中断处理程序入口段地址
       MOV AX,SEG MYISR
       MOV ES:[DI],AX             ;设置当前中断处理程序入口段地址
      
       IN  AL,21H
       MOV IM_BAK,AL              ;保存INTR原中断屏蔽字
       AND AL,7FH
       OUT 21H,AL

       STI
     
WAIT1: MOV AH,1                   ;判断是否有按键按下
       INT 16H
       JZ  WAIT1                  ;无按键则跳回继续等待，有则退出
    
QUIT:  CLI

       MOV AX,0000H               ;恢复INTR原中断矢量
       MOV ES,AX
       MOV DI,INTR_IVADD 
       MOV AX,IP_BAK              ;恢复INTR原中断处理程序入口偏移地址
       MOV ES:[DI],AX
       ADD DI,2
       MOV AX,CS_BAK              ;恢复INTR原中断处理程序入口段地址
       MOV ES:[DI],AX

       MOV AL,IM_BAK              ;恢复INTR原中断屏蔽寄存器的屏蔽字
       OUT 21H,AL
       STI

       MOV AX,4C00H               ;返回到DOS
       INT 21H

MYISR PROC NEAR                   ;中断处理程序MYISR
       PUSH AX
       MOV AL,39H
       MOV AH,0EH
       INT 10H
       MOV AL,20H
       INT 10H

OVER:  MOV AL,20H
       OUT 20H,AL      
       POP AX 
       IRET      
MYISR ENDP

CODE ENDS
     END START