SQLSERVER拯救某个时间点被误删除的数据

SQLSERVER拯救某个时间点被误删除的数据

转载自：http://blog.csdn.net/dba_huangzj/article/details/8491327

要拯救某个时间点被误删除的数据，需要你在那个时间点之前有一个完整数据库备份。

而且，需要你的数据库恢复模式为：“完整恢复模式”

如何查看你的数据库恢复模式为完整恢复模式，运行下面SQL

SELECT  recovery_model, recovery_model_desc
FROM    sys.databases
WHERE   name = 'GPOSDB'

在创建完一个新数据库之后，强烈建议做一次数据库完整备份

-------------------------------------------------------------------华丽的分割线-----------------------------------------------------------------------

先创建测试表

/*
由于tempdb永远为简单恢复模式，所以不适合做案例。
这里使用我的测试机器里的数据库GPOSDB
*/
USE [GPOSDB]
GO
IF OBJECT_ID('testRestore') IS NOT NULL 
    DROP TABLE testRestore
GO
CREATE TABLE testRestore
    (
      id INT IDENTITY(1, 1) ,
      NAME VARCHAR(50)
    );

插入测试数据

--插入测试数据：   
INSERT INTO testRestore(Name)
SELECT 'test1'
UNION ALL 
SELECT 'test2'
UNION ALL 
SELECT 'test3'
UNION ALL 
SELECT 'test4'
UNION ALL 
SELECT 'test5'
UNION ALL 
SELECT 'test6'
UNION ALL 
SELECT 'test7'
UNION ALL 
SELECT 'test8'

SELECT * FROM testRestore

先来一个数据库完整备份，在22:32的时候完整备份数据库

BACKUP DATABASE [GPOSDB]
TO DISK='D:GPOSDB_FULLBACKUP2013-07-23.bak'
WITH INIT
go

模拟删除表数据，这里使用waitfor time，目的是使删除数据的时间准确一点，这里选择22:34的时候删除数据方便后面还原某个时间点之前的数据

USE [GPOSDB]
GO
WAITFOR TIME '22:34'
DELETE FROM dbo.testRestore

查询一下数据是否删除

USE [GPOSDB]
GO
SELECT * FROM dbo.testRestore

断开与GPOSDB数据库的连接，如果还有连接就kill掉连接，然后执行事务日志备份，在22:36的时候执行事务日志备份

--删除了表中的数据之后最少要等3分钟才执行下面SQL语句，不然的话等一下还原事务日志的时候会报错
--必须断开所有与GPOSDB数据库的连接
USE master
GO
BACKUP LOG [GPOSDB] TO  DISK = N'D:GPOSDB_LOGBACKUP2013-07-23.bak' WITH  NO_TRUNCATE , NOFORMAT,  NAME = N'GPOSDB-事务日志备份', SKIP,  NORECOVERY ,  STATS = 10, CHECKSUM
GO
DECLARE @backupSetId AS INT
SELECT  @backupSetId = position
FROM    msdb..backupset
WHERE   database_name = N'GPOSDB' AND backup_set_id = ( SELECT
                                                              MAX(backup_set_id)
                                                        FROM  msdb..backupset
                                                        WHERE database_name = N'GPOSDB'
                                                      )
IF @backupSetId IS NULL  --这里是验证事务日志备份是否成功，如果没有断开与GPOSDB数据库的连接备份事务日志可能会失败
    BEGIN
        RAISERROR(N'验证失败。找不到数据库“GPOSDB”的备份信息。', 16, 1)
    END
RESTORE VERIFYONLY FROM  DISK = N'D:GPOSDB_LOGBACKUP2013-07-23.bak' WITH  FILE = @backupSetId
GO

--查询是否备份成功
SELECT TOP 10 * FROM    msdb..backupset ORDER BY [backup_set_id] DESC 

还原数据库完整备份

--数据库处于正在还原状态
RESTORE DATABASE [GPOSDB] FROM DISK='D:GPOSDB_FULLBACKUP2013-07-23.bak' WITH replace, NORECOVERY 

 还原事务日志

--因为删除数据是在'22:34' 所以还原到22:33
RESTORE LOG [GPOSDB] FROM DISK='D:GPOSDB_LOGBACKUP2013-07-23.bak' WITH RECOVERY ,STOPAT='2013-7-23 22:33'

如果事务日志还原失败的话，可以使用GUI界面

查看表中的数据

USE [GPOSDB]
GO
SELECT * FROM dbo.testRestore

 -----------------------------------------------------------华丽的分割线--------------------------------------------

要注意的两个地方：

（1）如果你发现误操作以后还有很多人做了操作，那么你还原成功后，别人的操作就会冲掉，所以发生误操作后，要马上停止别人对数据库的操作。

（2）这个方法要对数据库独占