QTP中FSO的使用

序

FSO即文件系统对象(File System Object),在测试工作中有广泛的应有，它可以帮助我们自动生成测试目录，写日志，测试报告等。FSO有对象有很多属性和方法，今天只介绍几个常用的。

创建文件夹及文件

测试过程中需要创建文件的地方很多，比如，可以用FSO对象来构建自动化的整体目录，像下面这个小例子。

'创建测试目录
Function create_test_dir(filepath)
    Set fso=createobject("scripting.filesystemobject")
    '若已存在则先在d盘下做个备份，然后删除之
    If fso.FolderExists(filepath) Then
        '拷贝文件夹并重命名和Linux中的cp命令很像
        fso.CopyFolder filepath,"d:" & "ackup" & cstr(year(now))&cstr(month(now))&cstr(day(now))

        fso.DeleteFolder filepath
        '新建文件夹
        Set test_folder=fso.CreateFolder(filepath)
    else
        Set test_folder=fso.CreateFolder(filepath)
    End If
        fso.CreateFolder filepath&"FrameAction"
        fso.CreateFolder filepath&"FrameUntilityFunction"
        fso.CreateFolder filepath&"FrameObjectRepository"
        fso.CreateFolder filepath&"TestData"
        fso.CreateTextFile  filepath&"TestDataUtility.xls"
        fso.CreateFolder filepath&"TestScript"
        fso.CreateFolder filepath&"TestRecovery"
        fso.CreateFolder filepath&"TestResult"
        fso.CreateFolder filepath&"TestLog"
        fso.CreateFolder filepath&"TestLogLog1"
End Function

create_test_dir("d:QTPFrame")

获取指定路径下的文件所有文件

刚才通过FSO创建了一个目录，现在把目录内包含的文件全部打印出来

'输出所有文件
Function get_file_name(root_file_name)

   Set fso=createobject("scripting.filesystemobject")
   Set folder_obj=fso.GetFolder(root_file_name)
   Set folders_obj=folder_obj.SubFolders
    Set files_obj=folder_obj.Files
    For each file_item in files_obj
            print "文件"&file_item
    Next
   For each folder_item in folders_obj
         Set child_folder=folder_item.SubFolders
         print "文件夹"&folder_item
        If child_folder.Count>0 Then
            '递归调用，获取子文件夹
            get_file_name folder_item
        else
            Set files_obj=folder_item.Files
            For each file_item in files_obj
                print "文件"&file_item
            Next
        End If
   Next

End Function

get_file_name "D:QTPFrame"

写文本文件

FSO对文本文件的操作主要有三种模式

• Forappending：追加模式，在文本末尾继续写入

• Forreading：读取模式

• Forwriting：写入模式，会覆盖原来文件内的内容

Function write_log(file_path)
   '追加模式
    Const Forappending =8
    '只读
    Const Forreading =1
    '写入，覆盖原有内容
    Const Forwriting =2

    set fso=CreateObject("scripting.filesystemobject")
    '如果文件不存在则新建
    If fso. FileExists(file_path)Then
        set txt=fso.OpenTextFile(file_path,Forappending,true)
    else
        set txt=fso.CreateTextFile(file_path,true)
    End If
    '写入字符串，不会自动换行
    txt.Write "Hello,qtp"
    txt.Write "Hi"
    '写入一行空行
    txt.WriteBlankLines 1
    txt.WriteLine "How are you!"
    txt.WriteLine "Fine thank you"
    txt.Close
End Function

write_log "D:QTPFrameTestLoglog.txt"

读取文本文件

读取文件时需要使用Forreading模式，读取时要注意每读取一次EOF指针会相应的移动。

Function read_log(file_path)
    '只读
    Const Forreading =1
    set fso=CreateObject("scripting.filesystemobject")
    '如果文件不存在则新建
    If fso. FileExists(file_path)Then
        set txt=fso.OpenTextFile(file_path,Forreading,true)
    else
        msgbox "File doesn't exist!"
    End If
    print txt.Read(2)
    print txt.ReadLine
    print txt.ReadAll
    txt.Close
End Function
read_log "D:QTPFrameTestLoglog.txt"

测试日志的生成方式

上文简单介绍了文本文件的写入方式，我们在工作中当然不会一个一个的手动去写日志，而是通过改写原有对象方法的方式来进行，我想，这也是大部分自动化同仁采用的方式吧,在这之前我们先做个获取当前时间的函数，一般日志文件的都是以系统时间来命名的。

function get_date_time(date_flag,time_flag)
   Dim current_date_time
   Dim yy,mm,dd,hh,min,ss

   current_date_time=now()
   yy=Year(current_date_time)
   mm=Month(current_date_time)
   If mm<10 Then
     mm="0"&mm
   End If
   dd=Day(current_date_time)
   If dd<10 Then
    dd="0"&dd
   End If
   hh=Hour(current_date_time)
   If hh<10 Then
    hh="0"& hh
  End If
  min=Minute(current_date_time)
   If min<10 Then
     min="0"&min
   End If
  ss=Second(current_date_time)
  If ss<10 Then
   ss="0"&ss
   End If
  get_date_time=yy &date_flag&mm&date_flag& dd &" "  & hh&time_flag & min&time_flag& ss
end function
msgbox get_date_time("/",":")

好了，现在先来重写WebEdit对象的set方法，使其可以自动的生成日志。

Function object_set_write_log(obj,val)
    obj.Set val
   '追加写,w+
   Const forappending=8
   '生成文件系统对象
    Set fso = CreateObject("Scripting.FileSystemObject")
    '左取8个字符获得日期
    log_file_name = left(cstr(get_date_time("",":")),8)+ ".txt"

    log_file_path = "D:QTPFrameTestLog"+"log"+log_file_name
     If not fso.FileExists(log_file_path) Then
        Set log_file = fso.CreateTextFile(log_file_path, True)
    Else
        Set log_file = fso.OpenTextFile(log_file_path,ForAppending,True)
    End If
    '右取8个字符获得时间，写入日志
    log_file.WriteLine right(cstr(get_date_time("",":")),8)&" "&"INFO  [" & obj.getToProperty("micClass")&_
    "-" & obj.getToProperty("TestObjName") & "]" & "input: " + val

    Set log_file=nothing
    Set fso=nothing
End Function

这是我们的测试网页，随便写的很简陋(轻喷)，新建脚本写入测试代码

'日志函数演示
'注册自定义函数
RegisterUserFunc "WebEdit","set","object_set_write_log"

Browser("web对象演示").Page("web对象演示").WebEdit("用户名").Set "test"
Browser("web对象演示").Page("web对象演示").WebEdit("邮箱").Set "11111@qq.com"

将脚本保存在"D:QTPFrameTestScript",获取日期和日志函数放在"D:QTPFrameFrameUntilityFunction"目录下，分别命名get_date_time.vbs,object_write_log.vbs，随后设置相对路径和Resources，然后，运行脚本。