[BZOJ2754] [SCOI2012]喵星球上的点名解题报告|后缀数组

　　

　　a180285幸运地被选做了地球到喵星球的留学生。他发现喵星人在上课前的点名现象非常有趣。   假设课堂上有N个喵星人，每个喵星人的名字由姓和名构成。喵星球上的老师会选择M个串来点名，每次读出一个串的时候，如果这个串是一个喵星人的姓或名的子串，那么这个喵星人就必须答到。 然而，由于喵星人的字码过于古怪，以至于不能用ASCII码来表示。为了方便描述，a180285决定用数串来表示喵星人的名字。

现在你能帮助a180285统计每次点名的时候有多少喵星人答到，以及M次点名结束后每个喵星人答到多少次吗？  

 

　　应该算是后缀数组比较简单的应用了吧...

　　首先把所有的串都接起来，中间用不同的分隔符隔开

　　然后进行后缀数组将sa,rank,height等数组求出来

　　最后枚举每一个点名串，以rank[点名串起点]开始向左和向右拓展

　　这里的拓展是指在sa的下标里拓展

　　边统计边累计每个喵星人的点到次数

　　为了避免一次点名中统计到一个喵星人多次，以及一个喵星人一次点名却统计了多次

　　（实际上二者是一样的...）

　　都可以用一个标号数组来处理

　　然而这个标号数组如果每次fillchar显然不现实...因为太慢...

　　然后就运用到KM算法里顶标更新的思想

　　当然，再做一次然后把数组还原也是可以的

 

　　另外在BZ上PE了一发...行末注意不能留有空格

program bzoj2754;
const INF = 100007;maxn = 400010;
var tota,totb,i,cnt,n,x,j:longint;
    a,rank,s,tmp,sa,height,pos,ter,len,vis,ans:array[-1..maxn]of longint;

function max(a,b:longint):longint;
begin
    if a>b then exit(a) else exit(b);
end;

procedure Suffix_Array;
var sz,i,j,p,v0,v1,v00,v01:longint;
begin
    sz:=max(n,INF+10000);
    for i:=0 to sz do s[i]:=0;
    for i:=0 to n-1 do rank[i]:=a[i];
    for i:=0 to n-1 do inc(s[rank[i]]);
    for i:=1 to sz do inc(s[i],s[i-1]);
    for i:=n-1 downto 0 do
    begin
        dec(s[rank[i]]);
        sa[s[rank[i]]]:=i;
    end;
    j:=1;
    while j<=n do
    begin
        p:=0;
        for i:=n-j to n-1 do
        begin
            tmp[p]:=i;inc(p);
        end;
        for i:=0 to n-1 do if sa[i]-j>=0 then
        begin
            tmp[p]:=sa[i]-j;inc(p);
        end;
        for i:=0 to sz do s[i]:=0;
        for i:=0 to n-1 do inc(s[rank[i]]);
        for i:=1 to sz do inc(s[i],s[i-1]);
        for i:=n-1 downto 0 do
        begin
            dec(s[rank[tmp[i]]]);
            sa[s[rank[tmp[i]]]]:=tmp[i];
        end;
        p:=0;tmp[sa[0]]:=0;
        for i:=1 to n-1 do
        begin
            v0:=sa[i-1];v1:=sa[i];
            if v0+j<n then v00:=rank[v0+j] else v00:=-1;
            if v1+j<n then v01:=rank[v1+j] else v01:=-1;
            if (rank[v0]=rank[v1])and(v00=v01) then tmp[sa[i]]:=p else
            begin
                inc(p);tmp[sa[i]]:=p;
            end;
        end;
        for i:=0 to n-1 do rank[i]:=tmp[i];
        j:=j << 1;
    end;
end;

function compare(i,j,x:longint):longint;
begin
    while (i+x-1<n)and(j+x-1<n)and(a[i+x-1]=a[j+x-1]) do inc(x);
    exit(x-1);
end;

procedure calc_height;
var i:longint;
begin
    if rank[0]=0 then height[0]:=0 else height[0]:=compare(0,sa[rank[0]-1],1);
    for i:=1 to n-1 do
    if rank[i]=0 then height[i]:=0 else height[i]:=compare(i,sa[rank[i]-1],max(height[i-1],1));
end;

function solve(x,y:longint):longint;
var i,tot:longint;
begin
    x:=rank[x];i:=x;tot:=0;
    while (i>=1)and(height[sa[i]]>=y) do
    begin
        if (pos[sa[i-1]]<>0)and(vis[pos[sa[i-1]]]<>x) then
        begin
            inc(tot);vis[pos[sa[i-1]]]:=x;inc(ans[pos[sa[i-1]]]);
        end;
        dec(i);
    end;
    i:=x+1;
    while (i<n)and(height[sa[i]]>=y) do
    begin
        if (pos[sa[i]]<>0)and(vis[pos[sa[i]]]<>x) then
        begin
            inc(tot);vis[pos[sa[i]]]:=x;inc(ans[pos[sa[i]]]);
        end;
        inc(i);
    end;
    exit(tot);
end;

begin
    readln(tota,totb);cnt:=0;n:=-1;
    for i:=1 to tota do
    begin
        read(x);for j:=1 to x do begin inc(n);read(a[n]);inc(a[n],INF);pos[n]:=i;end;
        inc(cnt);inc(n);a[n]:=cnt;
        read(x);for j:=1 to x do begin inc(n);read(a[n]);inc(a[n],INF);pos[n]:=i;end;
        inc(cnt);inc(n);a[n]:=cnt;
    end;
    for i:=1 to totb do
    begin
        ter[i]:=n+1;
        read(x);for j:=1 to x do begin inc(n);read(a[n]);inc(a[n],INF);end;
        len[i]:=x;
        inc(cnt);inc(n);a[n]:=cnt;
    end;
    fillchar(vis,sizeof(vis),255);
    inc(n);
    suffix_array;

    calc_height;
    fillchar(ans,sizeof(ans),0);
    for i:=1 to totb do writeln(solve(ter[i],len[i]));
    for i:=1 to tota-1 do write(ans[i],' ');writeln(ans[tota]);
end.