批量删除目录下的文件夹

from:http://www.jqpress.com/post/76.aspx

因为.net项目里的debug和release文件夹不需要提交到svn，项目多了，不方便挨个删，写个批处理，以后删除.svn目录也用得着。

批量删除debug和release

@echo off
for /r %%d in (.) do if exist "%%d\debug" rd /s /q "%%d\debug"
for /r %%d in (.) do if exist "%%d\Release" rd /s /q "%%d\Release"

顺便转载一下一个完整的删除各种文件的批处理

@ECHO OFF
@echo ===================================================================
@echo 清除svn,vss,cvs标记文件
@echo filename : clearSvnCvsVss.bat
@echo ===================================================================
@ECHO 按Ctrl + C取消。
@pause
@echo 执行批处理：%0 %1 %2 %3
@echo 转到：%1
cd /d %1

@echo (1)开始清除“.SVN”文件夹
@rem for /r %%d in (.) do if exist "%%d\.svn" echo /s /q "%%d\.svn"
@for /r %%d in (.) do if exist "%%d\.svn" rd /s /q "%%d\.svn"

@echo (2)开始清除CVS标记
@for /r %%d in (.) do if exist "%%d\CVS\Root" rd /s/q "%%d\CVS"

@echo (3)开始清除vssver.scc和vssver2.scc文件
attrib -s -h -r -a vssver?.scc /s
for /r . %%i in (vssver?.scc) do if exist %%i del %%i

@echo (4)开始清除VisualStudio中的VSS标记文件
attrib -s -h -r -a *.vssscc /s
attrib -s -h -r -a *.csproj.vspscc /s

for /r . %%i in (*.vssscc) do if exist %%i del %%i
for /r . %%i in (*.csproj.vspscc) do if exist %%i del %%i

@echo 删除完后请检查是否清楚干净。考虑不同的编码工具带有自己的特殊标志，可根据具体情况修改批处理文件中的命令行。
pause
exit