[BZOJ3343]教主的魔法|分块

Description

　　教主最近学会了一种神奇的魔法，能够使人长高。于是他准备演示给XMYZ信息组每个英雄看。于是N个英雄们又一次聚集在了一起，这次他们排成了一列，被编号为1、2、……、N。

每个人的身高一开始都是不超过1000的正整数。教主的魔法每次可以把闭区间[L, R]（1≤L≤R≤N）内的英雄的身高全部加上一个整数W。（虽然L=R时并不符合区间的书写规范，但我们可以认为是单独增加第L（R）个英雄的身高）

CYZ、光哥和ZJQ等人不信教主的邪，于是他们有时候会问WD闭区间 [L, R] 内有多少英雄身高大于等于C，以验证教主的魔法是否真的有效。

WD巨懒，于是他把这个回答的任务交给了你。

 

　　分块算法是指把一个序列分成sqrt(n)块，每块正好有sqrt(n)个元素

　　对于这道题，我们先将每个数按顺序分到一个块中，维护每个块内部的单调性

　　对于一个M操作，我们把l,r中间的块整块作一个加法的标记，对于两头的直接暴力标

　　整块不超过sqrt(n)块，两头的也不超过sqrt(n)个元素，所以时间复杂度还是O（sqrt(n)）

　　对于A操作，对于暴力的部分很容易统计，对于整块的由于我们之前维护好了单调性，直接二分查找就可以了

　　但是这里不要忽略了之前作的add标记

　　

　　

{
    Chunk.
}

program bzoj3343;
const maxn=1000010;maxm=1010;
var n,q,m,block,x,y,z,i:longint;
    ch:char;
    a,b,pos:array[-1..maxn]of longint;
    add:array[-1..maxm]of longint;

function min(a,b:longint):longint;
begin
    if a<b then exit(a) else exit(b);
end;

procedure qsort(L,R:longint);
var i,j,mid:longint;
begin
    i:=L;j:=R;mid:=b[random(R-L+1)+L];
    repeat
        while (i<R)and(b[i]>mid) do inc(i);
        while (L<j)and(b[j]<mid) do dec(j);
        if i<=j then
        begin
            b[0]:=b[i];b[i]:=b[j];b[j]:=b[0];
            inc(i);dec(j);
        end;
    until i>j;
    if i<R then qsort(i,R);
    if L<j then qsort(L,j);
end;

procedure new(p:longint);
var l,r,i:longint;
begin
    l:=(p-1)*block+1;r:=min(p*block,n);
    for i:=l to r do b[i]:=a[i];
    qsort(l,r);
end;

procedure update(x,y,z:longint);
var i:longint;
begin
    if pos[x]=pos[y] then
        for i:=x to y do inc(a[i],z) else
    begin
        for i:=x to pos[x]*block do inc(a[i],z);
        for i:=(pos[y]-1)*block+1 to y do inc(a[i],z);
    end;
    for i:=pos[x]+1 to pos[y]-1 do inc(add[i],z);
    new(pos[x]);new(pos[y]);
end;

function find(x,y:longint):longint;
var L,R,mid:longint;
begin
    find:=(x-1)*block;
    L:=(x-1)*block+1;R:=x*block;
    while L<=R do
    begin
        mid:=(L+R) >> 1;
        if b[mid]>=y then
        begin
            find:=mid;L:=mid+1;
        end else R:=mid-1;
    end;
    dec(find,(x-1)*block);
end;

function query(x,y,z:longint):longint;
var tot,i:longint;
begin
        tot:=0;
    if pos[x]=pos[y] then
    begin    for i:=x to y do if a[i]>=z then inc(tot);end else
    begin
        for i:=x to pos[x]*block do if a[i]>=z then inc(tot);
        for i:=(pos[y]-1)*block+1 to y do if a[i]>=z then inc(tot);
    end;
    for i:=pos[x]+1 to pos[y]-1 do inc(tot,find(i,z-add[i]));
        exit(tot);
end;

begin
    readln(n,q);
    fillchar(add,sizeof(add),0);
    block:=trunc(sqrt(n));
    for i:=1 to n do
    begin
        read(a[i]);
        pos[i]:=(i-1) div block+1;//pos[i]表示第i个数所在的块
    end;
        readln;
    if n mod block=0 then m:=n div block else m:=n div block +1;
    for i:=1 to m do new(i);
        for i:=1 to q do
    begin
        read(ch);
        if ch='M' then
        begin
            readln(x,y,z);
            update(x,y,z);
        end else
        begin
            readln(x,y,z);
            writeln(query(x,y,z));
        end;
    end;
end.